recipes-platform/images/agl-kvm-demo-platform.bb

   1 DESCRIPTION = "AGL KVM+QEMU Demo Platform image."
   2
   3 LICENSE = "MIT"
   4
   5 require recipes-platform/images/agl-image-weston.inc
   6
   7 IMAGE_FEATURES += "splash package-management ssh-server-openssh"
   8
   9 # Add packages for KVM+QEMU demo platform here
  10 IMAGE_INSTALL:append = " \
  11     packagegroup-agl-image-minimal \
  12     packagegroup-agl-core-connectivity \
  13     kernel-image \
  14     agl-compositor \
  15     weston-ini-conf-kvm \
  16     output-udev-conf \
  17     native-shell-client \
  18     qemu \
  19     ${QEMU_GUEST_CONFIGS} \
  20     util-linux-taskset \
  21     screen \
  22     simple-can-simulator \
  23     alsa-utils \
  24 "
  25
  26 # Potential size reduction options
  27 #IMAGE_LINGUAS = " "
  28 #NO_RECOMMENDATIONS = "1"
  29
  30 GUEST_MACHINE ?= "virtio-${TUNE_ARCH}"
  31
  32 GUEST_VM1_IMAGE ?= "agl-ivi-demo-platform-flutter"
  33 GUEST_VM2_IMAGE ?= "agl-cluster-demo-platform-flutter"
  34
  35 GUEST_IMAGES ?= "agl-kvm-guest:${GUEST_VM1_IMAGE} agl-kvm-guest:${GUEST_VM2_IMAGE}"
  36
  37 QEMU_GUEST_CONFIGS ?= ""
  38
  39 python __anonymous() {
  40     for c in (d.getVar('GUEST_IMAGES') or "").split():
  41         (mc, image) = c.split(':')
  42         dependency = 'mc::' + mc + ':' + image + ':do_image_complete'
  43         d.appendVarFlag('do_rootfs', 'mcdepends', ' ' + dependency)
  44
  45         # Assume there is a qemu-config-X package for guest image X
  46         d.appendVar('QEMU_GUEST_CONFIGS', ' ' + 'qemu-config-' + image)
  47 }
  48
  49 install_guest_images() {
  50     for c in ${GUEST_IMAGES}; do
  51         config=${c%:*}
  52         image=${c#*:}
  53         name=${image}
  54         rm -rf  ${IMAGE_ROOTFS}/var/lib/machines/${name}
  55         install -m 0755 -d ${IMAGE_ROOTFS}/var/lib/machines/${name}
  56         src="${TOPDIR}/tmp-${config}/deploy/images/${GUEST_MACHINE}/${image}-${GUEST_MACHINE}.ext4"
  57         bbnote "Installing ${src}"
  58         install -m 0600 ${src} ${IMAGE_ROOTFS}/var/lib/machines/${name}/
  59         # Placeholder until booting from kernel in VM image is worked out
  60         install -m 0600 ${TOPDIR}/tmp-${config}/deploy/images/${GUEST_MACHINE}/Image-${GUEST_MACHINE}.bin ${IMAGE_ROOTFS}/var/lib/machines/${name}/
  61     done
  62 }
  63
  64 ROOTFS_POSTPROCESS_COMMAND += "install_guest_images; "
  65
  66 IMAGE_ROOTFS_EXTRA_SPACE:append = "${@bb.utils.contains("DISTRO_FEATURES", "systemd", " + 4096", "" ,d)}"