templates/native/etc/macros.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20
  21 #--------------------------------------------------------------------------
  22 #  WARNING:
  23 #     Do not change this cmake template
  24 #     Customise your preferences in "./etc/config.cmake"
  25 #--------------------------------------------------------------------------
  26
  27
  28 # Generic useful macro
  29 # -----------------------
  30 macro(PROJECT_TARGET_ADD TARGET_NAME)
  31         set_property(GLOBAL APPEND PROPERTY PROJECT_TARGETS ${TARGET_NAME})
  32         set(TARGET_NAME ${TARGET_NAME})
  33 endmacro(PROJECT_TARGET_ADD)
  34
  35 # Check GCC minimal version version
  36 if (gcc_minimal_version)
  37    message ("-- Check gcc_minimal_version (found gcc version ${CMAKE_C_COMPILER_VERSION})  (found g++ version ${CMAKE_CXX_COMPILER_VERSION})")
  38 if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS ${gcc_minimal_version} OR CMAKE_C_COMPILER_VERSION VERSION_LESS ${gcc_minimal_version})
  39     message(FATAL_ERROR "**** FATAL: Require at least gcc-${gcc_minimal_version} please set CMAKE_C[XX]_COMPILER")
  40 endif()
  41 endif(gcc_minimal_version)
  42
  43 macro(defstr name value)
  44         add_definitions(-D${name}=${value})
  45 endmacro(defstr)
  46
  47 # WGT packaging
  48 macro(project_targets_populate)
  49         add_custom_target(MAIN_POPULATE)
  50         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
  51         foreach(TARGET ${PROJECT_TARGETS})
  52                 get_target_property(T ${TARGET} LABELS)
  53                 if(T)
  54                         # Declaration of a custom command that will populate widget tree with the target
  55                         set(POPULE_WIDGET_TARGET "project_populate_${TARGET}")
  56
  57                         get_target_property(P ${TARGET} PREFIX)
  58                         get_target_property(BD ${TARGET} BINARY_DIR)
  59                         get_target_property(OUT ${TARGET} OUTPUT_NAME)
  60
  61                         if(P MATCHES "NOTFOUND$")
  62                                 if (${T} STREQUAL "BINDING")
  63                                         set(P "lib")
  64                                 else()
  65                                         set(P "")
  66                                 endif()
  67                         endif()
  68
  69                         if(${T} STREQUAL "BINDING")
  70                                 add_custom_command(OUTPUT ${WIDGET_LIBDIR}/${P}${TARGET}.so
  71                                         DEPENDS ${TARGET}
  72                                         COMMAND mkdir -p ${WIDGET_LIBDIR}
  73                                         COMMAND cp ${BD}/${P}${OUT}.so ${WIDGET_LIBDIR}
  74                                 )
  75                                 add_custom_target(${POPULE_WIDGET_TARGET} DEPENDS ${WIDGET_LIBDIR}/${P}${TARGET}.so)
  76                                 add_dependencies(MAIN_POPULATE ${POPULE_WIDGET_TARGET})
  77                         elseif(${T} STREQUAL "EXECUTABLE")
  78                                 add_custom_command(OUTPUT ${WIDGET_BINDIR}/${P}${TARGET}
  79                                         DEPENDS ${TARGET}
  80                                         COMMAND mkdir -p ${WIDGET_BINDIR}
  81                                         COMMAND cp ${BD}/${P}${OUT} ${WIDGET_BINDIR}
  82                                 )
  83                                 add_custom_target(${POPULE_WIDGET_TARGET} DEPENDS ${WIDGET_BINDIR}/${P}${TARGET})
  84                                 add_dependencies(MAIN_POPULATE ${POPULE_WIDGET_TARGET})
  85                         elseif(${T} STREQUAL "HTDOCS")
  86                                 add_custom_command(OUTPUT ${WIDGET_HTTPDIR}
  87                                         DEPENDS ${TARGET}
  88                                         COMMAND cp -r ${BD}/${P}${OUT} ${WIDGET_HTTPDIR}
  89                                         )
  90                                         add_custom_target(${POPULE_WIDGET_TARGET} DEPENDS ${WIDGET_HTTPDIR})
  91                                         add_dependencies(MAIN_POPULATE ${POPULE_WIDGET_TARGET})
  92                         elseif(${T} STREQUAL "DATA")
  93                                 add_custom_command(OUTPUT ${WIDGET_DATADIR}
  94                                         DEPENDS ${TARGET}
  95                                         COMMAND cp -r ${BD}/${P}${OUT} ${WIDGET_DATADIR}
  96                                         )
  97                                         add_custom_target(${POPULE_WIDGET_TARGET} DEPENDS ${WIDGET_HTTPDIR})
  98                                         add_dependencies(MAIN_POPULATE ${POPULE_WIDGET_TARGET})
  99                         endif(${T} STREQUAL "BINDING")
 100 #               elseif(${CMAKE_BUILD_TYPE} MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 101 #                                       MESSAGE(WARNING "This target, ${TARGET}, will be not be included in the package.")
 102                 endif()
 103         endforeach()
 104 endmacro(project_targets_populate)
 105
 106 macro(project_package_build)
 107                 if(NOT EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_WGT_DIR}/config.xml.in OR NOT EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_WGT_DIR}/${PROJECT_ICON}.in)
 108                         MESSAGE(FATAL_ERROR "Missing mandatory files: you need config.xml.in and ${PROJECT_ICON}.in files in ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_WGT_DIR} folder.")
 109                 endif()
 110
 111                 if(NOT EXISTS ${WIDGET_DIR}/config.xml.in OR NOT EXISTS ${WIDGET_DIR}/${PROJECT_ICON}.in)
 112                         configure_file(${PROJECT_WGT_DIR}/config.xml.in ${WIDGET_DIR}/config.xml)
 113                         file(COPY ${PROJECT_WGT_DIR}/${PROJECT_ICON}.in DESTINATION ${WIDGET_DIR}/${PROJECT_ICON})
 114                 endif(NOT EXISTS ${WIDGET_DIR}/config.xml.in OR NOT EXISTS ${WIDGET_DIR}/${PROJECT_ICON}.in)
 115
 116                 file(GLOB PROJECT_CONF_FILES "${PROJECT_WGT_DIR}/etc/*")
 117                 if(${PROJECT_CONF_FILES})
 118                         file(COPY "${PROJECT_WGT_DIR}/etc/*" DESTINATION ${WIDGET_ETCDIR}/)
 119                 endif(${PROJECT_CONF_FILES})
 120
 121                 add_custom_command(OUTPUT ${PROJECT_NAME}.wgt
 122                         DEPENDS ${PROJECT_TARGETS}
 123                         COMMAND wgtpkg-pack -f -o ${PROJECT_NAME}.wgt ${WIDGET_DIR}
 124                 )
 125
 126                 add_custom_target(widget DEPENDS ${PROJECT_NAME}.wgt)
 127                 add_dependencies(widget MAIN_POPULATE)
 128                 set(ADDITIONAL_MAKE_CLEAN_FILES, "${PROJECT_NAME}.wgt")
 129
 130                 if(WIDGET_MESSAGE)
 131                 add_custom_command(TARGET widget
 132                         POST_BUILD
 133                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${WIDGET_MESSAGE}")
 134                 endif()
 135 endmacro(project_package_build)
 136
 137 macro(project_subdirs_add)
 138         if(${ARGV0})
 139                 file(GLOB filelist "${ARGV0}")
 140         else()
 141                 file(GLOB filelist "*")
 142         endif(${ARGV0})
 143
 144         foreach(filename ${filelist})
 145                 if(EXISTS "${filename}/CMakeLists.txt")
 146                         add_subdirectory(${filename})
 147                 endif(EXISTS "${filename}/CMakeLists.txt")
 148         endforeach()
 149 endmacro(project_subdirs_add)
 150
 151 set(CMAKE_BUILD_TYPE Debug CACHE STRING "the type of build")
 152 set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 153 set(CMP0048 1)
 154
 155 # Include project configuration
 156 # ------------------------------
 157 project(${PROJECT_NAME} VERSION ${PROJECT_VERSION} LANGUAGES ${PROJECT_LANGUAGES})
 158 set(PROJECT_WGT_DIR "packaging/wgt" CACHE PATH "Subpath to the widget directory")
 159 set(PROJECT_LIBDIR "libs" CACHE PATH "Subpath to libraries")
 160 set(PROJECT_RESOURCES "data" CACHE PATH "Subpath to data")
 161
 162 INCLUDE(FindPkgConfig)
 163 INCLUDE(CheckIncludeFiles)
 164 INCLUDE(CheckLibraryExists)
 165 INCLUDE(GNUInstallDirs)
 166
 167 # Default compilation options
 168 ############################################################################
 169 link_libraries(-Wl,--as-needed -Wl,--gc-sections)
 170 add_compile_options(-Wall -Wextra -Wconversion)
 171 add_compile_options(-Wno-unused-parameter) # frankly not using a parameter does it care?
 172 add_compile_options(-Wno-sign-compare -Wno-sign-conversion)
 173 add_compile_options(-Werror=maybe-uninitialized)
 174 add_compile_options(-Werror=implicit-function-declaration)
 175 add_compile_options(-ffunction-sections -fdata-sections)
 176 add_compile_options(-fPIC)
 177 add_compile_options(-g)
 178
 179 set(CMAKE_C_FLAGS_PROFILING   "-g -O2 -pg -Wp,-U_FORTIFY_SOURCE" CACHE STRING "Flags for profiling")
 180 set(CMAKE_C_FLAGS_DEBUG       "-g -O2 -ggdb -Wp,-U_FORTIFY_SOURCE" CACHE STRING "Flags for debugging")
 181 set(CMAKE_C_FLAGS_RELEASE     "-O2" CACHE STRING "Flags for releasing")
 182 set(CMAKE_C_FLAGS_CCOV        "-g -O2 --coverage" CACHE STRING "Flags for coverage test")
 183
 184 set(CMAKE_CXX_FLAGS_PROFILING    "-g -O0 -pg -Wp,-U_FORTIFY_SOURCE")
 185 set(CMAKE_CXX_FLAGS_DEBUG        "-g -O0 -ggdb -Wp,-U_FORTIFY_SOURCE")
 186 set(CMAKE_CXX_FLAGS_RELEASE      "-g -O2")
 187 set(CMAKE_CXX_FLAGS_CCOV "-g -O2 --coverage")
 188
 189 set(CMAKE_INSTALL_PREFIX      "${CMAKE_SOURCE_DIR}/Install" CACHE PATH "The path where to install")
 190
 191 # (BUG!!!) as PKG_CONFIG_PATH does not work [should be en env variable]
 192 set(PKG_CONFIG_USE_CMAKE_PREFIX_PATH ON CACHE BOOLEAN "Flag for using prefix path")
 193
 194 # Loop on required package and add options
 195 foreach (PKG_CONFIG ${PKG_REQUIRED_LIST})
 196         PKG_CHECK_MODULES(${PKG_CONFIG} REQUIRED ${PKG_CONFIG})
 197
 198         INCLUDE_DIRECTORIES(${${PKG_CONFIG}_INCLUDE_DIRS})
 199         list (APPEND link_libraries ${${PKG_CONFIG}_LIBRARIES})
 200         add_compile_options (${${PKG_CONFIG}_CFLAGS})
 201 endforeach(PKG_CONFIG)
 202
 203 # Optional LibEfence Malloc debug library
 204 IF(CMAKE_BUILD_TYPE MATCHES DEBUG)
 205 CHECK_LIBRARY_EXISTS(efence malloc "" HAVE_LIBEFENCE)
 206 IF(HAVE_LIBEFENCE)
 207         MESSAGE(STATUS "Linking with ElectricFence for debugging purposes...")
 208         SET(libefence_LIBRARIES "-lefence")
 209         list (APPEND link_libraries ${libefence_LIBRARIES})
 210 ENDIF(HAVE_LIBEFENCE)
 211 ENDIF(CMAKE_BUILD_TYPE MATCHES DEBUG)
 212
 213 # set default include directories
 214 INCLUDE_DIRECTORIES(${EXTRA_INCLUDE_DIRS})
 215
 216 # If no install dir try to guess some smart default
 217 if(BINDINGS_INSTALL_PREFIX)
 218         set(BINDINGS_INSTALL_DIR ${BINDINGS_INSTALL_PREFIX}/${PROJECT_NAME})
 219 else()
 220         set(BINDINGS_INSTALL_DIR ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME})
 221 endif()
 222
 223 # Define a default package directory
 224 if(WIDGET_PREFIX)
 225         set(WIDGET_DIR ${WIDGET_PREFIX}/package)
 226 else()
 227         set(WIDGET_DIR ${CMAKE_CURRENT_BINARY_DIR}/package)
 228 endif()
 229
 230 # and their subsequent subdir
 231 set(WIDGET_BINDIR ${WIDGET_DIR}/bin)
 232 set(WIDGET_ETCDIR ${WIDGET_DIR}/etc)
 233 set(WIDGET_LIBDIR ${WIDGET_DIR}/lib)
 234 set(WIDGET_HTTPDIR ${WIDGET_DIR}/htdocs)
 235 set(WIDGET_DATADIR ${WIDGET_DIR}/data)
 236
 237 # Default Linkflag
 238 if(NOT BINDINGS_LINK_FLAG)
 239         set(BINDINGS_LINK_FLAG "-Wl,--version-script=${CMAKE_SOURCE_DIR}/etc/export.map")
 240 endif()
 241
 242 # Add a dummy target to enable global dependency order
 243 # -----------------------------------------------------
 244 if(EXTRA_DEPENDENCIES_ORDER)
 245         set(DEPENDENCIES_TARGET ${PROJECT_NAME}_extra_dependencies)
 246         add_custom_target(${DEPENDENCIES_TARGET} ALL
 247                 DEPENDS ${EXTRA_DEPENDENCY_ORDER}
 248         )
 249 endif()
 250
 251 # Print developer helper message when build is done
 252 # -------------------------------------------------------
 253 macro(project_closing_msg)
 254         get_property(PROJECT_TARGETS_SET GLOBAL PROPERTY PROJECT_TARGETS SET)
 255         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 256         if(CLOSING_MESSAGE AND ${PROJECT_TARGETS_SET})
 257                 add_custom_target(${PROJECT_NAME}_build_done ALL
 258                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 259                 )
 260                  add_dependencies(${PROJECT_NAME}_build_done
 261                         ${DEPENDENCIES_TARGET} ${PROJECT_TARGETS})
 262         endif()
 263 endmacro()