recipes-demo/flutter-homescreen/flutter-homescreen_git.bb

   1 SUMMARY = "AGL Flutter Homescreen"
   2 DESCRIPTION = "Demo Flutter homescreen for Automotive Grade Linux."
   3 HOMEPAGE = "https://gerrit.automotivelinux.org/gerrit/apps/flutter-homescreen"
   4 SECTION = "graphics"
   5
   6 LICENSE = "Apache-2.0"
   7 LIC_FILES_CHKSUM = "file://LICENSE;md5=86d3f3a95c324c9479bd8986968f4327"
   8
   9 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/flutter-homescreen;protocol=https;branch=${AGL_BRANCH} \
  10            file://flutter-homescreen-debug.json \
  11            file://flutter-homescreen-profile.json \
  12            file://flutter-homescreen-release.json \
  13            file://flutter-homescreen.service \
  14 "
  15 SRCREV = "e21709c9601209e26d09dea0a45e37f0636bb605"
  16
  17 S = "${WORKDIR}/git"
  18
  19 PUBSPEC_APPNAME = "flutter_homescreen"
  20 FLUTTER_APPLICATION_INSTALL_PREFIX = "/flutter"
  21
  22 FLUTTER_BUILD_ARGS = "bundle -v"
  23
  24 inherit flutter-app
  25
  26 APP_CONFIG = "flutter-homescreen-release.json"
  27 APP_CONFIG:class-runtimedebug = "flutter-homescreen-debug.json"
  28 APP_CONFIG:class-runtimeprofile = "flutter-homescreen-profile.json"
  29
  30 do_install:append() {
  31     install -D -m 0644 ${WORKDIR}/flutter-homescreen.service ${D}${systemd_user_unitdir}/flutter-homescreen.service
  32     install -d ${D}${systemd_user_unitdir}/agl-session.target.wants
  33     ln -s ../flutter-homescreen.service ${D}${systemd_user_unitdir}/agl-session.target.wants/flutter-homescreen.service
  34
  35     install -D -m 0644 ${WORKDIR}/${APP_CONFIG} ${D}${datadir}/flutter/flutter-homescreen.json
  36 }
  37
  38 FILES:${PN} += "${datadir} ${systemd_user_unitdir}"