src/CMakeLists.txt

   1 if (CMAKE_C_COMPILER_VERSION VERSION_LESS 4.9)
   2     message(FATAL_ERROR "Require at least gcc-4.9")
   3 endif(CMAKE_C_COMPILER_VERSION VERSION_LESS 4.9)
   4
   5 INCLUDE(FindPkgConfig)
   6
   7 ADD_DEFINITIONS(-DBINDING_INSTALL_DIR="${binding_install_dir}")
   8
   9 CHECK_INCLUDE_FILES(magic.h HAVE_MAGIC_H)
  10 CHECK_LIBRARY_EXISTS(magic magic_load "" HAVE_LIBMAGIC_SO)
  11 IF(HAVE_MAGIC_H)
  12   IF(HAVE_LIBMAGIC_SO)
  13     SET(HAVE_LIBMAGIC "1")
  14   ENDIF(HAVE_LIBMAGIC_SO)
  15 ENDIF(HAVE_MAGIC_H)
  16
  17 IF(NOT HAVE_LIBMAGIC)
  18   MESSAGE(FATAL_ERROR "\"magic.h\" or \"libmagic.so\" missing.
  19     Please install the \"file-devel\" or \"libmagic-dev\" package !")
  20 ENDIF(NOT HAVE_LIBMAGIC)
  21
  22 PKG_CHECK_MODULES(libsystemd REQUIRED libsystemd>=222)
  23 PKG_CHECK_MODULES(libmicrohttpd REQUIRED libmicrohttpd>=0.9.48)
  24 PKG_CHECK_MODULES(openssl REQUIRED openssl)
  25 PKG_CHECK_MODULES(uuid REQUIRED uuid)
  26
  27 INCLUDE_DIRECTORIES(
  28         ${include_dirs}
  29         ${libsystemd_INCLUDE_DIRS}
  30         ${libmicrohttpd_INCLUDE_DIRS}
  31         ${uuid_INCLUDE_DIRS}
  32         ${openssl_INCLUDE_DIRS}
  33 )
  34
  35 ADD_LIBRARY(afb-lib STATIC
  36         afb-api-dbus.c
  37         afb-api-so.c
  38         afb-api-ws.c
  39         afb-apis.c
  40         afb-common.c
  41         afb-context.c
  42         afb-evt.c
  43         afb-hook.c
  44         afb-hreq.c
  45         afb-hsrv.c
  46         afb-hswitch.c
  47         afb-method.c
  48         afb-msg-json.c
  49         afb-sig-handler.c
  50         afb-svc.c
  51         afb-subcall.c
  52         afb-thread.c
  53         afb-websock.c
  54         afb-ws-client.c
  55         afb-ws-json1.c
  56         afb-ws.c
  57         afb-wsj1.c
  58         locale-root.c
  59         session.c
  60         verbose.c
  61         websock.c
  62 )
  63
  64 ###########################################
  65 # build and install afb-daemon
  66 ###########################################
  67 ADD_EXECUTABLE(afb-daemon main.c)
  68 TARGET_LINK_LIBRARIES(afb-daemon
  69         afb-lib
  70         ${link_libraries}
  71         ${libsystemd_LIBRARIES}
  72         ${libmicrohttpd_LIBRARIES}
  73         ${uuid_LIBRARIES}
  74         ${openssl_LIBRARIES}
  75         -lmagic
  76         -ldl
  77         -lrt
  78 )
  79 INSTALL(TARGETS afb-daemon
  80         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
  81
  82 ###########################################
  83 # build and install libafbwsc
  84 ###########################################
  85 ADD_LIBRARY(afbwsc SHARED afb-ws.c afb-ws-client.c afb-wsj1.c websock.c)
  86 SET_TARGET_PROPERTIES(afbwsc PROPERTIES
  87         VERSION ${LIBAFBWSC_VERSION}
  88         SOVERSION ${LIBAFBWSC_SOVERSION})
  89 TARGET_LINK_LIBRARIES(afbwsc
  90         ${libsystemd_LIBRARIES}
  91         -Wl,--version-script=${CMAKE_CURRENT_SOURCE_DIR}/export-afbwsc.map
  92         -Wl,--as-needed
  93         -Wl,--gc-sections
  94 )
  95 INSTALL(TARGETS afbwsc LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
  96 INSTALL(FILES afb-wsj1.h afb-ws-client.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/afb)
  97
  98 ###########################################
  99 # build and install afb-client-demo
 100 ###########################################
 101 ADD_EXECUTABLE(afb-client-demo afb-client-demo.c)
 102 TARGET_LINK_LIBRARIES(afb-client-demo
 103         afbwsc
 104         ${link_libraries}
 105         ${libsystemd_LIBRARIES}
 106 )
 107 INSTALL(TARGETS afb-client-demo
 108         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 109
 110