recipes-platform/images/agl-demo-platform-crosssdk.bb

   1 SUMMARY = "Cross SDK of Full AGL Distribution for IVI profile"
   2
   3 DESCRIPTION = "SDK image for full AGL Distribution for IVI profile. \
   4 It includes the full meta-toolchain, plus developement headers and libraries \
   5 to form a standalone cross SDK."
   6
   7 require agl-demo-platform.bb
   8
   9 LICENSE = "MIT"
  10
  11 IMAGE_FEATURES_append = " dev-pkgs"
  12 IMAGE_INSTALL_append = " kernel-dev kernel-devsrc"
  13
  14 inherit populate_sdk populate_sdk_qt5
  15
  16 # Task do_populate_sdk and do_rootfs can't be exec simultaneously.
  17 # Both exec "createrepo" on the same directory, and so one of them
  18 # can failed (randomly).
  19 addtask do_populate_sdk after do_rootfs
  20
  21 # Add wayland-scanner to SDK (SPEC-945)
  22 # Use TOOLCHAIN_HOST_TASK instead of adding to the packagegroup
  23 # wayland-scanner is in nativesdk-wayland-dev !
  24 # option: add also nativesdk-qtwayland-tools
  25 TOOLCHAIN_HOST_TASK_append = " nativesdk-wayland nativesdk-wayland-dev"
  26
  27 TOOLCHAIN_HOST_TASK_append = " nativesdk-perl-modules "
  28
  29 # Add mosquitto to support building the telematics demo application.
  30 # This is currently required for CI, as it uses agl-demo-platform-crosssdk
  31 # to build everything. An agenda item has been tabled for the May 2019 F2F
  32 # meeting to discuss the path forward (separate versus superset SDKs), this
  33 # should be reviewed after that.
  34 TOOLCHAIN_TARGET_TASK += "mosquitto-dev"
  35
  36 # Add nlohmann-json to support building the speech services.
  37 # Required until either the agl-speech-framework feature is added as a
  38 # dependency of agl-demo, or the speech services are migrated into the
  39 # core profile.
  40 TOOLCHAIN_TARGET_TASK += "nlohmann-json-dev"
  41
  42 # Add libstdc++-staticdev to support building agl-service-voice-high or
  43 # other users of the C++17 filesystem standard library feature.
  44 # Can be removed upon upgrade to gcc 9.x, as it will no longer be necessary.
  45 TOOLCHAIN_TARGET_TASK += "libstdc++-staticdev"
  46
  47 # Add gcc-sanitizers to support building applications using the SDK with
  48 # AddressSanitizer support to detect use-after-frees along with other
  49 # memory issue.
  50 TOOLCHAIN_TARGET_TASK += "gcc-sanitizers"
  51
  52 # Add azure-iot-sdk-c to support building agl-service-cloudproxy and
  53 # other users of Azure sdk.
  54 TOOLCHAIN_TARGET_TASK += "azure-iot-sdk-c"