recipes-support/vboxguestdrivers/vboxguestdrivers_6.0.10.bb

   1 SUMMARY = "VirtualBox Linux Guest Drivers"
   2 SECTION = "core"
   3 LICENSE = "GPL-2.0"
   4 LIC_FILES_CHKSUM = "file://${WORKDIR}/${VBOX_NAME}/COPYING;md5=e197d5641bb35b29d46ca8c4bf7f2660"
   5
   6 DEPENDS = "virtual/kernel"
   7
   8 inherit module kernel-module-split
   9
  10 COMPATIBLE_MACHINE = "(qemux86|qemux86-64)"
  11
  12 VBOX_NAME = "VirtualBox-${PV}"
  13
  14 SRC_URI = "http://download.virtualbox.org/virtualbox/${PV}/${VBOX_NAME}.tar.bz2 \
  15     file://Makefile.utils \
  16     "
  17 SRC_URI[md5sum] = "8428f7e27b244803df180213bc5d4a68"
  18 SRC_URI[sha256sum] = "5236148a93267478fb6d306f6343aa9587d3f90f437f54c7b3485bd9d538d2f8"
  19
  20 S = "${WORKDIR}/vbox_module"
  21
  22 export BUILD_TARGET_ARCH="${ARCH}"
  23 export BUILD_TARGET_ARCH_x86-64="amd64"
  24
  25 EXTRA_OEMAKE += "KERN_DIR='${WORKDIR}/${KERNEL_VERSION}/build' all"
  26
  27 addtask export_sources before do_patch after do_unpack
  28
  29 do_export_sources() {
  30     mkdir -p "${S}"
  31     ${WORKDIR}/${VBOX_NAME}/src/VBox/Additions/linux/export_modules.sh ${T}/vbox_modules.tar.gz
  32     tar -C "${S}" -xzf ${T}/vbox_modules.tar.gz
  33
  34     # add a mount utility to use shared folder from VBox Addition Source Code
  35     mkdir -p "${S}/utils"
  36     install ${WORKDIR}/${VBOX_NAME}/src/VBox/Additions/linux/sharedfolders/mount.vboxsf.c ${S}/utils
  37     install ${WORKDIR}/${VBOX_NAME}/src/VBox/Additions/linux/sharedfolders/vbsfmount.c ${S}/utils
  38     install ${S}/../Makefile.utils ${S}/utils/Makefile
  39
  40 }
  41
  42 do_configure_prepend() {
  43     mkdir -p ${WORKDIR}/${KERNEL_VERSION}
  44     ln -snf ${STAGING_KERNEL_DIR} ${WORKDIR}/${KERNEL_VERSION}/build
  45 }
  46
  47 # compile and install mount utility
  48 do_compile_append() {
  49     oe_runmake 'LD=${CC}' 'LDFLAGS=${LDFLAGS}' -C ${S}/utils
  50     if ! [ -e vboxguest.ko -a -e vboxsf.ko -a -e vboxvideo.ko ] ; then
  51         echo "ERROR: One of vbox*.ko modules wasn't built"
  52         exit 1
  53     fi
  54 }
  55
  56 module_do_install() {
  57     MODULE_DIR=${D}${nonarch_base_libdir}/modules/${KERNEL_VERSION}/kernel/misc
  58     install -d $MODULE_DIR
  59     install -m 644 vboxguest.ko $MODULE_DIR
  60     install -m 644 vboxsf.ko $MODULE_DIR
  61     install -m 644 vboxvideo.ko $MODULE_DIR
  62 }
  63
  64 do_install_append() {
  65     install -d ${D}${base_sbindir}
  66     install -m 755 ${S}/utils/mount.vboxsf ${D}${base_sbindir}
  67 }
  68
  69 PACKAGES += "kernel-module-vboxguest kernel-module-vboxsf kernel-module-vboxvideo"
  70 RRECOMMENDS_${PN} += "kernel-module-vboxguest kernel-module-vboxsf kernel-module-vboxvideo"
  71
  72 FILES_${PN} = "${base_sbindir}"
  73
  74 # autoload if installed
  75 KERNEL_MODULE_AUTOLOAD += "vboxguest vboxsf vboxvideo"