src/CMakeLists.txt

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: José Bollo <jose.bollo@iot.bzh>
   5 #
   6 # Licensed under the Apache License, Version 2.0 (the "License");
   7 # you may not use this file except in compliance with the License.
   8 # You may obtain a copy of the License at
   9 #
  10 #     http://www.apache.org/licenses/LICENSE-2.0
  11 #
  12 # Unless required by applicable law or agreed to in writing, software
  13 # distributed under the License is distributed on an "AS IS" BASIS,
  14 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15 # See the License for the specific language governing permissions and
  16 # limitations under the License.
  17 ###########################################################################
  18
  19 cmake_minimum_required(VERSION 3.4.3)
  20
  21 ###########################################################################
  22
  23 link_libraries(-Wl,--as-needed -Wl,--gc-sections)
  24
  25 add_compile_options(-Wall -Wextra -Wconversion)
  26 add_compile_options(-Wno-unused-parameter) # frankly not using a parameter does it care?
  27 add_compile_options(-Werror=maybe-uninitialized)
  28 add_compile_options(-Werror=implicit-function-declaration)
  29 add_compile_options(-Wno-pointer-sign) # for XmlChar handling
  30 add_compile_options(-ffunction-sections -fdata-sections)
  31 add_compile_options(-Wl,--as-needed -Wl,--gc-sections)
  32 add_compile_options(-fPIC)
  33 #add_definitions(-DNDEBUG)
  34
  35 set(CMAKE_C_FLAGS_PROFILING    "-g -O0 -pg -Wp,-U_FORTIFY_SOURCE")
  36 set(CMAKE_C_FLAGS_DEBUG        "-g -O0 -ggdb -Wp,-U_FORTIFY_SOURCE")
  37 set(CMAKE_C_FLAGS_RELEASE      "-g -O2")
  38 set(CMAKE_C_FLAGS_CCOV         "-g -O2 --coverage")
  39
  40 ###########################################################################
  41
  42 include(FindPkgConfig)
  43
  44 pkg_check_modules(EXTRAS REQUIRED libxml-2.0 openssl xmlsec1 xmlsec1-openssl json-c)
  45 add_compile_options(${EXTRAS_CFLAGS})
  46 include_directories(${EXTRAS_INCLUDE_DIRS})
  47 link_libraries(${EXTRAS_LIBRARIES})
  48
  49 pkg_check_modules(libzip libzip>=0.11)
  50 if(libzip_FOUND AND USE_LIBZIP)
  51         add_compile_options(${libzip_CFLAGS})
  52         include_directories(${libzip_INCLUDE_DIRS})
  53         link_libraries(${libzip_LIBRARIES})
  54         add_definitions(-DUSE_LIBZIP=1)
  55 else()
  56         add_definitions(-DUSE_LIBZIP=0)
  57 endif()
  58
  59 pkg_check_modules(libsystemd libsystemd>=222)
  60 if(libsystemd_FOUND)
  61         add_compile_options(${libsystemd_CFLAGS})
  62         include_directories(${libsystemd_INCLUDE_DIRS})
  63         link_libraries(${libsystemd_LIBRARIES})
  64 else()
  65         add_definitions(-DNO_LIBSYSTEMD)
  66 endif()
  67
  68 ###########################################################################
  69
  70 if(SIMULATE_SECMGR)
  71         add_definitions(-DSIMULATE_SECURITY_MANAGER=1)
  72 else(SIMULATE_SECMGR)
  73         pkg_check_modules(SECMGR REQUIRED security-manager)
  74         add_compile_options(${SECMGR_CFLAGS})
  75         include_directories(${SECMGR_INCLUDE_DIRS})
  76         link_libraries(${SECMGR_LIBRARIES})
  77         add_definitions(-DSIMULATE_SECURITY_MANAGER=0)
  78 endif(SIMULATE_SECMGR)
  79
  80 if(SIMULATE_SMACK)
  81         add_definitions(-DSIMULATE_LIBSMACK=1)
  82 else(SIMULATE_SMACK)
  83         pkg_check_modules(SMACK REQUIRED libsmack)
  84         add_compile_options(${SMACK_CFLAGS})
  85         include_directories(${SMACK_INCLUDE_DIRS})
  86         link_libraries(${SMACK_LIBRARIES})
  87         add_definitions(-DSIMULATE_LIBSMACK=0)
  88 endif(SIMULATE_SMACK)
  89
  90 ###########################################################################
  91
  92 add_library(wgtpkg STATIC
  93         wgtpkg-base64.c
  94         wgtpkg-certs.c
  95         wgtpkg-digsig.c
  96         wgtpkg-files.c
  97         wgtpkg-install.c
  98         wgtpkg-mustach.c
  99         wgtpkg-permissions.c
 100         wgtpkg-uninstall.c
 101         wgtpkg-unit.c
 102         wgtpkg-workdir.c
 103         wgtpkg-xmlsec.c
 104         wgtpkg-zip.c
 105         )
 106
 107 add_library(utils STATIC
 108         mustach.c
 109         utils-dir.c
 110         utils-file.c
 111         utils-json.c
 112         utils-systemd.c
 113         verbose.c
 114         )
 115
 116 add_library(wgt STATIC
 117         wgt-config.c
 118         wgt-info.c
 119         wgt-strings.c
 120         wgt-json.c
 121         wgt.c
 122         )
 123
 124 add_library(secwrp STATIC
 125         secmgr-wrap.c
 126         )
 127
 128 add_library(afm STATIC
 129         afm-db.c
 130         afm-udb.c
 131         afm-launch.c
 132         afm-launch-mode.c
 133         afm-run.c
 134         afm-urun.c
 135         )
 136
 137 ###########################################################################
 138 # packaging tools
 139
 140 MESSAGE(STATUS "Creating packaging tools")
 141
 142 add_executable(wgtpkg-sign wgtpkg-sign.c)
 143 target_link_libraries(wgtpkg-sign wgtpkg utils)
 144
 145 add_executable(wgtpkg-pack wgtpkg-pack.c)
 146 target_link_libraries(wgtpkg-pack wgtpkg utils)
 147
 148 add_executable(wgtpkg-info wgtpkg-info.c)
 149 target_link_libraries(wgtpkg-info wgtpkg wgt utils)
 150
 151 add_executable(wgtpkg-installer wgtpkg-installer.c)
 152 target_link_libraries(wgtpkg-installer wgtpkg wgt secwrp utils)
 153
 154 install(TARGETS wgtpkg-sign wgtpkg-pack wgtpkg-info wgtpkg-installer DESTINATION ${CMAKE_INSTALL_BINDIR})
 155
 156 if(libsystemd_FOUND)
 157         ###########################################################################
 158         # the daemons
 159
 160         MESSAGE(STATUS "Creating daemons")
 161
 162         add_library(jbus STATIC utils-jbus.c)
 163
 164         add_executable(afm-user-daemon afm-user-daemon.c)
 165         target_link_libraries(afm-user-daemon afm secwrp wgt utils jbus)
 166         install(TARGETS afm-user-daemon DESTINATION ${CMAKE_INSTALL_BINDIR})
 167
 168         add_executable(afm-system-daemon afm-system-daemon.c)
 169         target_link_libraries(afm-system-daemon wgtpkg afm secwrp wgt utils jbus)
 170         install(TARGETS afm-system-daemon DESTINATION ${CMAKE_INSTALL_BINDIR})
 171
 172         ###########################################################################
 173         # the binding for afb
 174
 175         pkg_check_modules(AFB afb-daemon)
 176         if(AFB_FOUND)
 177                 message(STATUS "Creation afm-main-binding for AFB-DAEMON")
 178                 ###############################################################
 179                 pkg_get_variable(afb_binding_install_dir afb-daemon binding_install_dir)
 180                 ###############################################################
 181                 add_library(afm-main-binding MODULE afm-main-binding.c)
 182                 target_compile_options(afm-main-binding PRIVATE ${AFB_CFLAGS})
 183                 target_include_directories(afm-main-binding PRIVATE ${AFB_INCLUDE_DIRS})
 184                 target_link_libraries(afm-main-binding utils jbus ${AFB_LIBRARIES})
 185                 set_target_properties(afm-main-binding PROPERTIES
 186                         PREFIX ""
 187                         LINK_FLAGS "-Wl,--version-script=${CMAKE_CURRENT_SOURCE_DIR}/afm-main-binding.export-map"
 188                 )
 189                 install(TARGETS afm-main-binding LIBRARY DESTINATION ${afb_binding_install_dir})
 190         else()
 191                 message(STATUS "Not creating the binding for AFB-DAEMON")
 192         endif()
 193 endif()
 194
 195 ###########################################################################
 196 # the tests
 197
 198 add_subdirectory(tests)
 199