src/CMakeLists.txt

   1 ###########################################################################
   2 # Copyright (C) 2015-2019 "IoT.bzh"
   3 #
   4 # author: José Bollo <jose.bollo@iot.bzh>
   5 #
   6 # Licensed under the Apache License, Version 2.0 (the "License");
   7 # you may not use this file except in compliance with the License.
   8 # You may obtain a copy of the License at
   9 #
  10 #     http://www.apache.org/licenses/LICENSE-2.0
  11 #
  12 # Unless required by applicable law or agreed to in writing, software
  13 # distributed under the License is distributed on an "AS IS" BASIS,
  14 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15 # See the License for the specific language governing permissions and
  16 # limitations under the License.
  17 ###########################################################################
  18
  19 if (CMAKE_C_COMPILER_VERSION VERSION_LESS 4.9)
  20     message(FATAL_ERROR "Require at least gcc-4.9")
  21 endif(CMAKE_C_COMPILER_VERSION VERSION_LESS 4.9)
  22
  23 add_definitions(-DBINDING_INSTALL_DIR="${binding_install_dir}")
  24
  25 ############################################################################
  26 # TODO: improve below setting by using config file
  27
  28 add_definitions(
  29   -DAGL_DEVEL=$<BOOL:${AGL_DEVEL}>
  30   -DWITH_SIG_MONITOR_DUMPSTACK=$<BOOL:${WITH_SIG_MONITOR_DUMPSTACK}>
  31   -DWITH_SIG_MONITOR_SIGNALS=$<BOOL:${WITH_SIG_MONITOR_SIGNALS}>
  32   -DWITH_SIG_MONITOR_FOR_CALL=$<BOOL:${WITH_SIG_MONITOR_FOR_CALL}>
  33   -DWITH_SIG_MONITOR_TIMERS=$<BOOL:${WITH_SIG_MONITOR_TIMERS}>
  34   -DWITH_AFB_HOOK=$<BOOL:${WITH_AFB_HOOK}>
  35   -DWITH_AFB_TRACE=$<BOOL:${WITH_AFB_TRACE}>
  36   -DWITH_LEGACY_BINDING_V1=$<BOOL:${INCLUDE_LEGACY_BINDING_V1}>
  37   -DWITH_LEGACY_BINDING_V2=$<BOOL:${WITH_LEGACY_BINDING_V2}>
  38   -DWITH_LEGACY_BINDING_VDYN=$<BOOL:${INCLUDE_LEGACY_BINDING_VDYN}>
  39   -DWITH_DBUS_TRANSPARENCY=$<BOOL:${INCLUDE_DBUS_TRANSPARENCY}>
  40   -DWITH_SUPERVISION=$<BOOL:${INCLUDE_SUPERVISOR}>
  41   -DWITH_DYNAMIC_BINDING=$<BOOL:${WITH_DYNAMIC_BINDING}>
  42   -DWITH_SYSTEMD=$<BOOL:${WITH_SYSTEMD}>
  43   -DWITH_FDEV_EPOLL=$<NOT:$<BOOL:${WITH_SYSTEMD}>>
  44   -DWITH_LIBMICROHTTPD=$<BOOL:${WITH_LIBMICROHTTPD}>
  45   -DWITH_MONITORING=$<BOOL:${WITH_MONITORING}>
  46 )
  47
  48 if (WITH_SUPERVISOR)
  49   add_definitions(
  50      -DAFS_SUPERVISION_SOCKET=\"${AFS_SUPERVISION_SOCKET}\"
  51      -DAFS_SUPERVISOR_TOKEN=\"${AFS_SUPERVISOR_TOKEN}\"
  52      -DAFS_SUPERVISOR_PORT=${AFS_SUPERVISOR_PORT}
  53   )
  54 endif()
  55
  56 if(WITH_LIBMICROHTTPD)
  57   # Always add INFER_EXTENSION (more details in afb-hreq.c)
  58   add_definitions(
  59      -DINFER_EXTENSION=1
  60      -DUSE_MAGIC_MIME_TYPE=1
  61   )
  62 endif()
  63
  64 ############################################################################
  65
  66 SET(AFB_LIB_SOURCES
  67         afb-api.c
  68         afb-api-dbus.c
  69         afb-api-so.c
  70         afb-api-so-v1.c
  71         afb-api-so-v2.c
  72         afb-api-so-v3.c
  73         afb-api-so-vdyn.c
  74         afb-api-v3.c
  75         afb-api-ws.c
  76         afb-apiset.c
  77         afb-args.c
  78         afb-auth.c
  79         afb-autoset.c
  80         afb-calls.c
  81         afb-common.c
  82         afb-context.c
  83         afb-cred.c
  84         afb-debug.c
  85         afb-evt.c
  86         afb-export.c
  87         afb-fdev.c
  88         afb-hook.c
  89         afb-hook-flags.c
  90         afb-hreq.c
  91         afb-hsrv.c
  92         afb-hswitch.c
  93         afb-method.c
  94         afb-monitor.c
  95         afb-msg-json.c
  96         afb-proto-ws.c
  97         afb-session.c
  98         afb-socket.c
  99         afb-stub-ws.c
 100         afb-supervision.c
 101         afb-trace.c
 102         afb-websock.c
 103         afb-ws-client.c
 104         afb-ws-json1.c
 105         afb-ws.c
 106         afb-wsj1.c
 107         afb-xreq.c
 108         evmgr.c
 109         fdev.c
 110         fdev-epoll.c
 111         fdev-systemd.c
 112         globset.c
 113         jobs.c
 114         locale-root.c
 115         pearson.c
 116         process-name.c
 117         sig-monitor.c
 118         subpath.c
 119         systemd.c
 120         verbose.c
 121         watchdog.c
 122         websock.c
 123         wrap-json.c
 124 )
 125
 126 ADD_LIBRARY(afb-lib STATIC ${AFB_LIB_SOURCES})
 127
 128 ###########################################
 129 # build and install afb-daemon
 130 ###########################################
 131 ADD_EXECUTABLE(afb-daemon main-afb-daemon.c)
 132 TARGET_LINK_LIBRARIES(afb-daemon
 133         afb-lib
 134         ${link_libraries}
 135 )
 136 INSTALL(TARGETS afb-daemon
 137         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 138
 139 ###########################################
 140 # build and install afb-daemon
 141 ###########################################
 142 IF(INCLUDE_SUPERVISOR)
 143         ADD_EXECUTABLE(afs-supervisor main-afs-supervisor.c afs-supervisor.c afs-discover.c afs-args.c)
 144         TARGET_LINK_LIBRARIES(afs-supervisor
 145                 afb-lib
 146                 ${link_libraries}
 147         )
 148         INSTALL(TARGETS afs-supervisor
 149                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 150 ENDIF()
 151
 152 ###########################################
 153 # build and install libafbwsc
 154 ###########################################
 155 ADD_LIBRARY(afbwsc SHARED afb-ws.c afb-ws-client.c afb-wsj1.c websock.c afb-proto-ws.c fdev.c fdev-systemd.c verbose.c)
 156 SET_TARGET_PROPERTIES(afbwsc PROPERTIES
 157         VERSION ${LIBAFBWSC_VERSION}
 158         SOVERSION ${LIBAFBWSC_SOVERSION})
 159 TARGET_LINK_LIBRARIES(afbwsc
 160         ${libsystemd_LDFLAGS}
 161         ${json-c_LDFLAGS}
 162         -lpthread
 163         -Wl,--version-script=${CMAKE_CURRENT_SOURCE_DIR}/export-afbwsc.map
 164         -Wl,--as-needed
 165         -Wl,--gc-sections
 166 )
 167 INSTALL(TARGETS afbwsc LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
 168 INSTALL(FILES afb-wsj1.h afb-ws-client.h afb-proto-ws.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/afb)
 169
 170 ###########################################
 171 # build and install afb-client-demo
 172 ###########################################
 173 ADD_EXECUTABLE(afb-client-demo main-afb-client-demo.c)
 174 TARGET_LINK_LIBRARIES(afb-client-demo
 175         afbwsc
 176         ${link_libraries}
 177         ${libsystemd_LDFLAGS}
 178 )
 179 INSTALL(TARGETS afb-client-demo
 180         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 181