conf/unit/generate-unit-conf/afm-unit

   1 divert(-1)
   2 dnl vim: set filetype=sysctl.conf.m4 syntax=sysctl.conf.m4:
   3 -----------------------------------------------------------------------
   4 -- Set the comment character of m4 to ; instead of #
   5 -- This is needed for substitution within lines starting with #
   6 changecom( ';')
   7
   8 -----------------------------------------------------------------------
   9 --
  10 define( `X_EMITS', 1)
  11 define( `X_DIVERTS', `divert(eval(-!X_EMITS()))')
  12 define( `X_PUSH_DIVERTS', `pushdef(`X_EMITS', eval(X_EMITS() && $1))X_DIVERTS()')
  13
  14 define( `X_IF', `pushdef(`X_COND', $1)X_PUSH_DIVERTS($1)')
  15 define( `X_ELSE', `popdef(`X_EMITS')X_PUSH_DIVERTS(eval(!X_COND))')
  16 define( `X_ELIF', `X_ELSE()X_IF($1)')
  17 define( `X_ENDIF', `popdef(`X_EMITS')popdef(`X_COND')X_DIVERTS()')
  18
  19 define( `IF', `pushdef(`ELSE',`X_ELSE()')pushdef(`ELIF',`X_ELIF($1)')pushdef(`ENDIF',`X_ENDIF()popdef(`ELSE',`ELIF',`ENDIF')')X_IF($1)')
  20
  21 -----------------------------------------------------------------------
  22 --
  23 define( `MUSTACH_ON', `ifelse(`$2',,,`{{#$1}}`$2'{{/$1}}')ifelse(`$3',,,`{{^$1}}`$3'{{/$1}}')')
  24 define( `MUSTACH_IF', `{{#$1}}pushdef(`ELSE',`{{/$1}}{{^$1}}')pushdef(`ENDIF',`{{/$1}}popdef(`ELSE',`ENDIF')')')
  25 define( `MUSTACH_IF_NOT', `{{^$1}}pushdef(`ELSE',`{{/$1}}{{#$1}}')pushdef(`ENDIF',`{{/$1}}popdef(`ELSE',`ENDIF')')')
  26
  27 -----------------------------------------------------------------------
  28 --
  29 define( `PERM', `urn:AGL:permission:$1')
  30 define( `REQPERM', `required-permission.PERM($1)')
  31
  32 define( `ON_PERM', `MUSTACH_ON(REQPERM($1),$2,$3)')
  33 define( `IF_PERM', `MUSTACH_IF(REQPERM($1))')
  34 define( `IF_NOT_PERM', `MUSTACH_IF_NOT(REQPERM($1))')
  35
  36 define( `ON_CONTENT', `MUSTACH_ON(content.type=$1,$2,$3)')
  37 define( `IF_CONTENT', `MUSTACH_IF(content.type=$1)')
  38 define( `IF_NOT_CONTENT', `MUSTACH_IF_NOT(content.type=$1)')
  39
  40 define( `ON_VALUE', `MUSTACH_ON(value=$1,$2,$3)')
  41 define( `IF_VALUE', `MUSTACH_IF(value=$1)')
  42 define( `IF_NOT_VALUE', `MUSTACH_IF_NOT(value=$1)')
  43
  44 -----------------------------------------------------------------------
  45 --
  46  when home screen will use real ids
  47  use TARGET={{:id}}--{{:ver}}--{{:#target}}
  48  instead of TARGET={{idaver}}{{^#target=main}}@{{:#target}}{{/#target=main}}
  49
  50 define( `TARGET', `{{idaver}}{{^#target=main}}@{{:#target}}{{/#target=main}}')
  51 define( `UNIT_NAME_BASE', `afm-ON_PERM(`:public:hidden', `service', `appli')-{{:id}}--{{:ver}}--{{:#target}}@')
  52 define( `UNIT_NAME_SERVICE', `UNIT_NAME_BASE%i.service')
  53 define( `UNIT_NAME_SOCKET_FOR', `afm-api-ws-$1@%i.socket')
  54 define( `APP_DATA_DIR', `/home/%i/app-data')
  55 define( `USER_RUN_DIR', `@afm_users_rundir@/%i')
  56 define( `DEBUGGING_DIR', `@afm_platform_rundir@/debug')
  57
  58 -----------------------------------------------------------------------
  59 --
  60 define( `ON_AGL_DEVEL', `ifdef(`AGL_DEVEL', $1, $2)')
  61 define( `IF_AGL_DEVEL', `IF(ON_AGL_DEVEL(1,0))')
  62
  63 divert(0)dnl
  64 ;---------------------------------------------------------------------------------
  65 ; File:
  66 ;
  67 ;    afm-unit.conf
  68 ;
  69 ; Mode:
  70 ;
  71 ;    ON_AGL_DEVEL(DEVEL, RELEASE)
  72 ;
  73 ; Role:
  74 ;
  75 ;    Configure how installation of widget produces unit files for systemd
  76 ;
  77 ; Processing and format:
  78 ;
  79 ;    1. File load
  80 ;
  81 ;           Lines beginning with ; are firstly removed
  82 ;
  83 ;    2. File instantiation
  84 ;
  85 ;           Mustache (extended) substitutions are applied using JSON
  86 ;           data deduced from config.xml file of the widget.
  87 ;
  88 ;    3. Extraction of units
  89 ;
  90 ;           Extract produced units, pack it (remove empty lines and directives)
  91 ;
  92 ; Directives:
  93 ;
  94 ;    Any directive occupy one whole line starting with %
  95 ;
  96 ;     - %nl
  97 ;
  98 ;             produce an empty line at the end
  99 ;
 100 ;     - %begin systemd-unit
 101 ;     - %end systemd-unit
 102 ;
 103 ;             delimit the produced unit
 104 ;
 105 ;     - %systemd-unit user
 106 ;     - %systemd-unit system
 107 ;
 108 ;             tells the kind of unit (user/system)
 109 ;
 110 ;     - %systemd-unit service NAME
 111 ;     - %systemd-unit socket NAME
 112 ;
 113 ;             gives the name and type of the unit
 114 ;
 115 ;     - %systemd-unit wanted-by NAME
 116 ;
 117 ;             tells to install a link to unit in the wants of NAME
 118 ;
 119 ; Setting variables:
 120 ;
 121 ;    AFM uses the feature of systemd that completely ignores options prefixed
 122 ;    with X-
 123 ;
 124 ;    Consequently, options starting with X-AFM- are recorded as public data
 125 ;    about the application and options starting starting with X-AFM-- are
 126 ;    recorded as private data.
 127 ;
 128 ;    Examples:
 129 ;
 130 ;        X-AFM-description={{description}}
 131 ;
 132 ;              Records the description of the unit in the field "description"
 133 ;              of both the public and private object describing the unit.
 134 ;
 135 ;        X-AFM--wgtdir={{:#metadata.install-dir}}
 136 ;
 137 ;              Records the installation directory path in the field "wgtdir"
 138 ;              of the private object only.
 139 ;
 140 ;---------------------------------------------------------------------------------
 141 {{#targets}}
 142
 143 include(service.inc)
 144
 145 include(provided.inc)
 146
 147 {{/targets}}
 148 ;---------------------------------------------------------------------------------
 149 ; End of file afm-unit.conf mode ON_AGL_DEVEL(DEVEL, RELEASE)
 150 ;---------------------------------------------------------------------------------