src/CMakeLists.txt

   1 ###########################################################################
   2 # Copyright (C) 2015-2019 "IoT.bzh"
   3 #
   4 # author: José Bollo <jose.bollo@iot.bzh>
   5 #
   6 # Licensed under the Apache License, Version 2.0 (the "License");
   7 # you may not use this file except in compliance with the License.
   8 # You may obtain a copy of the License at
   9 #
  10 #     http://www.apache.org/licenses/LICENSE-2.0
  11 #
  12 # Unless required by applicable law or agreed to in writing, software
  13 # distributed under the License is distributed on an "AS IS" BASIS,
  14 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15 # See the License for the specific language governing permissions and
  16 # limitations under the License.
  17 ###########################################################################
  18
  19 if (CMAKE_C_COMPILER_VERSION VERSION_LESS 4.9)
  20     message(FATAL_ERROR "Require at least gcc-4.9")
  21 endif(CMAKE_C_COMPILER_VERSION VERSION_LESS 4.9)
  22
  23 add_definitions(-DBINDING_INSTALL_DIR="${binding_install_dir}")
  24
  25 ############################################################################
  26 # TODO: improve below setting by using config file
  27
  28 add_definitions(
  29   -DAGL_DEVEL=$<BOOL:${AGL_DEVEL}>
  30   -DWITH_SIG_MONITOR_DUMPSTACK=$<BOOL:${WITH_SIG_MONITOR_DUMPSTACK}>
  31   -DWITH_SIG_MONITOR_SIGNALS=$<BOOL:${WITH_SIG_MONITOR_SIGNALS}>
  32   -DWITH_SIG_MONITOR_FOR_CALL=$<BOOL:${WITH_SIG_MONITOR_FOR_CALL}>
  33   -DWITH_SIG_MONITOR_TIMERS=$<BOOL:${WITH_SIG_MONITOR_TIMERS}>
  34   -DWITH_AFB_HOOK=$<BOOL:${WITH_AFB_HOOK}>
  35   -DWITH_AFB_TRACE=$<BOOL:${WITH_AFB_TRACE}>
  36   -DWITH_LEGACY_BINDING_V1=$<BOOL:${INCLUDE_LEGACY_BINDING_V1}>
  37   -DWITH_LEGACY_BINDING_V2=$<BOOL:${WITH_LEGACY_BINDING_V2}>
  38   -DWITH_LEGACY_BINDING_VDYN=$<BOOL:${INCLUDE_LEGACY_BINDING_VDYN}>
  39   -DWITH_DBUS_TRANSPARENCY=$<BOOL:${INCLUDE_DBUS_TRANSPARENCY}>
  40   -DWITH_SUPERVISION=$<BOOL:${INCLUDE_SUPERVISOR}>
  41   -DWITH_DYNAMIC_BINDING=$<BOOL:${WITH_DYNAMIC_BINDING}>
  42   -DWITH_SYSTEMD=$<BOOL:${WITH_SYSTEMD}>
  43   -DWITH_FDEV_EPOLL=$<NOT:$<BOOL:${WITH_SYSTEMD}>>
  44   -DWITH_LIBMICROHTTPD=$<BOOL:${WITH_LIBMICROHTTPD}>
  45   -DWITH_MONITORING=$<BOOL:${WITH_MONITORING}>
  46   -DWITH_FNMATCH=$<BOOL:${WITH_FNMATCH}>
  47 )
  48
  49 if (WITH_SUPERVISOR)
  50   add_definitions(
  51      -DAFS_SUPERVISION_SOCKET=\"${AFS_SUPERVISION_SOCKET}\"
  52      -DAFS_SUPERVISOR_TOKEN=\"${AFS_SUPERVISOR_TOKEN}\"
  53      -DAFS_SUPERVISOR_PORT=${AFS_SUPERVISOR_PORT}
  54   )
  55 endif()
  56
  57 if(WITH_LIBMICROHTTPD)
  58   # Always add INFER_EXTENSION (more details in afb-hreq.c)
  59   add_definitions(
  60      -DINFER_EXTENSION=1
  61      -DUSE_MAGIC_MIME_TYPE=1
  62   )
  63 endif()
  64
  65 ############################################################################
  66
  67 SET(AFB_LIB_SOURCES
  68         afb-api.c
  69         afb-api-dbus.c
  70         afb-api-so.c
  71         afb-api-so-v1.c
  72         afb-api-so-v2.c
  73         afb-api-so-v3.c
  74         afb-api-so-vdyn.c
  75         afb-api-v3.c
  76         afb-api-ws.c
  77         afb-apiset.c
  78         afb-args.c
  79         afb-auth.c
  80         afb-autoset.c
  81         afb-calls.c
  82         afb-common.c
  83         afb-context.c
  84         afb-cred.c
  85         afb-debug.c
  86         afb-evt.c
  87         afb-export.c
  88         afb-fdev.c
  89         afb-hook.c
  90         afb-hook-flags.c
  91         afb-hreq.c
  92         afb-hsrv.c
  93         afb-hswitch.c
  94         afb-method.c
  95         afb-monitor.c
  96         afb-msg-json.c
  97         afb-proto-ws.c
  98         afb-session.c
  99         afb-socket.c
 100         afb-stub-ws.c
 101         afb-supervision.c
 102         afb-trace.c
 103         afb-websock.c
 104         afb-ws-client.c
 105         afb-ws-json1.c
 106         afb-ws.c
 107         afb-wsj1.c
 108         afb-xreq.c
 109         evmgr.c
 110         fdev.c
 111         fdev-epoll.c
 112         fdev-systemd.c
 113         globmatch.c
 114         globset.c
 115         jobs.c
 116         locale-root.c
 117         pearson.c
 118         process-name.c
 119         sig-monitor.c
 120         subpath.c
 121         systemd.c
 122         verbose.c
 123         watchdog.c
 124         websock.c
 125         wrap-json.c
 126 )
 127
 128 ADD_LIBRARY(afb-lib STATIC ${AFB_LIB_SOURCES})
 129
 130 ###########################################
 131 # build and install afb-daemon
 132 ###########################################
 133 ADD_EXECUTABLE(afb-daemon main-afb-daemon.c)
 134 TARGET_LINK_LIBRARIES(afb-daemon
 135         afb-lib
 136         ${link_libraries}
 137 )
 138 INSTALL(TARGETS afb-daemon
 139         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 140
 141 ###########################################
 142 # build and install afb-daemon
 143 ###########################################
 144 IF(INCLUDE_SUPERVISOR)
 145         ADD_EXECUTABLE(afs-supervisor main-afs-supervisor.c afs-supervisor.c afs-discover.c afs-args.c)
 146         TARGET_LINK_LIBRARIES(afs-supervisor
 147                 afb-lib
 148                 ${link_libraries}
 149         )
 150         INSTALL(TARGETS afs-supervisor
 151                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 152 ENDIF()
 153
 154 ###########################################
 155 # build and install libafbwsc
 156 ###########################################
 157 ADD_LIBRARY(afbwsc SHARED afb-ws.c afb-ws-client.c afb-wsj1.c websock.c afb-proto-ws.c fdev.c fdev-systemd.c verbose.c)
 158 SET_TARGET_PROPERTIES(afbwsc PROPERTIES
 159         VERSION ${LIBAFBWSC_VERSION}
 160         SOVERSION ${LIBAFBWSC_SOVERSION})
 161 TARGET_LINK_LIBRARIES(afbwsc
 162         ${libsystemd_LDFLAGS}
 163         ${json-c_LDFLAGS}
 164         -lpthread
 165         -Wl,--version-script=${CMAKE_CURRENT_SOURCE_DIR}/export-afbwsc.map
 166         -Wl,--as-needed
 167         -Wl,--gc-sections
 168 )
 169 INSTALL(TARGETS afbwsc LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
 170 INSTALL(FILES afb-wsj1.h afb-ws-client.h afb-proto-ws.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/afb)
 171
 172 ###########################################
 173 # build and install afb-client-demo
 174 ###########################################
 175 ADD_EXECUTABLE(afb-client-demo main-afb-client-demo.c)
 176 TARGET_LINK_LIBRARIES(afb-client-demo
 177         afbwsc
 178         ${link_libraries}
 179         ${libsystemd_LDFLAGS}
 180 )
 181 INSTALL(TARGETS afb-client-demo
 182         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 183