conf/generate-unit-conf/afm-unit

   1 divert(-1)
   2 -----------------------------------------------------------------------
   3 -- Set the comment character of m4 to ; instead of #
   4 -- This is needed for substitution within lines starting with #
   5 changecom( ';')
   6
   7 -----------------------------------------------------------------------
   8 --
   9 define( `X_EMITS', 1)
  10 define( `X_DIVERTS', `divert(eval(-!X_EMITS()))')
  11 define( `X_PUSH_DIVERTS', `pushdef(`X_EMITS', eval(X_EMITS() && $1))X_DIVERTS()')
  12
  13 define( `X_IF', `pushdef(`X_COND', $1)X_PUSH_DIVERTS($1)')
  14 define( `X_ELSE', `popdef(`X_EMITS')X_PUSH_DIVERTS(eval(!X_COND))')
  15 define( `X_ELIF', `X_ELSE()X_IF($1)')
  16 define( `X_ENDIF', `popdef(`X_EMITS')popdef(`X_COND')X_DIVERTS()')
  17
  18 define( `IF', `pushdef(`ELSE',`X_ELSE()')pushdef(`ELIF',`X_ELIF($1)')pushdef(`ENDIF',`X_ENDIF()popdef(`ELSE',`ELIF',`ENDIF')')X_IF($1)')
  19
  20 -----------------------------------------------------------------------
  21 --
  22 define( `MUSTACH_ON', `ifelse(`$2',,,`{{#$1}}`$2'{{/$1}}')ifelse(`$3',,,`{{^$1}}`$3'{{/$1}}')')
  23 define( `MUSTACH_IF', `{{#$1}}pushdef(`ELSE',`{{/$1}}{{^$1}}')pushdef(`ENDIF',`{{/$1}}popdef(`ELSE',`ENDIF')')')
  24 define( `MUSTACH_IF_NOT', `{{^$1}}pushdef(`ELSE',`{{/$1}}{{#$1}}')pushdef(`ENDIF',`{{/$1}}popdef(`ELSE',`ENDIF')')')
  25
  26 -----------------------------------------------------------------------
  27 --
  28 define( `PERM', `urn:AGL:permission:$1')
  29 define( `REQPERM', `required-permission.PERM($1)')
  30
  31 define( `ON_PERM', `MUSTACH_ON(REQPERM($1),$2,$3)')
  32 define( `IF_PERM', `MUSTACH_IF(REQPERM($1))')
  33 define( `IF_NOT_PERM', `MUSTACH_IF_NOT(REQPERM($1))')
  34
  35 define( `ON_CONTENT', `MUSTACH_ON(content.type=$1,$2,$3)')
  36 define( `IF_CONTENT', `MUSTACH_IF(content.type=$1)')
  37 define( `IF_NOT_CONTENT', `MUSTACH_IF_NOT(content.type=$1)')
  38
  39 define( `ON_VALUE', `MUSTACH_ON(value=$1,$2,$3)')
  40 define( `IF_VALUE', `MUSTACH_IF(value=$1)')
  41 define( `IF_NOT_VALUE', `MUSTACH_IF_NOT(value=$1)')
  42
  43 -----------------------------------------------------------------------
  44 --
  45 define( `TARGET', `{{idaver}}{{^#target=main}}@{{:#target}}{{/#target=main}}')
  46 define( `UNIT_NAME_BASE', `afm-ON_PERM(`:public:hidden', `service', `appli')-{{:id}}--{{:ver}}--{{:#target}}')
  47 define( `UNIT_NAME_SERVICE', `UNIT_NAME_BASE%i.service')
  48 define( `UNIT_NAME_SOCKET_FOR', `afm-api-ws-$1@%i.socket')
  49
  50 -----------------------------------------------------------------------
  51 --
  52 define( `ON_AGL_DEVEL', `ifdef(`AGL_DEVEL', $1, $2)')
  53 define( `IF_AGL_DEVEL', `IF(ON_AGL_DEVEL(1,0))')
  54
  55 divert(0)dnl
  56 ;---------------------------------------------------------------------------------
  57 ; File:
  58 ;
  59 ;    afm-unit.conf
  60 ;
  61 ; Mode:
  62 ;
  63 ;    ON_AGL_DEVEL(DEVEL, RELEASE)
  64 ;
  65 ; Role:
  66 ;
  67 ;    Configure how installation of widget produces unit files for systemd
  68 ;
  69 ; Processing and format:
  70 ;
  71 ;    1. File load
  72 ;
  73 ;           Lines beginning with ; are firstly removed
  74 ;
  75 ;    2. File instantiation
  76 ;
  77 ;           Mustache (extended) substitutions are applied using JSON
  78 ;           data deduced from config.xml file of the widget.
  79 ;
  80 ;    3. Extraction of units
  81 ;
  82 ;           Extract produced units, pack it (remove empty lines and directives)
  83 ;
  84 ; Directives:
  85 ;
  86 ;    Any directive occupy one whole line starting with %
  87 ;
  88 ;     - %nl
  89 ;
  90 ;             produce an empty line at the end
  91 ;
  92 ;     - %begin systemd-unit
  93 ;     - %end systemd-unit
  94 ;
  95 ;             delimit the produced unit
  96 ;
  97 ;     - %systemd-unit user
  98 ;     - %systemd-unit system
  99 ;
 100 ;             tells the kind of unit (user/system)
 101 ;
 102 ;     - %systemd-unit service NAME
 103 ;     - %systemd-unit socket NAME
 104 ;
 105 ;             gives the name and type of the unit
 106 ;
 107 ;     - %systemd-unit wanted-by NAME
 108 ;
 109 ;             tells to install a link to unit in the wants of NAME
 110 ;
 111 ; Setting variables:
 112 ;
 113 ;    AFM uses the feature of systemd that completely ignores options prefixed
 114 ;    with X-
 115 ;
 116 ;    Consequently, options starting with X-AFM- are recorded as public data
 117 ;    about the application and options starting starting with X-AFM-- are
 118 ;    recorded as private data.
 119 ;
 120 ;    Examples:
 121 ;
 122 ;        X-AFM-description={{description}}
 123 ;
 124 ;              Records the description of the unit in the field "description"
 125 ;              of both the public and private object describing the unit.
 126 ;
 127 ;        X-AFM--wgtdir={{:#metadata.install-dir}}
 128 ;
 129 ;              Records the installation directory path in the field "wgtdir"
 130 ;              of the private object only.
 131 ;
 132 ;---------------------------------------------------------------------------------
 133 {{#targets}}
 134
 135 include(service.inc)
 136
 137 include(provided.inc)
 138
 139 {{/targets}}
 140 ;---------------------------------------------------------------------------------
 141 ; End of file afm-unit.conf mode ON_AGL_DEVEL(DEVEL, RELEASE)
 142 ;---------------------------------------------------------------------------------