src/CMakeLists.txt

   1 ###########################################################################
   2 # Copyright 2015 IoT.bzh
   3 #
   4 # author: José Bollo <jose.bollo@iot.bzh>
   5 #
   6 # Licensed under the Apache License, Version 2.0 (the "License");
   7 # you may not use this file except in compliance with the License.
   8 # You may obtain a copy of the License at
   9 #
  10 #     http://www.apache.org/licenses/LICENSE-2.0
  11 #
  12 # Unless required by applicable law or agreed to in writing, software
  13 # distributed under the License is distributed on an "AS IS" BASIS,
  14 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15 # See the License for the specific language governing permissions and
  16 # limitations under the License.
  17 ###########################################################################
  18
  19 cmake_minimum_required(VERSION 2.8)
  20
  21 ###########################################################################
  22
  23 link_libraries(-Wl,--as-needed -Wl,--gc-sections)
  24
  25 add_compile_options(-Wall -Wextra -Wconversion)
  26 add_compile_options(-Wno-unused-parameter) # frankly not using a parameter does it care?
  27 add_compile_options(-Werror=maybe-uninitialized)
  28 add_compile_options(-Werror=implicit-function-declaration)
  29 add_compile_options(-Wno-pointer-sign) # for XmlChar handling
  30 add_compile_options(-ffunction-sections -fdata-sections)
  31 add_compile_options(-Wl,--as-needed -Wl,--gc-sections)
  32 add_compile_options(-fPIC)
  33 #add_definitions(-DNDEBUG)
  34
  35 set(CMAKE_C_FLAGS_PROFILING    "-g -O0 -pg -Wp,-U_FORTIFY_SOURCE")
  36 set(CMAKE_C_FLAGS_DEBUG        "-g -O0 -ggdb -Wp,-U_FORTIFY_SOURCE")
  37 set(CMAKE_C_FLAGS_RELEASE      "-g -O2")
  38 set(CMAKE_C_FLAGS_CCOV         "-g -O2 --coverage")
  39
  40 ###########################################################################
  41
  42 include(FindPkgConfig)
  43
  44 pkg_check_modules(EXTRAS REQUIRED libxml-2.0 openssl xmlsec1 xmlsec1-openssl)
  45 add_compile_options(${EXTRAS_CFLAGS})
  46 include_directories(${EXTRAS_INCLUDE_DIRS})
  47 link_libraries(${EXTRAS_LIBRARIES})
  48
  49 pkg_check_modules(libzip libzip>=0.11)
  50 if(libzip_FOUND)
  51         add_compile_options(${libzip_CFLAGS})
  52         include_directories(${libzip_INCLUDE_DIRS})
  53         link_libraries(${libzip_LIBRARIES})
  54         add_definitions(-DUSE_LIBZIP=1)
  55 else()
  56         add_definitions(-DUSE_LIBZIP=0)
  57 endif()
  58
  59 ###########################################################################
  60
  61 if(USE_SIMULATION)
  62         include_directories(simulation)
  63 else(USE_SIMULATION)
  64         pkg_check_modules(SECMGR REQUIRED security-manager)
  65         add_compile_options(${SECMGR_CFLAGS})
  66         include_directories(${SECMGR_INCLUDE_DIRS})
  67         link_libraries(${SECMGR_LIBRARIES})
  68 endif(USE_SIMULATION)
  69
  70 ###########################################################################
  71
  72 add_library(wgtpkg STATIC
  73         wgtpkg-base64.c
  74         wgtpkg-certs.c
  75         wgtpkg-digsig.c
  76         wgtpkg-files.c
  77         wgtpkg-install.c
  78         wgtpkg-permissions.c
  79         wgtpkg-uninstall.c
  80         wgtpkg-workdir.c
  81         wgtpkg-xmlsec.c
  82         wgtpkg-zip.c
  83         )
  84
  85 add_library(utils STATIC
  86         utils-dir.c
  87         verbose.c
  88         )
  89
  90 add_library(wgt STATIC
  91         wgt-config.c
  92         wgt-info.c
  93         wgt.c
  94         )
  95
  96 add_library(secwrp STATIC
  97         secmgr-wrap.c
  98         )
  99
 100 ###########################################################################
 101 # packaging tools
 102
 103 MESSAGE(STATUS "Creating packaging tools")
 104
 105 add_executable(wgtpkg-sign wgtpkg-sign.c)
 106 target_link_libraries(wgtpkg-sign wgtpkg utils)
 107
 108 add_executable(wgtpkg-pack wgtpkg-pack.c)
 109 target_link_libraries(wgtpkg-pack wgtpkg utils)
 110
 111 add_executable(wgtpkg-info wgtpkg-info.c)
 112 target_link_libraries(wgtpkg-info wgtpkg wgt utils)
 113
 114 add_executable(wgtpkg-installer wgtpkg-installer.c)
 115 target_link_libraries(wgtpkg-installer wgtpkg wgt secwrp utils)
 116
 117 install(TARGETS wgtpkg-sign wgtpkg-pack wgtpkg-info wgtpkg-installer DESTINATION ${CMAKE_INSTALL_BINDIR})
 118
 119 ###########################################################################
 120 # the targeted
 121
 122 pkg_check_modules(EXTRA2 json-c libsystemd)
 123 if(EXTRA2_FOUND)
 124         add_compile_options(${EXTRA2_CFLAGS})
 125         include_directories(${EXTRA2_INCLUDE_DIRS})
 126         link_libraries(${EXTRA2_LIBRARIES})
 127
 128         add_library(utils2 STATIC
 129                 utils-jbus.c
 130                 utils-json.c
 131                 )
 132
 133         add_library(afm STATIC
 134                 afm-db.c
 135                 afm-launch.c
 136                 afm-launch-mode.c
 137                 afm-run.c
 138                 )
 139
 140         ###########################################################################
 141         # the daemons
 142         MESSAGE(STATUS "Creating daemons")
 143
 144         add_executable(afm-user-daemon afm-user-daemon.c)
 145         target_link_libraries(afm-user-daemon afm secwrp wgt utils utils2)
 146         install(TARGETS afm-user-daemon DESTINATION ${CMAKE_INSTALL_BINDIR})
 147
 148         add_executable(afm-system-daemon afm-system-daemon.c)
 149         target_link_libraries(afm-system-daemon wgtpkg afm secwrp wgt utils utils2)
 150         install(TARGETS afm-system-daemon DESTINATION ${CMAKE_INSTALL_BINDIR})
 151
 152         ###########################################################################
 153         # the binding for afb
 154
 155         pkg_check_modules(afb afb-daemon)
 156         if(afb_FOUND)
 157                 message(STATUS "Creation afm-main-binding for AFB-DAEMON")
 158                 ###############################################################
 159                 #pkg_get_variable(afb_binding_install_dir afb-daemon binding_install_dir)
 160                 execute_process(
 161                         COMMAND pkg-config --variable binding_install_dir afb-daemon
 162                         OUTPUT_VARIABLE afb_binding_install_dir OUTPUT_STRIP_TRAILING_WHITESPACE
 163                 )
 164                 ###############################################################
 165                 add_library(afm-main-binding MODULE afm-main-binding.c)
 166                 target_compile_options(afm-main-binding PRIVATE ${afb_CFLAGS})
 167                 target_include_directories(afm-main-binding PRIVATE ${afb_INCLUDE_DIRS})
 168                 target_link_libraries(afm-main-binding utils utils2 ${afb_LIBRARIES})
 169                 set_target_properties(afm-main-binding PROPERTIES
 170                         PREFIX ""
 171                         LINK_FLAGS "-Wl,--version-script=${CMAKE_CURRENT_SOURCE_DIR}/afm-main-binding.export-map"
 172                 )
 173                 install(TARGETS afm-main-binding LIBRARY DESTINATION ${afb_binding_install_dir})
 174         else()
 175                 message(STATUS "Not creating the binding for AFB-DAEMON")
 176         endif()
 177
 178 endif(EXTRA2_FOUND)