cmake/cmake.d/03-macros.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20 #--------------------------------------------------------------------------
  21 #  WARNING:
  22 #     Do not change this cmake template
  23 #     Customise your preferences in "./conf.d/cmake/config.cmake"
  24 #--------------------------------------------------------------------------
  25 # CMake 3.6 imported macros to simulate list(FILTER ...) subcommand
  26 #--------------------------------------------------------------------------
  27 MACRO(prevent_in_source_build)
  28         execute_process(COMMAND rm -rf ${CMAKE_SOURCE_DIR}/CMakeCache.txt ${CMAKE_SOURCE_DIR}/CMakeCacheForScript.cmake ${CMAKE_SOURCE_DIR}/CMakeFiles ${CMAKE_SOURCE_DIR}/cmake_install.cmake)
  29
  30         get_filename_component(srcdir "${CMAKE_SOURCE_DIR}" REALPATH)
  31         get_filename_component(bindir "${CMAKE_BINARY_DIR}" REALPATH)
  32
  33         if(${srcdir} STREQUAL ${bindir})
  34                 message(FATAL_ERROR "${Red}**** ERROR: You trying to build the project from the source directory or a previous build in-source occured. This isn't allowed, you have to clean CMakeCache.txt file from your source directory (${srcdir}), and build from a separate directory. ****\n")
  35         endif()
  36 ENDMACRO(prevent_in_source_build)
  37
  38 MACRO(PARSE_ARGUMENTS prefix arg_names option_names)
  39         SET(DEFAULT_ARGS)
  40         FOREACH(arg_name ${arg_names})
  41         SET(${prefix}_${arg_name})
  42         ENDFOREACH(arg_name)
  43         FOREACH(option ${option_names})
  44         SET(${prefix}_${option} FALSE)
  45         ENDFOREACH(option)
  46
  47         SET(current_arg_name DEFAULT_ARGS)
  48         SET(current_arg_list)
  49         FOREACH(arg ${ARGN})
  50         LIST_CONTAINS(is_arg_name ${arg} ${arg_names})
  51         IF (is_arg_name)
  52                 SET(${prefix}_${current_arg_name} ${current_arg_list})
  53                 SET(current_arg_name ${arg})
  54                 SET(current_arg_list)
  55         ELSE (is_arg_name)
  56                 LIST_CONTAINS(is_option ${arg} ${option_names})
  57                 IF (is_option)
  58         SET(${prefix}_${arg} TRUE)
  59                 ELSE (is_option)
  60         SET(current_arg_list ${current_arg_list} ${arg})
  61                 ENDIF (is_option)
  62         ENDIF (is_arg_name)
  63         ENDFOREACH(arg)
  64         SET(${prefix}_${current_arg_name} ${current_arg_list})
  65 ENDMACRO(PARSE_ARGUMENTS)
  66
  67 MACRO(LIST_CONTAINS var value)
  68 SET(${var})
  69 FOREACH (value2 ${ARGN})
  70   IF (${value} STREQUAL ${value2})
  71         SET(${var} TRUE)
  72   ENDIF (${value} STREQUAL ${value2})
  73 ENDFOREACH (value2)
  74 ENDMACRO(LIST_CONTAINS)
  75
  76 MACRO(LIST_FILTER)
  77 PARSE_ARGUMENTS(LIST_FILTER "OUTPUT_VARIABLE" "" ${ARGV})
  78 # Check arguments.
  79 LIST(LENGTH LIST_FILTER_DEFAULT_ARGS LIST_FILTER_default_length)
  80 IF(${LIST_FILTER_default_length} EQUAL 0)
  81   MESSAGE(FATAL_ERROR "LIST_FILTER: missing list variable.")
  82 ENDIF(${LIST_FILTER_default_length} EQUAL 0)
  83 IF(${LIST_FILTER_default_length} EQUAL 1)
  84   MESSAGE(FATAL_ERROR "LIST_FILTER: missing regular expression variable.")
  85 ENDIF(${LIST_FILTER_default_length} EQUAL 1)
  86 # Reset output variable
  87 IF(NOT LIST_FILTER_OUTPUT_VARIABLE)
  88   SET(LIST_FILTER_OUTPUT_VARIABLE "LIST_FILTER_internal_output")
  89 ENDIF(NOT LIST_FILTER_OUTPUT_VARIABLE)
  90 SET(${LIST_FILTER_OUTPUT_VARIABLE})
  91 # Extract input list from arguments
  92 LIST(GET LIST_FILTER_DEFAULT_ARGS 0 LIST_FILTER_input_list)
  93 LIST(REMOVE_AT LIST_FILTER_DEFAULT_ARGS 0)
  94 FOREACH(LIST_FILTER_item ${${LIST_FILTER_input_list}})
  95   FOREACH(LIST_FILTER_regexp_var ${LIST_FILTER_DEFAULT_ARGS})
  96         FOREACH(LIST_FILTER_regexp ${${LIST_FILTER_regexp_var}})
  97           IF(${LIST_FILTER_item} MATCHES ${LIST_FILTER_regexp})
  98                 LIST(APPEND ${LIST_FILTER_OUTPUT_VARIABLE} ${LIST_FILTER_item})
  99           ENDIF(${LIST_FILTER_item} MATCHES ${LIST_FILTER_regexp})
 100         ENDFOREACH(LIST_FILTER_regexp ${${LIST_FILTER_regexp_var}})
 101   ENDFOREACH(LIST_FILTER_regexp_var)
 102 ENDFOREACH(LIST_FILTER_item)
 103 # If OUTPUT_VARIABLE is not specified, overwrite the input list.
 104 IF(${LIST_FILTER_OUTPUT_VARIABLE} STREQUAL "LIST_FILTER_internal_output")
 105   SET(${LIST_FILTER_input_list} ${${LIST_FILTER_OUTPUT_VARIABLE}})
 106 ENDIF(${LIST_FILTER_OUTPUT_VARIABLE} STREQUAL "LIST_FILTER_internal_output")
 107 ENDMACRO(LIST_FILTER)
 108
 109 # Generic useful macro
 110 # -----------------------
 111 macro(PROJECT_TARGET_ADD TARGET_NAME)
 112         set_property(GLOBAL APPEND PROPERTY PROJECT_TARGETS ${TARGET_NAME})
 113         set(TARGET_NAME ${TARGET_NAME})
 114 endmacro(PROJECT_TARGET_ADD)
 115
 116 macro(PROJECT_PKGDEP_ADD PKG_NAME)
 117         set_property(GLOBAL APPEND PROPERTY PROJECT_PKG_DEPS ${PKG_NAME})
 118 endmacro(PROJECT_PKGDEP_ADD)
 119
 120 macro(defstr name value)
 121         add_definitions(-D${name}=${value})
 122 endmacro(defstr)
 123
 124 macro(configure_files_in_dir dir)
 125         file(GLOB filelist "${dir}/*in")
 126         foreach(file ${filelist})
 127                 get_filename_component(filename ${file} NAME)
 128                 string(REGEX REPLACE "target" "${RSYNC_TARGET}" destinationfile ${filename})
 129                 string(REGEX REPLACE ".in$" "" destinationfile ${destinationfile})
 130                 configure_file(${file} ${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile})
 131                 set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile}")
 132         endforeach()
 133 endmacro(configure_files_in_dir)
 134
 135 # Create custom target dedicated for HTML5 and DATA AGL target type
 136 macro(add_input_files INPUT_FILES)
 137         if(NOT DEFINED XML_FILES)
 138                 set(ext_reg "xml$")
 139                 set(XML_LIST ${INPUT_FILES})
 140                 list_filter(XML_LIST ext_reg)
 141                 execute_process(
 142                         COMMAND which ${XML_CHECKER}
 143                         RESULT_VARIABLE XML_CHECKER_PRESENT
 144                         OUTPUT_QUIET ERROR_QUIET
 145                 )
 146         endif()
 147         if(NOT DEFINED LUA_LIST)
 148                 set(ext_reg "lua$")
 149                 set(LUA_LIST ${INPUT_FILES})
 150                 list_filter(LUA_LIST ext_reg)
 151                 execute_process(
 152                         COMMAND which ${LUA_CHECKER}
 153                         RESULT_VARIABLE LUA_CHECKER_PRESENT
 154                         OUTPUT_QUIET ERROR_QUIET
 155                 )
 156         endif()
 157         if(NOT DEFINED JSON_FILES)
 158                 set(ext_reg "json$")
 159                 set(JSON_LIST ${INPUT_FILES})
 160                 list_filter(JSON_LIST ext_reg)
 161                 execute_process(
 162                         COMMAND which ${JSON_CHECKER}
 163                         RESULT_VARIABLE JSON_CHECKER_PRESENT
 164                         OUTPUT_QUIET ERROR_QUIET
 165                 )
 166         endif()
 167
 168         # These are v3.6 subcommand. Not used as default for now as
 169         # many dev use Ubuntu 16.04 which have only 3.5 version
 170         #list(FILTER XML_LIST INCLUDE REGEX "xml$")
 171         #list(FILTER LUA_LIST INCLUDE REGEX "lua$")
 172         #list(FILTER JSON_LIST INCLUDE REGEX "json$")
 173
 174         add_custom_target(${TARGET_NAME} ALL
 175         DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 176         )
 177
 178         if(XML_CHECKER_PRESENT EQUAL 0)
 179                 foreach(file ${XML_LIST})
 180                         add_custom_command(TARGET ${TARGET_NAME}
 181                                 PRE_BUILD
 182                                 WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 183                                 COMMAND ${XML_CHECKER} ${file}
 184                         )
 185                 endforeach()
 186         elseif(XML_LIST)
 187         add_custom_command(TARGET ${TARGET_NAME}
 188         PRE_BUILD
 189         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 190         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --red "Warning: XML_CHECKER not found. Not verification made on files !")
 191         endif()
 192         if(LUA_CHECKER_PRESENT EQUAL 0)
 193                 foreach(file ${LUA_LIST})
 194                 add_custom_command(TARGET ${TARGET_NAME}
 195                         PRE_BUILD
 196                         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 197                         COMMAND ${LUA_CHECKER} ${file}
 198                 )
 199                 endforeach()
 200         elseif(LUA_LIST)
 201                 add_custom_command(TARGET ${TARGET_NAME}
 202                         PRE_BUILD
 203                         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 204                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --red "Warning: LUA_CHECKER not found. Not verification made on files !")
 205         endif()
 206         if(JSON_CHECKER_PRESENT EQUAL 0)
 207                 foreach(file ${JSON_LIST})
 208                 add_custom_command(TARGET ${TARGET_NAME}
 209                         PRE_BUILD
 210                         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 211                         COMMAND ${JSON_CHECKER} ${file}
 212                 )
 213                 endforeach()
 214         elseif(JSON_LIST)
 215         add_custom_command(TARGET ${TARGET_NAME}
 216         PRE_BUILD
 217         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 218         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --red "Warning: JSON_CHECKER not found. Not verification made on files !")
 219         endif()
 220
 221         add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 222         DEPENDS ${INPUT_FILES}
 223         COMMAND mkdir -p ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 224         COMMAND touch ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 225         COMMAND cp -r ${INPUT_FILES} ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 226         )
 227 endmacro()
 228
 229 # Set the name of the OPENAPI definition JSON file for binding v2
 230 macro(set_openapi_filename openapi_filename)
 231         set(OPENAPI_DEF ${openapi_filename} CACHE STRING "OpenAPI JSON file name used to generate binding header file before building a binding v2 target.")
 232 endmacro()
 233
 234 # Common command to call inside project_targets_populate macro
 235 macro(generate_one_populate_target OUTPUTFILES PKG_DESTDIR)
 236         add_custom_command(OUTPUT ${PKG_DESTDIR}/${OUTPUTFILES}
 237                 DEPENDS ${BD}/${OUTPUTFILES}
 238                 COMMAND mkdir -p ${PKG_DESTDIR}
 239                 COMMAND touch ${PKG_DESTDIR}
 240                 COMMAND cp -r ${BD}/${OUTPUTFILES}/* ${PKG_DESTDIR} 2> /dev/null || cp ${BD}/${OUTPUTFILES} ${PKG_DESTDIR}
 241         )
 242
 243         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PKG_DESTDIR}/${OUTPUTFILES})
 244         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 245         add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 246 endmacro()
 247
 248 # To be call inside project_targets_populate macro
 249 macro(afb_genskel)
 250         if (OPENAPI_DEF)
 251                 add_custom_command(OUTPUT ${SD}/${OPENAPI_DEF}.h
 252                         DEPENDS ${SD}/${OPENAPI_DEF}.json
 253                         COMMAND afb-genskel ${SD}/${OPENAPI_DEF}.json > ${SD}/${OPENAPI_DEF}.h
 254                 )
 255                 add_custom_target("${TARGET}_GENSKEL" DEPENDS ${SD}/${OPENAPI_DEF}.h
 256                         COMMENT "Generating OpenAPI header file ${OPENAPI_DEF}.h")
 257                 add_dependencies(${TARGET} "${TARGET}_GENSKEL")
 258         else()
 259                 add_custom_command(OUTPUT ${SD}/${OUT}-apidef.h
 260                         DEPENDS ${SD}/${OUT}-apidef.json
 261                         COMMAND afb-genskel ${SD}/${OUT}-apidef.json > ${SD}/${OUT}-apidef.h
 262                 )
 263                 add_custom_target("${TARGET}_GENSKEL" DEPENDS ${SD}/${OUT}-apidef.h
 264                         COMMENT "Generating OpenAPI header file ${OUT}-apidef.h")
 265                 add_dependencies(${TARGET} "${TARGET}_GENSKEL")
 266         endif()
 267 endmacro()
 268
 269 # Pre-packaging
 270 macro(project_targets_populate)
 271         # Default Widget default directory
 272         set(BINDIR bin)
 273         set(ETCDIR etc)
 274         set(LIBDIR lib)
 275         set(HTTPDIR htdocs)
 276         set(DATADIR data)
 277         set(PACKAGE_BINDIR  ${PROJECT_PKG_BUILD_DIR}/${BINDIR})
 278         set(PACKAGE_ETCDIR  ${PROJECT_PKG_BUILD_DIR}/${ETCDIR})
 279         set(PACKAGE_LIBDIR  ${PROJECT_PKG_BUILD_DIR}/${LIBDIR})
 280         set(PACKAGE_HTTPDIR ${PROJECT_PKG_BUILD_DIR}/${HTTPDIR})
 281         set(PACKAGE_DATADIR ${PROJECT_PKG_BUILD_DIR}/${DATADIR})
 282
 283         add_custom_command(OUTPUT ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR}
 284                 COMMAND mkdir -p ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR})
 285         add_custom_target(populate DEPENDS ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR})
 286
 287         # Dirty trick to define a default INSTALL command for app-templates handled
 288         # targets
 289         INSTALL(CODE "execute_process(COMMAND make populate)")
 290         if(NO_DEDICATED_INSTALL_DIR)
 291                 INSTALL(DIRECTORY ${PROJECT_PKG_BUILD_DIR}/
 292                         DESTINATION ${CMAKE_INSTALL_PREFIX}
 293                 )
 294         else()
 295                 INSTALL(DIRECTORY ${PROJECT_PKG_BUILD_DIR}/
 296                         DESTINATION ${CMAKE_INSTALL_PREFIX}/${PROJECT_NAME}
 297                 )
 298         endif()
 299
 300         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 301         foreach(TARGET ${PROJECT_TARGETS})
 302                 # Declaration of a custom command that will populate widget tree with the target
 303                 set(POPULE_PACKAGE_TARGET "project_populate_${TARGET}")
 304                 get_target_property(T ${TARGET} LABELS)
 305
 306                 if(T)
 307                         get_target_property(P ${TARGET} PREFIX)
 308                         get_target_property(S ${TARGET} SUFFIX)
 309                         get_target_property(BD ${TARGET} BINARY_DIR)
 310                         get_target_property(SD ${TARGET} SOURCE_DIR)
 311                         get_target_property(OUT ${TARGET} OUTPUT_NAME)
 312
 313                         if(P MATCHES "NOTFOUND$")
 314                                 if (${T} STREQUAL "LIBRARY")
 315                                         set(P "lib")
 316                                 else()
 317                                         set(P "")
 318                                 endif()
 319                         endif()
 320
 321                         get_target_property(IMPPATH ${TARGET} IMPORTED_LOCATION)
 322                         if(${T} STREQUAL "LIBRARY")
 323                                 unset(BD)
 324                                 generate_one_populate_target(${IMPPATH} ${PACKAGE_LIBDIR})
 325                         elseif(${T} STREQUAL "PLUGIN")
 326                                 if(NOT S)
 327                                         set(S ".ctlso")
 328                                 endif()
 329                                 generate_one_populate_target(${P}${OUT}${S} "${PACKAGE_LIBDIR}/plugins")
 330                         elseif(${T} STREQUAL "BINDING")
 331                                 if(NOT S)
 332                                         set(S ".so")
 333                                 endif()
 334                                 list(APPEND BINDINGS_LIST "${P}${OUT}${S}")
 335                                 generate_one_populate_target(${P}${OUT}${S} ${PACKAGE_LIBDIR})
 336                         elseif(${T} STREQUAL "BINDINGV2")
 337                                 if(NOT S)
 338                                         set(S ".so")
 339                                 endif()
 340                                 afb_genskel()
 341                                 generate_one_populate_target(${P}${OUT}${S} ${PACKAGE_LIBDIR})
 342                         elseif(${T} STREQUAL "EXECUTABLE")
 343                                 if(NOT S)
 344                                         set(S "")
 345                                 endif()
 346                                 if(NOT OUT AND IMPPATH)
 347                                         unset(BD)
 348                                         generate_one_populate_target(${IMPPATH} ${PACKAGE_BINDIR})
 349                                 else()
 350                                         generate_one_populate_target(${P}${OUT}${S} ${PACKAGE_BINDIR})
 351                                 endif()
 352                         elseif(${T} STREQUAL "HTDOCS")
 353                                 generate_one_populate_target(${P}${OUT} ${PACKAGE_HTTPDIR})
 354                         elseif(${T} STREQUAL "DATA")
 355                                 generate_one_populate_target(${TARGET} ${PACKAGE_DATADIR})
 356                         elseif(${T} STREQUAL "BINDING-CONFIG")
 357                                 generate_one_populate_target(${TARGET} ${PACKAGE_ETCDIR})
 358                         endif()
 359                         elseif(${CMAKE_BUILD_TYPE} MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 360                                 MESSAGE("${Yellow}.. Warning: ${TARGET} ignored when packaging.${ColourReset}")
 361                 endif()
 362         endforeach()
 363 endmacro(project_targets_populate)
 364
 365 macro(remote_targets_populate)
 366         if (DEFINED ENV{RSYNC_TARGET})
 367                 set (RSYNC_TARGET $ENV{RSYNC_TARGET})
 368         endif()
 369         if (DEFINED ENV{RSYNC_PREFIX})
 370                 set (RSYNC_PREFIX $ENV{RSYNC_PREFIX})
 371         endif()
 372
 373         set(
 374                 REMOTE_LAUNCH "Test on target with: ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh"
 375                 CACHE STRING "Command to start ${PROJECT_NAME} on remote target ${RSYNC_TARGET}"
 376         )
 377
 378         if(NOT RSYNC_TARGET OR NOT RSYNC_PREFIX)
 379                 message ("${Yellow}.. Warning: RSYNC_TARGET RSYNC_PREFIX not defined 'make remote-target-populate' not instanciated${ColourReset}")
 380                 add_custom_target(remote-target-populate
 381                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make remote-target-populate'${ColourReset}"
 382                         COMMAND exit -1
 383                 )
 384         else()
 385                 set(BINDINGS_REGEX "not_set")
 386                 if(DEFINED BINDINGS_LIST)
 387                         list(LENGTH BINDINGS_LIST BINDINGS_LIST_LENGTH)
 388                         if(BINDINGS_LIST_LENGTH EQUAL 1)
 389                                 list(GET BINDINGS_LIST 0 BINDINGS_REGEX)
 390                                 string(APPEND BINDINGS_REGEX ".so")
 391                         elseif(BINDINGS_LIST_LENGTH GREATER 1)
 392                                 foreach(B IN LISTS BINDINGS_LIST)
 393                                         STRING(APPEND BINDINGS_STR "${B}|")
 394                                 endforeach()
 395                                         STRING(REGEX REPLACE "^(.*)\\|$" "(\\1).so" BINDINGS_REGEX ${BINDINGS_STR})
 396                         endif()
 397                 endif()
 398
 399                 configure_files_in_dir(${TEMPLATE_DIR})
 400                 configure_files_in_dir(${TEMPLATE_DIR})
 401
 402                 add_custom_target(remote-target-populate
 403                         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/*.sh
 404                         COMMAND rsync -e "ssh -o StrictHostKeyChecking=no -o UserKnownHostsFile=/dev/null" --archive --delete ${PROJECT_PKG_BUILD_DIR}/ ${RSYNC_TARGET}:${RSYNC_PREFIX}/${PROJECT_NAME}
 405                 )
 406
 407                 add_custom_command(TARGET remote-target-populate
 408                 POST_BUILD
 409                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --green --bold ${REMOTE_LAUNCH}
 410                 )
 411
 412                 add_dependencies(remote-target-populate populate)
 413         endif()
 414 endmacro(remote_targets_populate)
 415
 416 macro(wgt_package_build)
 417         if(NOT EXISTS ${WIDGET_CONFIG_TEMPLATE})
 418                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need a config.xml template: please specify WIDGET_CONFIG_TEMPLATE correctly.${ColourReset}")
 419         endif()
 420         if(NOT WIDGET_TYPE)
 421                 MESSAGE(FATAL_ERROR "WIDGET_TYPE must be set in your config.cmake.\neg.: set(WIDGET_TYPE application/vnd.agl.service)")
 422         endif()
 423         if(NOT DEFINED PROJECT_ICON)
 424                 if( ${WIDGET_TYPE} MATCHES "agl.native")
 425                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-native.png)
 426                 elseif( ${WIDGET_TYPE} MATCHES "agl.service")
 427                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-service.png)
 428                 elseif( ${WIDGET_TYPE} MATCHES "x-executable")
 429                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-qml.png)
 430                 elseif( ${WIDGET_TYPE} MATCHES "text/html")
 431                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-html5.png)
 432                 endif()
 433         elseif(EXISTS "${CMAKE_SOURCE_DIR}/${WIDGET_ICON}")
 434                 set(ICON_PATH "${CMAKE_SOURCE_DIR}/${WIDGET_ICON}")
 435         elseif(EXISTS "${WIDGET_ICON}")
 436                 set(ICON_PATH "${WIDGET_ICON}")
 437         else()
 438                 set(ICON_PATH ${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/wgt/icon-default.png)
 439         endif()
 440
 441         if(NOT WIDGET_ENTRY_POINT)
 442                 set(WIDGET_ENTRY_POINT lib)
 443         endif()
 444
 445         add_custom_command(OUTPUT ${PROJECT_PKG_BUILD_DIR}/config.xml
 446                 COMMAND ${CMAKE_COMMAND} -DINFILE=${WIDGET_CONFIG_TEMPLATE} -DOUTFILE=${PROJECT_PKG_BUILD_DIR}/config.xml -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 447                 COMMAND cp ${ICON_PATH} ${PROJECT_PKG_BUILD_DIR}/${PROJECT_ICON}
 448
 449         )
 450         add_custom_target(packaging_wgt DEPENDS ${PROJECT_PKG_BUILD_DIR}/config.xml)
 451
 452         # Fulup ??? copy any extra file in wgt/etc into populate package before building the widget
 453         file(GLOB PROJECT_CONF_FILES "${TEMPLATE_DIR}/etc/*")
 454         if(${PROJECT_CONF_FILES})
 455                 file(COPY "${TEMPLATE_DIR}/etc/*" DESTINATION ${PROJECT_PKG_BUILD_DIR}/etc/)
 456         endif(${PROJECT_CONF_FILES})
 457
 458         add_custom_command(OUTPUT ${PROJECT_NAME}.wgt
 459                 DEPENDS ${PROJECT_TARGETS}
 460                 COMMAND wgtpkg-pack -f -o ${PROJECT_NAME}.wgt ${PROJECT_PKG_BUILD_DIR}
 461         )
 462
 463         add_custom_target(widget DEPENDS ${PROJECT_NAME}.wgt)
 464         add_dependencies(widget populate packaging_wgt)
 465         set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}.wgt")
 466
 467         if(NOT RSYNC_TARGET)
 468                 message ("${Yellow}.. Warning: RSYNC_TARGET not defined 'make widget-target-install' not instanciated${ColourReset}")
 469                 add_custom_target(widget-target-install
 470                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make widget-target-install'${ColourReset}"
 471                         COMMAND exit -1
 472                 )
 473         else()
 474         configure_files_in_dir(${TEMPLATE_DIR})
 475         add_custom_target(widget-target-install
 476         DEPENDS widget
 477         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 478         COMMAND ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 479         )
 480 endif()
 481
 482         if(PACKAGE_MESSAGE)
 483         add_custom_command(TARGET widget
 484                 POST_BUILD
 485                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 486         endif()
 487 endmacro(wgt_package_build)
 488
 489 macro(rpm_package_build)
 490         add_custom_command(OUTPUT ${NPKG_PROJECT_NAME}.spec
 491                 DEPENDS ${PROJECT_TARGETS}
 492                                 archive
 493                                 packaging
 494                 COMMAND rpmbuild --define=\"%_sourcedir ${PROJECT_PKG_ENTRY_POINT}\" -ba  ${PROJECT_PKG_ENTRY_POINT}/${NPKG_PROJECT_NAME}.spec
 495         )
 496
 497         add_custom_target(rpm DEPENDS ${NPKG_PROJECT_NAME}.spec)
 498         add_dependencies(rpm populate packaging)
 499
 500         if(PACKAGE_MESSAGE)
 501         add_custom_command(TARGET rpm
 502                 POST_BUILD
 503                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 504         endif()
 505 endmacro(rpm_package_build)
 506
 507 macro(project_package_build)
 508         if(EXISTS ${TEMPLATE_DIR})
 509                 wgt_package_build()
 510         endif()
 511 endmacro(project_package_build)
 512
 513 macro(project_subdirs_add)
 514         set (ARGSLIST ${ARGN})
 515         list(LENGTH ARGSLIST ARGSNUM)
 516         if(${ARGSNUM} GREATER 0)
 517                 file(GLOB filelist "${ARGV0}")
 518         else()
 519         file(GLOB filelist "*")
 520         endif()
 521
 522         foreach(filename ${filelist})
 523                 if(EXISTS "${filename}/CMakeLists.txt")
 524                         add_subdirectory(${filename})
 525                 endif(EXISTS "${filename}/CMakeLists.txt")
 526         endforeach()
 527 endmacro(project_subdirs_add)
 528
 529 # Print developer helper message when build is done
 530 # -------------------------------------------------------
 531 macro(project_closing_msg)
 532         get_property(PROJECT_TARGETS_SET GLOBAL PROPERTY PROJECT_TARGETS SET)
 533         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 534         if(CLOSING_MESSAGE AND ${PROJECT_TARGETS_SET})
 535                 add_custom_target(${PROJECT_NAME}_build_done ALL
 536                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 537                 )
 538                 add_dependencies(${PROJECT_NAME}_build_done
 539                         ${PROJECT_TARGETS} populate)
 540         endif()
 541 endmacro()