recipes-demo/flutter-ics-homescreen/flutter-ics-homescreen_git.bb

   1 SUMMARY = "AGL ICS Flutter Homescreen"
   2 DESCRIPTION = "Demo Flutter homescreen for Automotive Grade Linux by ICS."
   3 HOMEPAGE = "https://gerrit.automotivelinux.org/gerrit/apps/flutter-ics-homescreen"
   4 SECTION = "graphics"
   5
   6 LICENSE = "Apache-2.0"
   7 LIC_FILES_CHKSUM = "file://LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57"
   8
   9 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/flutter-ics-homescreen;protocol=https;branch=${AGL_BRANCH} \
  10   file://flutter-ics-homescreen.json \
  11   file://flutter-ics-homescreen.service \
  12   file://ics-homescreen.yaml \
  13   file://ics-homescreen.token \
  14 "
  15 SRCREV = "94b78fd369c318baf1a98d4f510d791ea9f17017"
  16
  17 S = "${WORKDIR}/git"
  18
  19 PUBSPEC_APPNAME = "flutter_ics_homescreen"
  20 FLUTTER_APPLICATION_INSTALL_PREFIX = "/flutter"
  21
  22 FLUTTER_BUILD_ARGS = "bundle -v"
  23
  24 inherit flutter-app systemd
  25
  26 APP_CONFIG = "${BPN}.json"
  27
  28 SYSTEMD_SERVICE:${PN} = "flutter-ics-homescreen.service"
  29
  30 do_install:append() {
  31   install -D -m 0644 ${WORKDIR}/${BPN}.service ${D}${systemd_system_unitdir}/${BPN}.service
  32
  33   install -D -m 0644 ${WORKDIR}/${APP_CONFIG} ${D}${datadir}/flutter/${BPN}.json
  34
  35   # VIS authorization token file for KUKSA.val should ideally not
  36   # be readable by other users, but currently that's not doable
  37   # until a packaging/sandboxing/MAC scheme is (re)implemented or
  38   # something like OAuth is plumbed in as an alternative.
  39   install -d ${D}${sysconfdir}/xdg/AGL/ics-homescreen
  40   install -m 0644 ${WORKDIR}/ics-homescreen.yaml ${D}${sysconfdir}/xdg/AGL/
  41   install -m 0644 ${WORKDIR}/ics-homescreen.token ${D}${sysconfdir}/xdg/AGL/ics-homescreen/
  42 }
  43
  44 FILES:${PN} += "${datadir} ${sysconfdir}/xdg/AGL"
  45 RDEPENDS:${PN} += "flutter-auto agl-flutter-env"