src/CMakeLists.txt

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: José Bollo <jose.bollo@iot.bzh>
   5 #
   6 # Licensed under the Apache License, Version 2.0 (the "License");
   7 # you may not use this file except in compliance with the License.
   8 # You may obtain a copy of the License at
   9 #
  10 #     http://www.apache.org/licenses/LICENSE-2.0
  11 #
  12 # Unless required by applicable law or agreed to in writing, software
  13 # distributed under the License is distributed on an "AS IS" BASIS,
  14 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15 # See the License for the specific language governing permissions and
  16 # limitations under the License.
  17 ###########################################################################
  18
  19 if (CMAKE_C_COMPILER_VERSION VERSION_LESS 4.9)
  20     message(FATAL_ERROR "Require at least gcc-4.9")
  21 endif(CMAKE_C_COMPILER_VERSION VERSION_LESS 4.9)
  22
  23 INCLUDE(FindPkgConfig)
  24
  25 ADD_DEFINITIONS(-DBINDING_INSTALL_DIR="${binding_install_dir}")
  26 # Always add INFER_EXTENSION (more details in afb-hreq.c)
  27 ADD_DEFINITIONS(-DINFER_EXTENSION)
  28
  29 CHECK_INCLUDE_FILES(magic.h HAVE_MAGIC_H)
  30 CHECK_LIBRARY_EXISTS(magic magic_load "" HAVE_LIBMAGIC_SO)
  31 IF(HAVE_MAGIC_H)
  32   IF(HAVE_LIBMAGIC_SO)
  33     SET(HAVE_LIBMAGIC "1")
  34   ENDIF(HAVE_LIBMAGIC_SO)
  35 ENDIF(HAVE_MAGIC_H)
  36
  37 IF(NOT HAVE_LIBMAGIC)
  38   MESSAGE(FATAL_ERROR "\"magic.h\" or \"libmagic.so\" missing.
  39     Please install the \"file-devel\" or \"libmagic-dev\" package !")
  40 ENDIF(NOT HAVE_LIBMAGIC)
  41 ADD_DEFINITIONS(-DUSE_MAGIC_MIME_TYPE)
  42
  43 PKG_CHECK_MODULES(libsystemd REQUIRED libsystemd>=222)
  44 PKG_CHECK_MODULES(libmicrohttpd REQUIRED libmicrohttpd>=0.9.48)
  45 PKG_CHECK_MODULES(openssl REQUIRED openssl)
  46 PKG_CHECK_MODULES(uuid REQUIRED uuid)
  47
  48 INCLUDE_DIRECTORIES(
  49         ${include_dirs}
  50         ${libsystemd_INCLUDE_DIRS}
  51         ${libmicrohttpd_INCLUDE_DIRS}
  52         ${uuid_INCLUDE_DIRS}
  53         ${openssl_INCLUDE_DIRS}
  54 )
  55
  56 ADD_LIBRARY(afb-lib STATIC
  57         afb-api-dbus.c
  58         afb-api-so.c
  59         afb-api-ws.c
  60         afb-apis.c
  61         afb-common.c
  62         afb-config.c
  63         afb-context.c
  64         afb-evt.c
  65         afb-hook.c
  66         afb-hreq.c
  67         afb-hsrv.c
  68         afb-hswitch.c
  69         afb-method.c
  70         afb-msg-json.c
  71         afb-session.c
  72         afb-sig-handler.c
  73         afb-svc.c
  74         afb-subcall.c
  75         afb-thread.c
  76         afb-websock.c
  77         afb-ws-client.c
  78         afb-ws-json1.c
  79         afb-ws.c
  80         afb-wsj1.c
  81         locale-root.c
  82         verbose.c
  83         websock.c
  84 )
  85
  86 ###########################################
  87 # build and install afb-daemon
  88 ###########################################
  89 ADD_EXECUTABLE(afb-daemon main.c)
  90 TARGET_LINK_LIBRARIES(afb-daemon
  91         afb-lib
  92         ${link_libraries}
  93         ${libsystemd_LIBRARIES}
  94         ${libmicrohttpd_LIBRARIES}
  95         ${uuid_LIBRARIES}
  96         ${openssl_LIBRARIES}
  97         -lmagic
  98         -ldl
  99         -lrt
 100 )
 101 INSTALL(TARGETS afb-daemon
 102         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 103
 104 ###########################################
 105 # build and install libafbwsc
 106 ###########################################
 107 ADD_LIBRARY(afbwsc SHARED afb-ws.c afb-ws-client.c afb-wsj1.c websock.c)
 108 SET_TARGET_PROPERTIES(afbwsc PROPERTIES
 109         VERSION ${LIBAFBWSC_VERSION}
 110         SOVERSION ${LIBAFBWSC_SOVERSION})
 111 TARGET_LINK_LIBRARIES(afbwsc
 112         ${libsystemd_LIBRARIES}
 113         -Wl,--version-script=${CMAKE_CURRENT_SOURCE_DIR}/export-afbwsc.map
 114         -Wl,--as-needed
 115         -Wl,--gc-sections
 116 )
 117 INSTALL(TARGETS afbwsc LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
 118 INSTALL(FILES afb-wsj1.h afb-ws-client.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/afb)
 119
 120 ###########################################
 121 # build and install afb-client-demo
 122 ###########################################
 123 ADD_EXECUTABLE(afb-client-demo afb-client-demo.c)
 124 TARGET_LINK_LIBRARIES(afb-client-demo
 125         afbwsc
 126         ${link_libraries}
 127         ${libsystemd_LIBRARIES}
 128 )
 129 INSTALL(TARGETS afb-client-demo
 130         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 131
 132