cmake/cmake.d/03-macros.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20 #--------------------------------------------------------------------------
  21 #  WARNING:
  22 #     Do not change this cmake template
  23 #     Customise your preferences in "./conf.d/cmake/config.cmake"
  24 #--------------------------------------------------------------------------
  25 # CMake 3.6 imported macros to simulate list(FILTER ...) subcommand
  26 # -----------------------
  27 MACRO(PARSE_ARGUMENTS prefix arg_names option_names)
  28 SET(DEFAULT_ARGS)
  29 FOREACH(arg_name ${arg_names})
  30   SET(${prefix}_${arg_name})
  31 ENDFOREACH(arg_name)
  32 FOREACH(option ${option_names})
  33   SET(${prefix}_${option} FALSE)
  34 ENDFOREACH(option)
  35
  36 SET(current_arg_name DEFAULT_ARGS)
  37 SET(current_arg_list)
  38 FOREACH(arg ${ARGN})
  39   LIST_CONTAINS(is_arg_name ${arg} ${arg_names})
  40   IF (is_arg_name)
  41         SET(${prefix}_${current_arg_name} ${current_arg_list})
  42         SET(current_arg_name ${arg})
  43         SET(current_arg_list)
  44   ELSE (is_arg_name)
  45         LIST_CONTAINS(is_option ${arg} ${option_names})
  46         IF (is_option)
  47   SET(${prefix}_${arg} TRUE)
  48         ELSE (is_option)
  49   SET(current_arg_list ${current_arg_list} ${arg})
  50         ENDIF (is_option)
  51   ENDIF (is_arg_name)
  52 ENDFOREACH(arg)
  53 SET(${prefix}_${current_arg_name} ${current_arg_list})
  54 ENDMACRO(PARSE_ARGUMENTS)
  55
  56 MACRO(LIST_CONTAINS var value)
  57 SET(${var})
  58 FOREACH (value2 ${ARGN})
  59   IF (${value} STREQUAL ${value2})
  60         SET(${var} TRUE)
  61   ENDIF (${value} STREQUAL ${value2})
  62 ENDFOREACH (value2)
  63 ENDMACRO(LIST_CONTAINS)
  64
  65 MACRO(LIST_FILTER)
  66 PARSE_ARGUMENTS(LIST_FILTER "OUTPUT_VARIABLE" "" ${ARGV})
  67 # Check arguments.
  68 LIST(LENGTH LIST_FILTER_DEFAULT_ARGS LIST_FILTER_default_length)
  69 IF(${LIST_FILTER_default_length} EQUAL 0)
  70   MESSAGE(FATAL_ERROR "LIST_FILTER: missing list variable.")
  71 ENDIF(${LIST_FILTER_default_length} EQUAL 0)
  72 IF(${LIST_FILTER_default_length} EQUAL 1)
  73   MESSAGE(FATAL_ERROR "LIST_FILTER: missing regular expression variable.")
  74 ENDIF(${LIST_FILTER_default_length} EQUAL 1)
  75 # Reset output variable
  76 IF(NOT LIST_FILTER_OUTPUT_VARIABLE)
  77   SET(LIST_FILTER_OUTPUT_VARIABLE "LIST_FILTER_internal_output")
  78 ENDIF(NOT LIST_FILTER_OUTPUT_VARIABLE)
  79 SET(${LIST_FILTER_OUTPUT_VARIABLE})
  80 # Extract input list from arguments
  81 LIST(GET LIST_FILTER_DEFAULT_ARGS 0 LIST_FILTER_input_list)
  82 LIST(REMOVE_AT LIST_FILTER_DEFAULT_ARGS 0)
  83 FOREACH(LIST_FILTER_item ${${LIST_FILTER_input_list}})
  84   FOREACH(LIST_FILTER_regexp_var ${LIST_FILTER_DEFAULT_ARGS})
  85         FOREACH(LIST_FILTER_regexp ${${LIST_FILTER_regexp_var}})
  86           IF(${LIST_FILTER_item} MATCHES ${LIST_FILTER_regexp})
  87                 LIST(APPEND ${LIST_FILTER_OUTPUT_VARIABLE} ${LIST_FILTER_item})
  88           ENDIF(${LIST_FILTER_item} MATCHES ${LIST_FILTER_regexp})
  89         ENDFOREACH(LIST_FILTER_regexp ${${LIST_FILTER_regexp_var}})
  90   ENDFOREACH(LIST_FILTER_regexp_var)
  91 ENDFOREACH(LIST_FILTER_item)
  92 # If OUTPUT_VARIABLE is not specified, overwrite the input list.
  93 IF(${LIST_FILTER_OUTPUT_VARIABLE} STREQUAL "LIST_FILTER_internal_output")
  94   SET(${LIST_FILTER_input_list} ${${LIST_FILTER_OUTPUT_VARIABLE}})
  95 ENDIF(${LIST_FILTER_OUTPUT_VARIABLE} STREQUAL "LIST_FILTER_internal_output")
  96 ENDMACRO(LIST_FILTER)
  97
  98 # Generic useful macro
  99 # -----------------------
 100 macro(PROJECT_TARGET_ADD TARGET_NAME)
 101         set_property(GLOBAL APPEND PROPERTY PROJECT_TARGETS ${TARGET_NAME})
 102         set(TARGET_NAME ${TARGET_NAME})
 103 endmacro(PROJECT_TARGET_ADD)
 104
 105 macro(PROJECT_PKGDEP_ADD PKG_NAME)
 106         set_property(GLOBAL APPEND PROPERTY PROJECT_PKG_DEPS ${PKG_NAME})
 107 endmacro(PROJECT_PKGDEP_ADD)
 108
 109 macro(defstr name value)
 110         add_definitions(-D${name}=${value})
 111 endmacro(defstr)
 112
 113 macro(configure_files_in_dir dir)
 114         file(GLOB filelist "${dir}/*in")
 115         foreach(file ${filelist})
 116                 get_filename_component(filename ${file} NAME)
 117                 string(REGEX REPLACE "target" "${RSYNC_TARGET}" destinationfile ${filename})
 118                 string(REGEX REPLACE ".in$" "" destinationfile ${destinationfile})
 119                 configure_file(${file} ${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile})
 120                 set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile}")
 121         endforeach()
 122 endmacro(configure_files_in_dir)
 123
 124 # Create custom target dedicated for HTML5 and DATA AGL target type
 125 macro(add_input_files INPUT_FILES)
 126         if(NOT DEFINED XML_FILES)
 127                 set(ext_reg "xml$")
 128                 set(XML_LIST ${INPUT_FILES})
 129                 list_filter(XML_LIST ext_reg)
 130                 execute_process(
 131                         COMMAND which ${XML_CHECKER}
 132                         RESULT_VARIABLE XML_CHECKER_PRESENT
 133                         OUTPUT_QUIET ERROR_QUIET
 134                 )
 135         endif()
 136         if(NOT DEFINED LUA_LIST)
 137                 set(ext_reg "lua$")
 138                 set(LUA_LIST ${INPUT_FILES})
 139                 list_filter(LUA_LIST ext_reg)
 140                 execute_process(
 141                         COMMAND which ${LUA_CHECKER}
 142                         RESULT_VARIABLE LUA_CHECKER_PRESENT
 143                         OUTPUT_QUIET ERROR_QUIET
 144                 )
 145         endif()
 146         if(NOT DEFINED JSON_FILES)
 147                 set(ext_reg "json$")
 148                 set(JSON_LIST ${INPUT_FILES})
 149                 list_filter(JSON_LIST ext_reg)
 150                 execute_process(
 151                         COMMAND which ${JSON_CHECKER}
 152                         RESULT_VARIABLE JSON_CHECKER_PRESENT
 153                         OUTPUT_QUIET ERROR_QUIET
 154                 )
 155         endif()
 156
 157         # These are v3.6 subcommand. Not used as default for now as
 158         # many dev use Ubuntu 16.04 which have only 3.5 version
 159         #list(FILTER XML_LIST INCLUDE REGEX "xml$")
 160         #list(FILTER LUA_LIST INCLUDE REGEX "lua$")
 161         #list(FILTER JSON_LIST INCLUDE REGEX "json$")
 162
 163         add_custom_target(${TARGET_NAME} ALL
 164         DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 165         )
 166
 167         if(XML_CHECKER_PRESENT EQUAL 0)
 168                 foreach(file ${XML_LIST})
 169                         add_custom_command(TARGET ${TARGET_NAME}
 170                                 PRE_BUILD
 171                                 WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 172                                 COMMAND ${XML_CHECKER} ${file}
 173                         )
 174                 endforeach()
 175         elseif(XML_LIST)
 176         add_custom_command(TARGET ${TARGET_NAME}
 177         PRE_BUILD
 178         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 179         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --red "Warning: XML_CHECKER not found. Not verification made on files !")
 180         endif()
 181         if(LUA_CHECKER_PRESENT EQUAL 0)
 182                 foreach(file ${LUA_LIST})
 183                 add_custom_command(TARGET ${TARGET_NAME}
 184                         PRE_BUILD
 185                         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 186                         COMMAND ${LUA_CHECKER} ${file}
 187                 )
 188                 endforeach()
 189         elseif(LUA_LIST)
 190                 add_custom_command(TARGET ${TARGET_NAME}
 191                         PRE_BUILD
 192                         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 193                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --red "Warning: LUA_CHECKER not found. Not verification made on files !")
 194         endif()
 195         if(JSON_CHECKER_PRESENT EQUAL 0)
 196                 foreach(file ${JSON_LIST})
 197                 add_custom_command(TARGET ${TARGET_NAME}
 198                         PRE_BUILD
 199                         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 200                         COMMAND ${JSON_CHECKER} ${file}
 201                 )
 202                 endforeach()
 203         elseif(JSON_LIST)
 204         add_custom_command(TARGET ${TARGET_NAME}
 205         PRE_BUILD
 206         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 207         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --red "Warning: JSON_CHECKER not found. Not verification made on files !")
 208         endif()
 209
 210         add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 211         DEPENDS ${INPUT_FILES}
 212         COMMAND mkdir -p ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 213         COMMAND touch ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 214         COMMAND cp -r ${INPUT_FILES} ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 215         )
 216 endmacro()
 217
 218 # Set the name of the OPENAPI definition JSON file for binding v2
 219 macro(set_openapi_filename openapi_filename)
 220         set(OPENAPI_DEF ${openapi_filename} CACHE STRING "OpenAPI JSON file name used to generate binding header file before building a binding v2 target.")
 221 endmacro()
 222
 223 # Common command to call inside project_targets_populate macro
 224 macro(generate_one_populate_target OUTPUTFILES PKG_DESTDIR)
 225         add_custom_command(OUTPUT ${PKG_DESTDIR}/${OUTPUTFILES}
 226                 DEPENDS ${BD}/${OUTPUTFILES}
 227                 COMMAND mkdir -p ${PKG_DESTDIR}
 228                 COMMAND touch ${PKG_DESTDIR}
 229                 COMMAND cp -r ${BD}/${OUTPUTFILES}/* ${PKG_DESTDIR} 2> /dev/null || cp ${BD}/${OUTPUTFILES} ${PKG_DESTDIR}
 230         )
 231
 232         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PKG_DESTDIR}/${OUTPUTFILES})
 233         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 234         add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 235 endmacro()
 236
 237 # To be call inside project_targets_populate macro
 238 macro(afb_genskel)
 239         if (OPENAPI_DEF)
 240                 add_custom_command(OUTPUT ${SD}/${OPENAPI_DEF}.h
 241                         DEPENDS ${SD}/${OPENAPI_DEF}.json
 242                         COMMAND afb-genskel ${SD}/${OPENAPI_DEF}.json > ${SD}/${OPENAPI_DEF}.h
 243                 )
 244                 add_custom_target("${TARGET}_GENSKEL" DEPENDS ${SD}/${OPENAPI_DEF}.h
 245                         COMMENT "Generating OpenAPI header file ${OPENAPI_DEF}.h")
 246                 add_dependencies(${TARGET} "${TARGET}_GENSKEL")
 247         else()
 248                 add_custom_command(OUTPUT ${SD}/${OUT}-apidef.h
 249                         DEPENDS ${SD}/${OUT}-apidef.json
 250                         COMMAND afb-genskel ${SD}/${OUT}-apidef.json > ${SD}/${OUT}-apidef.h
 251                 )
 252                 add_custom_target("${TARGET}_GENSKEL" DEPENDS ${SD}/${OUT}-apidef.h
 253                         COMMENT "Generating OpenAPI header file ${OUT}-apidef.h")
 254                 add_dependencies(${TARGET} "${TARGET}_GENSKEL")
 255         endif()
 256 endmacro()
 257
 258 # Pre-packaging
 259 macro(project_targets_populate)
 260         # Default Widget default directory
 261         set(BINDIR bin)
 262         set(ETCDIR etc)
 263         set(LIBDIR lib)
 264         set(HTTPDIR htdocs)
 265         set(DATADIR data)
 266         set(PACKAGE_BINDIR  ${PROJECT_PKG_BUILD_DIR}/${BINDIR})
 267         set(PACKAGE_ETCDIR  ${PROJECT_PKG_BUILD_DIR}/${ETCDIR})
 268         set(PACKAGE_LIBDIR  ${PROJECT_PKG_BUILD_DIR}/${LIBDIR})
 269         set(PACKAGE_HTTPDIR ${PROJECT_PKG_BUILD_DIR}/${HTTPDIR})
 270         set(PACKAGE_DATADIR ${PROJECT_PKG_BUILD_DIR}/${DATADIR})
 271
 272         add_custom_command(OUTPUT ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR}
 273                 COMMAND mkdir -p ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR})
 274         add_custom_target(populate DEPENDS ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR})
 275
 276         # Dirty trick to define a default INSTALL command for app-templates handled
 277         # targets
 278         INSTALL(CODE "execute_process(COMMAND make populate)")
 279         if(NO_DEDICATED_INSTALL_DIR)
 280                 INSTALL(DIRECTORY ${PROJECT_PKG_BUILD_DIR}/
 281                         DESTINATION ${CMAKE_INSTALL_PREFIX}
 282                 )
 283         else()
 284                 INSTALL(DIRECTORY ${PROJECT_PKG_BUILD_DIR}/
 285                         DESTINATION ${CMAKE_INSTALL_PREFIX}/${PROJECT_NAME}
 286                 )
 287         endif()
 288
 289         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 290         foreach(TARGET ${PROJECT_TARGETS})
 291                 # Declaration of a custom command that will populate widget tree with the target
 292                 set(POPULE_PACKAGE_TARGET "project_populate_${TARGET}")
 293                 get_target_property(T ${TARGET} LABELS)
 294
 295                 if(T)
 296                         get_target_property(P ${TARGET} PREFIX)
 297                         get_target_property(S ${TARGET} SUFFIX)
 298                         get_target_property(BD ${TARGET} BINARY_DIR)
 299                         get_target_property(SD ${TARGET} SOURCE_DIR)
 300                         get_target_property(OUT ${TARGET} OUTPUT_NAME)
 301
 302                         if(P MATCHES "NOTFOUND$")
 303                                 if (${T} STREQUAL "LIBRARY")
 304                                         set(P "lib")
 305                                 else()
 306                                         set(P "")
 307                                 endif()
 308                         endif()
 309
 310                         get_target_property(IMPPATH ${TARGET} IMPORTED_LOCATION)
 311                         if(${T} STREQUAL "LIBRARY")
 312                                 unset(BD)
 313                                 generate_one_populate_target(${IMPPATH} ${PACKAGE_LIBDIR})
 314                         elseif(${T} STREQUAL "PLUGIN")
 315                                 if(NOT S)
 316                                         set(S ".ctlso")
 317                                 endif()
 318                                 generate_one_populate_target(${P}${OUT}${S} "${PACKAGE_LIBDIR}/plugins")
 319                         elseif(${T} STREQUAL "BINDING")
 320                                 if(NOT S)
 321                                         set(S ".so")
 322                                 endif()
 323                                 list(APPEND BINDINGS_LIST "${P}${OUT}${S}")
 324                                 generate_one_populate_target(${P}${OUT}${S} ${PACKAGE_LIBDIR})
 325                         elseif(${T} STREQUAL "BINDINGV2")
 326                                 if(NOT S)
 327                                         set(S ".so")
 328                                 endif()
 329                                 afb_genskel()
 330                                 generate_one_populate_target(${P}${OUT}${S} ${PACKAGE_LIBDIR})
 331                         elseif(${T} STREQUAL "EXECUTABLE")
 332                                 if(NOT S)
 333                                         set(S "")
 334                                 endif()
 335                                 if(NOT OUT AND IMPPATH)
 336                                         unset(BD)
 337                                         generate_one_populate_target(${IMPPATH} ${PACKAGE_BINDIR})
 338                                 else()
 339                                         generate_one_populate_target(${P}${OUT}${S} ${PACKAGE_BINDIR})
 340                                 endif()
 341                         elseif(${T} STREQUAL "HTDOCS")
 342                                 generate_one_populate_target(${P}${OUT} ${PACKAGE_HTTPDIR})
 343                         elseif(${T} STREQUAL "DATA")
 344                                 generate_one_populate_target(${TARGET} ${PACKAGE_DATADIR})
 345                         elseif(${T} STREQUAL "BINDING-CONFIG")
 346                                 generate_one_populate_target(${TARGET} ${PACKAGE_ETCDIR})
 347                         endif()
 348                         elseif(${CMAKE_BUILD_TYPE} MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 349                                 MESSAGE("${Yellow}.. Warning: ${TARGET} ignored when packaging.${ColourReset}")
 350                 endif()
 351         endforeach()
 352 endmacro(project_targets_populate)
 353
 354 macro(remote_targets_populate)
 355         if (DEFINED ENV{RSYNC_TARGET})
 356                 set (RSYNC_TARGET $ENV{RSYNC_TARGET})
 357         endif()
 358         if (DEFINED ENV{RSYNC_PREFIX})
 359                 set (RSYNC_PREFIX $ENV{RSYNC_PREFIX})
 360         endif()
 361
 362         set(
 363                 REMOTE_LAUNCH "Test on target with: ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh"
 364                 CACHE STRING "Command to start ${PROJECT_NAME} on remote target ${RSYNC_TARGET}"
 365         )
 366
 367         if(NOT RSYNC_TARGET OR NOT RSYNC_PREFIX)
 368                 message ("${Yellow}.. Warning: RSYNC_TARGET RSYNC_PREFIX not defined 'make remote-target-populate' not instanciated${ColourReset}")
 369                 add_custom_target(remote-target-populate
 370                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make remote-target-populate'${ColourReset}"
 371                         COMMAND exit -1
 372                 )
 373         else()
 374                 set(BINDINGS_REGEX "not_set")
 375                 if(DEFINED BINDINGS_LIST)
 376                         list(LENGTH BINDINGS_LIST BINDINGS_LIST_LENGTH)
 377                         if(BINDINGS_LIST_LENGTH EQUAL 1)
 378                                 list(GET BINDINGS_LIST 0 BINDINGS_REGEX)
 379                                 string(APPEND BINDINGS_REGEX ".so")
 380                         elseif(BINDINGS_LIST_LENGTH GREATER 1)
 381                                 foreach(B IN LISTS BINDINGS_LIST)
 382                                         STRING(APPEND BINDINGS_STR "${B}|")
 383                                 endforeach()
 384                                         STRING(REGEX REPLACE "^(.*)\\|$" "(\\1).so" BINDINGS_REGEX ${BINDINGS_STR})
 385                         endif()
 386                 endif()
 387
 388                 configure_files_in_dir(${TEMPLATE_DIR})
 389                 configure_files_in_dir(${TEMPLATE_DIR})
 390
 391                 add_custom_target(remote-target-populate
 392                         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/*.sh
 393                         COMMAND rsync -e "ssh -o StrictHostKeyChecking=no -o UserKnownHostsFile=/dev/null" --archive --delete ${PROJECT_PKG_BUILD_DIR}/ ${RSYNC_TARGET}:${RSYNC_PREFIX}/${PROJECT_NAME}
 394                 )
 395
 396                 add_custom_command(TARGET remote-target-populate
 397                 POST_BUILD
 398                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --green --bold ${REMOTE_LAUNCH}
 399                 )
 400
 401                 add_dependencies(remote-target-populate populate)
 402         endif()
 403 endmacro(remote_targets_populate)
 404
 405 macro(wgt_package_build)
 406         if(NOT EXISTS ${WIDGET_CONFIG_TEMPLATE})
 407                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need a config.xml template: please specify WIDGET_CONFIG_TEMPLATE correctly.${ColourReset}")
 408         endif()
 409         if(NOT WIDGET_TYPE)
 410                 MESSAGE(FATAL_ERROR "WIDGET_TYPE must be set in your config.cmake.\neg.: set(WIDGET_TYPE application/vnd.agl.service)")
 411         endif()
 412         if(NOT DEFINED PROJECT_ICON)
 413                 if( ${WIDGET_TYPE} MATCHES "agl.native")
 414                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-native.png)
 415                 elseif( ${WIDGET_TYPE} MATCHES "agl.service")
 416                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-service.png)
 417                 elseif( ${WIDGET_TYPE} MATCHES "x-executable")
 418                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-qml.png)
 419                 elseif( ${WIDGET_TYPE} MATCHES "text/html")
 420                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-html5.png)
 421                 endif()
 422         elseif(EXISTS "${CMAKE_SOURCE_DIR}/${WIDGET_ICON}")
 423                 set(ICON_PATH "${CMAKE_SOURCE_DIR}/${WIDGET_ICON}")
 424         elseif(EXISTS "${WIDGET_ICON}")
 425                 set(ICON_PATH "${WIDGET_ICON}")
 426         else()
 427                 set(ICON_PATH ${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/wgt/icon-default.png)
 428         endif()
 429
 430         if(NOT WIDGET_ENTRY_POINT)
 431                 set(WIDGET_ENTRY_POINT lib)
 432         endif()
 433
 434         add_custom_command(OUTPUT ${PROJECT_PKG_BUILD_DIR}/config.xml
 435                 COMMAND ${CMAKE_COMMAND} -DINFILE=${WIDGET_CONFIG_TEMPLATE} -DOUTFILE=${PROJECT_PKG_BUILD_DIR}/config.xml -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 436                 COMMAND cp ${ICON_PATH} ${PROJECT_PKG_BUILD_DIR}/${PROJECT_ICON}
 437
 438         )
 439         add_custom_target(packaging_wgt DEPENDS ${PROJECT_PKG_BUILD_DIR}/config.xml)
 440
 441         # Fulup ??? copy any extra file in wgt/etc into populate package before building the widget
 442         file(GLOB PROJECT_CONF_FILES "${TEMPLATE_DIR}/etc/*")
 443         if(${PROJECT_CONF_FILES})
 444                 file(COPY "${TEMPLATE_DIR}/etc/*" DESTINATION ${PROJECT_PKG_BUILD_DIR}/etc/)
 445         endif(${PROJECT_CONF_FILES})
 446
 447         add_custom_command(OUTPUT ${PROJECT_NAME}.wgt
 448                 DEPENDS ${PROJECT_TARGETS}
 449                 COMMAND wgtpkg-pack -f -o ${PROJECT_NAME}.wgt ${PROJECT_PKG_BUILD_DIR}
 450         )
 451
 452         add_custom_target(widget DEPENDS ${PROJECT_NAME}.wgt)
 453         add_dependencies(widget populate packaging_wgt)
 454         set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}.wgt")
 455
 456         if(NOT RSYNC_TARGET)
 457                 message ("${Yellow}.. Warning: RSYNC_TARGET not defined 'make widget-target-install' not instanciated${ColourReset}")
 458                 add_custom_target(widget-target-install
 459                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make widget-target-install'${ColourReset}"
 460                         COMMAND exit -1
 461                 )
 462         else()
 463         configure_files_in_dir(${TEMPLATE_DIR})
 464         add_custom_target(widget-target-install
 465         DEPENDS widget
 466         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 467         COMMAND ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 468         )
 469 endif()
 470
 471         if(PACKAGE_MESSAGE)
 472         add_custom_command(TARGET widget
 473                 POST_BUILD
 474                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 475         endif()
 476 endmacro(wgt_package_build)
 477
 478 macro(rpm_package_build)
 479         add_custom_command(OUTPUT ${NPKG_PROJECT_NAME}.spec
 480                 DEPENDS ${PROJECT_TARGETS}
 481                                 archive
 482                                 packaging
 483                 COMMAND rpmbuild --define=\"%_sourcedir ${PROJECT_PKG_ENTRY_POINT}\" -ba  ${PROJECT_PKG_ENTRY_POINT}/${NPKG_PROJECT_NAME}.spec
 484         )
 485
 486         add_custom_target(rpm DEPENDS ${NPKG_PROJECT_NAME}.spec)
 487         add_dependencies(rpm populate packaging)
 488
 489         if(PACKAGE_MESSAGE)
 490         add_custom_command(TARGET rpm
 491                 POST_BUILD
 492                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 493         endif()
 494 endmacro(rpm_package_build)
 495
 496 macro(project_package_build)
 497         if(EXISTS ${TEMPLATE_DIR})
 498                 wgt_package_build()
 499         endif()
 500 endmacro(project_package_build)
 501
 502 macro(project_subdirs_add)
 503         set (ARGSLIST ${ARGN})
 504         list(LENGTH ARGSLIST ARGSNUM)
 505         if(${ARGSNUM} GREATER 0)
 506                 file(GLOB filelist "${ARGV0}")
 507         else()
 508         file(GLOB filelist "*")
 509         endif()
 510
 511         foreach(filename ${filelist})
 512                 if(EXISTS "${filename}/CMakeLists.txt")
 513                         add_subdirectory(${filename})
 514                 endif(EXISTS "${filename}/CMakeLists.txt")
 515         endforeach()
 516 endmacro(project_subdirs_add)
 517
 518 # Print developer helper message when build is done
 519 # -------------------------------------------------------
 520 macro(project_closing_msg)
 521         get_property(PROJECT_TARGETS_SET GLOBAL PROPERTY PROJECT_TARGETS SET)
 522         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 523         if(CLOSING_MESSAGE AND ${PROJECT_TARGETS_SET})
 524                 add_custom_target(${PROJECT_NAME}_build_done ALL
 525                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 526                 )
 527                 add_dependencies(${PROJECT_NAME}_build_done
 528                         ${PROJECT_TARGETS} populate)
 529         endif()
 530 endmacro()