src/CMakeLists.txt

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: José Bollo <jose.bollo@iot.bzh>
   5 #
   6 # Licensed under the Apache License, Version 2.0 (the "License");
   7 # you may not use this file except in compliance with the License.
   8 # You may obtain a copy of the License at
   9 #
  10 #     http://www.apache.org/licenses/LICENSE-2.0
  11 #
  12 # Unless required by applicable law or agreed to in writing, software
  13 # distributed under the License is distributed on an "AS IS" BASIS,
  14 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15 # See the License for the specific language governing permissions and
  16 # limitations under the License.
  17 ###########################################################################
  18
  19 cmake_minimum_required(VERSION 2.8)
  20
  21 ###########################################################################
  22
  23 link_libraries(-Wl,--as-needed -Wl,--gc-sections)
  24
  25 add_compile_options(-Wall -Wextra -Wconversion)
  26 add_compile_options(-Wno-unused-parameter) # frankly not using a parameter does it care?
  27 add_compile_options(-Werror=maybe-uninitialized)
  28 add_compile_options(-Werror=implicit-function-declaration)
  29 add_compile_options(-Wno-pointer-sign) # for XmlChar handling
  30 add_compile_options(-ffunction-sections -fdata-sections)
  31 add_compile_options(-Wl,--as-needed -Wl,--gc-sections)
  32 add_compile_options(-fPIC)
  33 #add_definitions(-DNDEBUG)
  34
  35 set(CMAKE_C_FLAGS_PROFILING    "-g -O0 -pg -Wp,-U_FORTIFY_SOURCE")
  36 set(CMAKE_C_FLAGS_DEBUG        "-g -O0 -ggdb -Wp,-U_FORTIFY_SOURCE")
  37 set(CMAKE_C_FLAGS_RELEASE      "-g -O2")
  38 set(CMAKE_C_FLAGS_CCOV         "-g -O2 --coverage")
  39
  40 ###########################################################################
  41
  42 include(FindPkgConfig)
  43
  44 pkg_check_modules(EXTRAS REQUIRED libxml-2.0 openssl xmlsec1 xmlsec1-openssl)
  45 add_compile_options(${EXTRAS_CFLAGS})
  46 include_directories(${EXTRAS_INCLUDE_DIRS})
  47 link_libraries(${EXTRAS_LIBRARIES})
  48
  49 pkg_check_modules(libzip libzip>=0.11)
  50 if(libzip_FOUND AND USE_LIBZIP)
  51         add_compile_options(${libzip_CFLAGS})
  52         include_directories(${libzip_INCLUDE_DIRS})
  53         link_libraries(${libzip_LIBRARIES})
  54         add_definitions(-DUSE_LIBZIP=1)
  55 else()
  56         add_definitions(-DUSE_LIBZIP=0)
  57 endif()
  58
  59 ###########################################################################
  60
  61 if(SIMULATE_SECMGR)
  62         add_definitions(-DSIMULATE_SECURITY_MANAGER=1)
  63 else(SIMULATE_SECMGR)
  64         pkg_check_modules(SECMGR REQUIRED security-manager)
  65         add_compile_options(${SECMGR_CFLAGS})
  66         include_directories(${SECMGR_INCLUDE_DIRS})
  67         link_libraries(${SECMGR_LIBRARIES})
  68         add_definitions(-DSIMULATE_SECURITY_MANAGER=0)
  69 endif(SIMULATE_SECMGR)
  70
  71 if(SIMULATE_SMACK)
  72         add_definitions(-DSIMULATE_LIBSMACK=1)
  73 else(SIMULATE_SMACK)
  74         pkg_check_modules(SMACK REQUIRED libsmack)
  75         add_compile_options(${SMACK_CFLAGS})
  76         include_directories(${SMACK_INCLUDE_DIRS})
  77         link_libraries(${SMACK_LIBRARIES})
  78         add_definitions(-DSIMULATE_LIBSMACK=0)
  79 endif(SIMULATE_SMACK)
  80
  81 ###########################################################################
  82
  83 add_library(wgtpkg STATIC
  84         wgtpkg-base64.c
  85         wgtpkg-certs.c
  86         wgtpkg-digsig.c
  87         wgtpkg-files.c
  88         wgtpkg-install.c
  89         wgtpkg-permissions.c
  90         wgtpkg-uninstall.c
  91         wgtpkg-workdir.c
  92         wgtpkg-xmlsec.c
  93         wgtpkg-zip.c
  94         )
  95
  96 add_library(utils STATIC
  97         utils-dir.c
  98         verbose.c
  99         )
 100
 101 add_library(wgt STATIC
 102         wgt-config.c
 103         wgt-info.c
 104         wgt-strings.c
 105         wgt.c
 106         )
 107
 108 add_library(secwrp STATIC
 109         secmgr-wrap.c
 110         )
 111
 112 ###########################################################################
 113 # packaging tools
 114
 115 MESSAGE(STATUS "Creating packaging tools")
 116
 117 add_executable(wgtpkg-sign wgtpkg-sign.c)
 118 target_link_libraries(wgtpkg-sign wgtpkg utils)
 119
 120 add_executable(wgtpkg-pack wgtpkg-pack.c)
 121 target_link_libraries(wgtpkg-pack wgtpkg utils)
 122
 123 add_executable(wgtpkg-info wgtpkg-info.c)
 124 target_link_libraries(wgtpkg-info wgtpkg wgt utils)
 125
 126 add_executable(wgtpkg-installer wgtpkg-installer.c)
 127 target_link_libraries(wgtpkg-installer wgtpkg wgt secwrp utils)
 128
 129 install(TARGETS wgtpkg-sign wgtpkg-pack wgtpkg-info wgtpkg-installer DESTINATION ${CMAKE_INSTALL_BINDIR})
 130
 131 ###########################################################################
 132 # the targeted
 133
 134 pkg_check_modules(EXTRA2 json-c libsystemd)
 135 if(EXTRA2_FOUND)
 136         add_compile_options(${EXTRA2_CFLAGS})
 137         include_directories(${EXTRA2_INCLUDE_DIRS})
 138         link_libraries(${EXTRA2_LIBRARIES})
 139
 140         add_library(utils2 STATIC
 141                 utils-jbus.c
 142                 utils-json.c
 143                 )
 144
 145         add_library(afm STATIC
 146                 afm-db.c
 147                 afm-launch.c
 148                 afm-launch-mode.c
 149                 afm-run.c
 150                 )
 151
 152         ###########################################################################
 153         # the daemons
 154         MESSAGE(STATUS "Creating daemons")
 155
 156         add_executable(afm-user-daemon afm-user-daemon.c)
 157         target_link_libraries(afm-user-daemon afm secwrp wgt utils utils2)
 158         install(TARGETS afm-user-daemon DESTINATION ${CMAKE_INSTALL_BINDIR})
 159
 160         add_executable(afm-system-daemon afm-system-daemon.c)
 161         target_link_libraries(afm-system-daemon wgtpkg afm secwrp wgt utils utils2)
 162         install(TARGETS afm-system-daemon DESTINATION ${CMAKE_INSTALL_BINDIR})
 163
 164         ###########################################################################
 165         # the binding for afb
 166
 167         pkg_check_modules(afb afb-daemon)
 168         if(afb_FOUND)
 169                 message(STATUS "Creation afm-main-binding for AFB-DAEMON")
 170                 ###############################################################
 171                 #pkg_get_variable(afb_binding_install_dir afb-daemon binding_install_dir)
 172                 execute_process(
 173                         COMMAND pkg-config --variable binding_install_dir afb-daemon
 174                         OUTPUT_VARIABLE afb_binding_install_dir OUTPUT_STRIP_TRAILING_WHITESPACE
 175                 )
 176                 ###############################################################
 177                 add_library(afm-main-binding MODULE afm-main-binding.c)
 178                 target_compile_options(afm-main-binding PRIVATE ${afb_CFLAGS})
 179                 target_include_directories(afm-main-binding PRIVATE ${afb_INCLUDE_DIRS})
 180                 target_link_libraries(afm-main-binding utils utils2 ${afb_LIBRARIES})
 181                 set_target_properties(afm-main-binding PROPERTIES
 182                         PREFIX ""
 183                         LINK_FLAGS "-Wl,--version-script=${CMAKE_CURRENT_SOURCE_DIR}/afm-main-binding.export-map"
 184                 )
 185                 install(TARGETS afm-main-binding LIBRARY DESTINATION ${afb_binding_install_dir})
 186         else()
 187                 message(STATUS "Not creating the binding for AFB-DAEMON")
 188         endif()
 189
 190 endif(EXTRA2_FOUND)