src/CMakeLists.txt

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: José Bollo <jose.bollo@iot.bzh>
   5 #
   6 # Licensed under the Apache License, Version 2.0 (the "License");
   7 # you may not use this file except in compliance with the License.
   8 # You may obtain a copy of the License at
   9 #
  10 #     http://www.apache.org/licenses/LICENSE-2.0
  11 #
  12 # Unless required by applicable law or agreed to in writing, software
  13 # distributed under the License is distributed on an "AS IS" BASIS,
  14 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15 # See the License for the specific language governing permissions and
  16 # limitations under the License.
  17 ###########################################################################
  18
  19 if (CMAKE_C_COMPILER_VERSION VERSION_LESS 4.9)
  20     message(FATAL_ERROR "Require at least gcc-4.9")
  21 endif(CMAKE_C_COMPILER_VERSION VERSION_LESS 4.9)
  22
  23 INCLUDE(FindPkgConfig)
  24
  25 ADD_DEFINITIONS(-DBINDING_INSTALL_DIR="${binding_install_dir}")
  26 ADD_DEFINITIONS(-DINFER_EXTENSION)
  27
  28 CHECK_INCLUDE_FILES(magic.h HAVE_MAGIC_H)
  29 CHECK_LIBRARY_EXISTS(magic magic_load "" HAVE_LIBMAGIC_SO)
  30 IF(HAVE_MAGIC_H)
  31   IF(HAVE_LIBMAGIC_SO)
  32     SET(HAVE_LIBMAGIC "1")
  33   ENDIF(HAVE_LIBMAGIC_SO)
  34 ENDIF(HAVE_MAGIC_H)
  35
  36 IF(NOT HAVE_LIBMAGIC)
  37   MESSAGE(FATAL_ERROR "\"magic.h\" or \"libmagic.so\" missing.
  38     Please install the \"file-devel\" or \"libmagic-dev\" package !")
  39 ENDIF(NOT HAVE_LIBMAGIC)
  40 ADD_DEFINITIONS(-DUSE_MAGIC_MIME_TYPE)
  41
  42 PKG_CHECK_MODULES(libsystemd REQUIRED libsystemd>=222)
  43 PKG_CHECK_MODULES(libmicrohttpd REQUIRED libmicrohttpd>=0.9.48)
  44 PKG_CHECK_MODULES(openssl REQUIRED openssl)
  45 PKG_CHECK_MODULES(uuid REQUIRED uuid)
  46
  47 INCLUDE_DIRECTORIES(
  48         ${include_dirs}
  49         ${libsystemd_INCLUDE_DIRS}
  50         ${libmicrohttpd_INCLUDE_DIRS}
  51         ${uuid_INCLUDE_DIRS}
  52         ${openssl_INCLUDE_DIRS}
  53 )
  54
  55 ADD_LIBRARY(afb-lib STATIC
  56         afb-api-dbus.c
  57         afb-api-so.c
  58         afb-api-ws.c
  59         afb-apis.c
  60         afb-common.c
  61         afb-config.c
  62         afb-context.c
  63         afb-evt.c
  64         afb-hook.c
  65         afb-hreq.c
  66         afb-hsrv.c
  67         afb-hswitch.c
  68         afb-method.c
  69         afb-msg-json.c
  70         afb-session.c
  71         afb-sig-handler.c
  72         afb-svc.c
  73         afb-subcall.c
  74         afb-thread.c
  75         afb-websock.c
  76         afb-ws-client.c
  77         afb-ws-json1.c
  78         afb-ws.c
  79         afb-wsj1.c
  80         locale-root.c
  81         verbose.c
  82         websock.c
  83 )
  84
  85 ###########################################
  86 # build and install afb-daemon
  87 ###########################################
  88 ADD_EXECUTABLE(afb-daemon main.c)
  89 TARGET_LINK_LIBRARIES(afb-daemon
  90         afb-lib
  91         ${link_libraries}
  92         ${libsystemd_LIBRARIES}
  93         ${libmicrohttpd_LIBRARIES}
  94         ${uuid_LIBRARIES}
  95         ${openssl_LIBRARIES}
  96         -lmagic
  97         -ldl
  98         -lrt
  99 )
 100 INSTALL(TARGETS afb-daemon
 101         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 102
 103 ###########################################
 104 # build and install libafbwsc
 105 ###########################################
 106 ADD_LIBRARY(afbwsc SHARED afb-ws.c afb-ws-client.c afb-wsj1.c websock.c)
 107 SET_TARGET_PROPERTIES(afbwsc PROPERTIES
 108         VERSION ${LIBAFBWSC_VERSION}
 109         SOVERSION ${LIBAFBWSC_SOVERSION})
 110 TARGET_LINK_LIBRARIES(afbwsc
 111         ${libsystemd_LIBRARIES}
 112         -Wl,--version-script=${CMAKE_CURRENT_SOURCE_DIR}/export-afbwsc.map
 113         -Wl,--as-needed
 114         -Wl,--gc-sections
 115 )
 116 INSTALL(TARGETS afbwsc LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
 117 INSTALL(FILES afb-wsj1.h afb-ws-client.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/afb)
 118
 119 ###########################################
 120 # build and install afb-client-demo
 121 ###########################################
 122 ADD_EXECUTABLE(afb-client-demo afb-client-demo.c)
 123 TARGET_LINK_LIBRARIES(afb-client-demo
 124         afbwsc
 125         ${link_libraries}
 126         ${libsystemd_LIBRARIES}
 127 )
 128 INSTALL(TARGETS afb-client-demo
 129         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 130
 131