src/CMakeLists.txt

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: José Bollo <jose.bollo@iot.bzh>
   5 #
   6 # Licensed under the Apache License, Version 2.0 (the "License");
   7 # you may not use this file except in compliance with the License.
   8 # You may obtain a copy of the License at
   9 #
  10 #     http://www.apache.org/licenses/LICENSE-2.0
  11 #
  12 # Unless required by applicable law or agreed to in writing, software
  13 # distributed under the License is distributed on an "AS IS" BASIS,
  14 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15 # See the License for the specific language governing permissions and
  16 # limitations under the License.
  17 ###########################################################################
  18
  19 cmake_minimum_required(VERSION 2.8)
  20
  21 ###########################################################################
  22
  23 link_libraries(-Wl,--as-needed -Wl,--gc-sections)
  24
  25 add_compile_options(-Wall -Wextra -Wconversion)
  26 add_compile_options(-Wno-unused-parameter) # frankly not using a parameter does it care?
  27 add_compile_options(-Werror=maybe-uninitialized)
  28 add_compile_options(-Werror=implicit-function-declaration)
  29 add_compile_options(-Wno-pointer-sign) # for XmlChar handling
  30 add_compile_options(-ffunction-sections -fdata-sections)
  31 add_compile_options(-Wl,--as-needed -Wl,--gc-sections)
  32 add_compile_options(-fPIC)
  33 #add_definitions(-DNDEBUG)
  34
  35 set(CMAKE_C_FLAGS_PROFILING    "-g -O0 -pg -Wp,-U_FORTIFY_SOURCE")
  36 set(CMAKE_C_FLAGS_DEBUG        "-g -O0 -ggdb -Wp,-U_FORTIFY_SOURCE")
  37 set(CMAKE_C_FLAGS_RELEASE      "-g -O2")
  38 set(CMAKE_C_FLAGS_CCOV         "-g -O2 --coverage")
  39
  40 ###########################################################################
  41
  42 include(FindPkgConfig)
  43
  44 pkg_check_modules(EXTRAS REQUIRED libxml-2.0 openssl xmlsec1 xmlsec1-openssl json-c)
  45 add_compile_options(${EXTRAS_CFLAGS})
  46 include_directories(${EXTRAS_INCLUDE_DIRS})
  47 link_libraries(${EXTRAS_LIBRARIES})
  48
  49 pkg_check_modules(libzip libzip>=0.11)
  50 if(libzip_FOUND AND USE_LIBZIP)
  51         add_compile_options(${libzip_CFLAGS})
  52         include_directories(${libzip_INCLUDE_DIRS})
  53         link_libraries(${libzip_LIBRARIES})
  54         add_definitions(-DUSE_LIBZIP=1)
  55 else()
  56         add_definitions(-DUSE_LIBZIP=0)
  57 endif()
  58
  59 ###########################################################################
  60
  61 if(SIMULATE_SECMGR)
  62         add_definitions(-DSIMULATE_SECURITY_MANAGER=1)
  63 else(SIMULATE_SECMGR)
  64         pkg_check_modules(SECMGR REQUIRED security-manager)
  65         add_compile_options(${SECMGR_CFLAGS})
  66         include_directories(${SECMGR_INCLUDE_DIRS})
  67         link_libraries(${SECMGR_LIBRARIES})
  68         add_definitions(-DSIMULATE_SECURITY_MANAGER=0)
  69 endif(SIMULATE_SECMGR)
  70
  71 if(SIMULATE_SMACK)
  72         add_definitions(-DSIMULATE_LIBSMACK=1)
  73 else(SIMULATE_SMACK)
  74         pkg_check_modules(SMACK REQUIRED libsmack)
  75         add_compile_options(${SMACK_CFLAGS})
  76         include_directories(${SMACK_INCLUDE_DIRS})
  77         link_libraries(${SMACK_LIBRARIES})
  78         add_definitions(-DSIMULATE_LIBSMACK=0)
  79 endif(SIMULATE_SMACK)
  80
  81 ###########################################################################
  82
  83 add_library(wgtpkg STATIC
  84         wgtpkg-base64.c
  85         wgtpkg-certs.c
  86         wgtpkg-digsig.c
  87         wgtpkg-files.c
  88         wgtpkg-install.c
  89         wgtpkg-permissions.c
  90         wgtpkg-uninstall.c
  91         wgtpkg-workdir.c
  92         wgtpkg-xmlsec.c
  93         wgtpkg-zip.c
  94         )
  95
  96 add_library(utils STATIC
  97         utils-dir.c
  98         utils-file.c
  99         utils-json.c
 100         verbose.c
 101         )
 102
 103 add_library(wgt STATIC
 104         wgt-config.c
 105         wgt-info.c
 106         wgt-strings.c
 107         wgt.c
 108         )
 109
 110 add_library(secwrp STATIC
 111         secmgr-wrap.c
 112         )
 113
 114 ###########################################################################
 115 # packaging tools
 116
 117 MESSAGE(STATUS "Creating packaging tools")
 118
 119 add_executable(wgtpkg-sign wgtpkg-sign.c)
 120 target_link_libraries(wgtpkg-sign wgtpkg utils)
 121
 122 add_executable(wgtpkg-pack wgtpkg-pack.c)
 123 target_link_libraries(wgtpkg-pack wgtpkg utils)
 124
 125 add_executable(wgtpkg-info wgtpkg-info.c)
 126 target_link_libraries(wgtpkg-info wgtpkg wgt utils)
 127
 128 add_executable(wgtpkg-installer wgtpkg-installer.c)
 129 target_link_libraries(wgtpkg-installer wgtpkg wgt secwrp utils)
 130
 131 install(TARGETS wgtpkg-sign wgtpkg-pack wgtpkg-info wgtpkg-installer DESTINATION ${CMAKE_INSTALL_BINDIR})
 132
 133 ###########################################################################
 134 # the targeted
 135
 136 pkg_check_modules(EXTRA2 libsystemd)
 137 if(EXTRA2_FOUND)
 138         add_compile_options(${EXTRA2_CFLAGS})
 139         include_directories(${EXTRA2_INCLUDE_DIRS})
 140         link_libraries(${EXTRA2_LIBRARIES})
 141
 142         add_library(utils2 STATIC
 143                 utils-jbus.c
 144                 )
 145
 146         add_library(afm STATIC
 147                 afm-db.c
 148                 afm-launch.c
 149                 afm-launch-mode.c
 150                 afm-run.c
 151                 )
 152
 153         ###########################################################################
 154         # the daemons
 155         MESSAGE(STATUS "Creating daemons")
 156
 157         add_executable(afm-user-daemon afm-user-daemon.c)
 158         target_link_libraries(afm-user-daemon afm secwrp wgt utils utils2)
 159         install(TARGETS afm-user-daemon DESTINATION ${CMAKE_INSTALL_BINDIR})
 160
 161         add_executable(afm-system-daemon afm-system-daemon.c)
 162         target_link_libraries(afm-system-daemon wgtpkg afm secwrp wgt utils utils2)
 163         install(TARGETS afm-system-daemon DESTINATION ${CMAKE_INSTALL_BINDIR})
 164
 165         ###########################################################################
 166         # the binding for afb
 167
 168         pkg_check_modules(afb afb-daemon)
 169         if(afb_FOUND)
 170                 message(STATUS "Creation afm-main-binding for AFB-DAEMON")
 171                 ###############################################################
 172                 #pkg_get_variable(afb_binding_install_dir afb-daemon binding_install_dir)
 173                 execute_process(
 174                         COMMAND pkg-config --variable binding_install_dir afb-daemon
 175                         OUTPUT_VARIABLE afb_binding_install_dir OUTPUT_STRIP_TRAILING_WHITESPACE
 176                 )
 177                 ###############################################################
 178                 add_library(afm-main-binding MODULE afm-main-binding.c)
 179                 target_compile_options(afm-main-binding PRIVATE ${afb_CFLAGS})
 180                 target_include_directories(afm-main-binding PRIVATE ${afb_INCLUDE_DIRS})
 181                 target_link_libraries(afm-main-binding utils utils2 ${afb_LIBRARIES})
 182                 set_target_properties(afm-main-binding PROPERTIES
 183                         PREFIX ""
 184                         LINK_FLAGS "-Wl,--version-script=${CMAKE_CURRENT_SOURCE_DIR}/afm-main-binding.export-map"
 185                 )
 186                 install(TARGETS afm-main-binding LIBRARY DESTINATION ${afb_binding_install_dir})
 187         else()
 188                 message(STATUS "Not creating the binding for AFB-DAEMON")
 189         endif()
 190
 191 endif(EXTRA2_FOUND)