recipes-demo/flutter-ics-homescreen/flutter-ics-homescreen_git.bb

   1 SUMMARY = "AGL ICS Flutter Homescreen"
   2 DESCRIPTION = "Demo Flutter homescreen for Automotive Grade Linux by ICS."
   3 HOMEPAGE = "https://gerrit.automotivelinux.org/gerrit/apps/flutter-ics-homescreen"
   4 SECTION = "graphics"
   5
   6 LICENSE = "Apache-2.0"
   7 LIC_FILES_CHKSUM = "file://LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57"
   8
   9 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/flutter-ics-homescreen;protocol=https;branch=${AGL_BRANCH} \
  10   file://flutter-ics-homescreen.json \
  11   file://flutter-ics-homescreen.service \
  12   file://ics-homescreen.yaml \
  13   file://ics-homescreen.token \
  14   file://radio-presets.yaml \
  15 "
  16 SRCREV = "5587c6ae79b482fbff26442bb239d7d7eb55a337"
  17
  18 S = "${WORKDIR}/git"
  19
  20 PUBSPEC_APPNAME = "flutter_ics_homescreen"
  21 FLUTTER_APPLICATION_INSTALL_PREFIX = "/flutter"
  22
  23 FLUTTER_BUILD_ARGS = "bundle -v"
  24
  25 inherit flutter-app systemd
  26
  27 APP_CONFIG = "${BPN}.json"
  28
  29 SYSTEMD_SERVICE:${PN} = "flutter-ics-homescreen.service"
  30
  31 # Disable the background animation on all platforms except the Renesas M3/H3 for now
  32 DISABLE_BG_ANIMATION = "-DDISABLE_BKG_ANIMATION=true"
  33 DISABLE_BG_ANIMATION:rcar-gen3 = ""
  34 APP_AOT_EXTRA:append = " ${DISABLE_BG_ANIMATION}"
  35
  36 do_install:append() {
  37     install -D -m 0644 ${WORKDIR}/${BPN}.service ${D}${systemd_system_unitdir}/${BPN}.service
  38
  39     install -D -m 0644 ${WORKDIR}/${APP_CONFIG} ${D}${datadir}/flutter/${BPN}.json
  40
  41     # VIS authorization token file for KUKSA.val should ideally not
  42     # be readable by other users, but currently that's not doable
  43     # until a packaging/sandboxing/MAC scheme is (re)implemented or
  44     # something like OAuth is plumbed in as an alternative.
  45     install -d ${D}${sysconfdir}/xdg/AGL/ics-homescreen
  46     install -m 0644 ${WORKDIR}/ics-homescreen.yaml ${D}${sysconfdir}/xdg/AGL/
  47     install -m 0644 ${WORKDIR}/ics-homescreen.token ${D}${sysconfdir}/xdg/AGL/ics-homescreen/
  48     install -m 0644 ${WORKDIR}/radio-presets.yaml ${D}${sysconfdir}/xdg/AGL/ics-homescreen/
  49 }
  50
  51 FILES:${PN} += "${datadir} ${sysconfdir}/xdg/AGL"
  52
  53 RDEPENDS:${PN} += " \
  54     flutter-auto \
  55     agl-flutter-env \
  56     applaunchd \
  57     agl-service-radio \
  58     mpd \
  59 "