conf/unit/macros.inc

   1 dnl vim: set filetype=sysctl.conf.m4 syntax=sysctl.conf.m4:
   2 --------------------------------------------------------------------------------
   3 -- GLOBAL IMPORTANT DEFINITIONS
   4 --------------------------------------------------------------------------------
   5 define( `X_EMITS', 1)
   6 define( `X_DIVERTS', `divert(eval(-!X_EMITS()))')
   7 define( `X_PUSH_DIVERTS', `pushdef(`X_EMITS', eval(X_EMITS() && $1))X_DIVERTS()')
   8
   9 define( `X_IF', `pushdef(`X_COND', $1)X_PUSH_DIVERTS($1)')
  10 define( `X_ELSE', `popdef(`X_EMITS')X_PUSH_DIVERTS(eval(!X_COND))')
  11 define( `X_ELIF', `X_ELSE()X_IF($1)')
  12 define( `X_ENDIF', `popdef(`X_EMITS')popdef(`X_COND')X_DIVERTS()')
  13
  14 define( `IF', `pushdef(`ELSE',`X_ELSE()')pushdef(`ELIF',`X_ELIF($1)')pushdef(`ENDIF',`X_ENDIF()popdef(`ELSE',`ELIF',`ENDIF')')X_IF($1)')
  15 --------------------------------------------------------------------------------
  16 -- MUSTACH SPECIFIC DEFINITIONS
  17 --------------------------------------------------------------------------------
  18 define( `MUSTACH_ON', `ifelse(`$2',,,`{{#$1}}`$2'{{/$1}}')ifelse(`$3',,,`{{^$1}}`$3'{{/$1}}')')
  19 define( `MUSTACH_IF', `{{#$1}}pushdef(`ELSE',`{{/$1}}{{^$1}}')pushdef(`ENDIF',`{{/$1}}popdef(`ELSE',`ENDIF')')')
  20 define( `MUSTACH_IF_NOT', `{{^$1}}pushdef(`ELSE',`{{/$1}}{{#$1}}')pushdef(`ENDIF',`{{/$1}}popdef(`ELSE',`ENDIF')')')
  21 --------------------------------------------------------------------------------
  22 -- CONDITIONAL HELPERS
  23 --------------------------------------------------------------------------------
  24 define( `PERM', `@afm_prefix@permission:$1')
  25 define( `REQPERM', `required-permission.PERM($1)')
  26
  27 define( `ON_PERM', `MUSTACH_ON(REQPERM($1),$2,$3)')
  28 define( `ON_NOT_PERM', `MUSTACH_ON(REQPERM($1),$3,$2)')
  29 define( `IF_PERM', `MUSTACH_IF(REQPERM($1))')
  30 define( `IF_NOT_PERM', `MUSTACH_IF_NOT(REQPERM($1))')
  31
  32 define( `ON_CONTENT', `MUSTACH_ON(content.type=$1,$2,$3)')
  33 define( `IF_CONTENT', `MUSTACH_IF(content.type=$1)')
  34 define( `IF_NOT_CONTENT', `MUSTACH_IF_NOT(content.type=$1)')
  35
  36 define( `ON_VALUE', `MUSTACH_ON(value=$1,$2,$3)')
  37 define( `IF_VALUE', `MUSTACH_IF(value=$1)')
  38 define( `IF_NOT_VALUE', `MUSTACH_IF_NOT(value=$1)')
  39 --------------------------------------------------------------------------------
  40 -- AFM DEFINITION
  41 --------------------------------------------------------------------------------
  42 -- NOTE:
  43 --  when home screen will use real ids
  44 --  use TARGET={{:id}}--{{:ver}}--{{:#target}}
  45 --  instead of TARGET={{idaver}}{{^#target=main}}@{{:#target}}{{/#target=main}}
  46 --------------------------------------------------------------------------------
  47 define( `AFID', `{{:#metatarget.afid}}')
  48 define( `SMACKLABEL', `User::App::{{:id}}')
  49 define( `TARGET', `{{idaver}}{{^#target=main}}@{{:#target}}{{/#target=main}}')
  50 define( `NEWTARGET', `{{:id}}--{{:ver}}--{{:#target}}')
  51 define( `UNITSUFFIX', `ON_NOT_PERM(`:partner:scope-platform', `@%i')')
  52 define( `UNIT_NAME_BASE', `afm-ON_PERM(`:public:hidden', `service', `appli')-NEWTARGET')
  53 define( `UNIT_NAME_API_BASE', `afm-api-$1')
  54 define( `UNIT_NAME_API_SERVICE', `UNIT_NAME_API_BASE($1)UNITSUFFIX.service')
  55 define( `UNIT_NAME_API_SOCKET', `UNIT_NAME_API_BASE($1)UNITSUFFIX.socket')
  56 define( `UNIT_NAME_BINDING_BASE', `afm-link-$1')
  57 define( `UNIT_NAME_BINDING_SERVICE', `UNIT_NAME_BINDING_BASE($1)UNITSUFFIX.service')
  58
  59 define( `USER_RUN_DIR', `@afm_users_rundir@/%i')
  60 define( `DEBUGGING_DIR', `@afm_platform_rundir@/debug')
  61 define( `PLATFORM_RUN_DIR', `@afm_platform_rundir@')
  62
  63 define( `APP_DATA_DIR', `ON_PERM(`:partner:scope-platform', `@afm_scope_platform_dir@', `/home/%i/app-data')')
  64 define( `APP_WORK_DIR', `APP_DATA_DIR/{{:id}}')
  65 define( `RUN_DIR', `ON_PERM(`:partner:scope-platform', `PLATFORM_RUN_DIR', `USER_RUN_DIR')')
  66
  67 define( `API_PATH', `RUN_DIR/apis')
  68 define( `API_PATH_WS', `API_PATH/ws')
  69 define( `API_PATH_LINK', `API_PATH/link')
  70
  71 define( `PLATFORM_API_PATH', `PLATFORM_RUN_DIR/apis')
  72 define( `PLATFORM_API_PATH_WS', `PLATFORM_API_PATH/ws')
  73 define( `PLATFORM_API_PATH_LINK', `PLATFORM_API_PATH/link')
  74
  75 define( `USER_API_PATH', `USER_RUN_DIR/apis')
  76 define( `USER_API_PATH_WS', `USER_API_PATH/ws')
  77 define( `USER_API_PATH_LINK', `USER_API_PATH/link')
  78
  79 define( `LOCALUSERAPP', `ON_PERM(`:partner:scope-platform', `localuser---AFID', `localuser--AFID')')
  80 --------------------------------------------------------------------------------
  81 -- AGL_DEVEL SPECIFIC PARTS
  82 --------------------------------------------------------------------------------
  83 define( `ON_AGL_DEVEL', `ifdef(`AGL_DEVEL', $1, $2)')
  84 define( `ON_NOT_AGL_DEVEL', `ifdef(`AGL_DEVEL', $2, $1)')
  85 define( `IF_AGL_DEVEL', `IF(ON_AGL_DEVEL(1,0))')
  86 define( `IF_NOT_AGL_DEVEL', `IF(ON_AGL_DEVEL(0,1))')
  87 --------------------------------------------------------------------------------