src/CMakeLists.txt

   1 ###########################################################################
   2 # Copyright (C) 2015-2019 "IoT.bzh"
   3 #
   4 # author: José Bollo <jose.bollo@iot.bzh>
   5 #
   6 # Licensed under the Apache License, Version 2.0 (the "License");
   7 # you may not use this file except in compliance with the License.
   8 # You may obtain a copy of the License at
   9 #
  10 #     http://www.apache.org/licenses/LICENSE-2.0
  11 #
  12 # Unless required by applicable law or agreed to in writing, software
  13 # distributed under the License is distributed on an "AS IS" BASIS,
  14 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15 # See the License for the specific language governing permissions and
  16 # limitations under the License.
  17 ###########################################################################
  18
  19 if (CMAKE_C_COMPILER_VERSION VERSION_LESS 4.9)
  20     message(FATAL_ERROR "Require at least gcc-4.9")
  21 endif(CMAKE_C_COMPILER_VERSION VERSION_LESS 4.9)
  22
  23 add_definitions(-DBINDING_INSTALL_DIR="${binding_install_dir}")
  24
  25 ############################################################################
  26 # TODO: improve below setting by using config file
  27
  28 add_definitions(
  29   -DAGL_DEVEL=$<BOOL:${AGL_DEVEL}>
  30   -DWITH_SIG_MONITOR_DUMPSTACK=$<BOOL:${WITH_SIG_MONITOR_DUMPSTACK}>
  31   -DWITH_SIG_MONITOR_SIGNALS=$<BOOL:${WITH_SIG_MONITOR_SIGNALS}>
  32   -DWITH_SIG_MONITOR_FOR_CALL=$<BOOL:${WITH_SIG_MONITOR_FOR_CALL}>
  33   -DWITH_SIG_MONITOR_TIMERS=$<BOOL:${WITH_SIG_MONITOR_TIMERS}>
  34   -DWITH_AFB_HOOK=$<BOOL:${WITH_AFB_HOOK}>
  35   -DWITH_AFB_TRACE=$<BOOL:${WITH_AFB_TRACE}>
  36   -DWITH_LEGACY_BINDING_V1=$<BOOL:${INCLUDE_LEGACY_BINDING_V1}>
  37   -DWITH_LEGACY_BINDING_V2=$<BOOL:${WITH_LEGACY_BINDING_V2}>
  38   -DWITH_LEGACY_BINDING_VDYN=$<BOOL:${INCLUDE_LEGACY_BINDING_VDYN}>
  39   -DWITH_DBUS_TRANSPARENCY=$<BOOL:${INCLUDE_DBUS_TRANSPARENCY}>
  40   -DWITH_SUPERVISION=$<BOOL:${INCLUDE_SUPERVISOR}>
  41   -DWITH_DYNAMIC_BINDING=$<BOOL:${WITH_DYNAMIC_BINDING}>
  42   -DWITH_SYSTEMD=$<BOOL:${WITH_SYSTEMD}>
  43   -DWITH_FDEV_EPOLL=$<NOT:$<BOOL:${WITH_SYSTEMD}>>
  44   -DWITH_LIBMICROHTTPD=$<BOOL:${WITH_LIBMICROHTTPD}>
  45   -DWITH_MONITORING=$<BOOL:${WITH_MONITORING}>
  46   -DWITH_FNMATCH=$<BOOL:${WITH_FNMATCH}>
  47   -DWITH_L4VSOCK=$<BOOL:${WITH_L4VSOCK}>
  48 )
  49
  50 if (WITH_SUPERVISOR)
  51   add_definitions(
  52      -DAFS_SUPERVISION_SOCKET=\"${AFS_SUPERVISION_SOCKET}\"
  53      -DAFS_SUPERVISOR_TOKEN=\"${AFS_SUPERVISOR_TOKEN}\"
  54      -DAFS_SUPERVISOR_PORT=${AFS_SUPERVISOR_PORT}
  55   )
  56 endif()
  57
  58 if(WITH_LIBMICROHTTPD)
  59   # Always add INFER_EXTENSION (more details in afb-hreq.c)
  60   add_definitions(
  61      -DINFER_EXTENSION=1
  62      -DUSE_MAGIC_MIME_TYPE=1
  63   )
  64 endif()
  65
  66 ############################################################################
  67
  68 SET(AFB_LIB_SOURCES
  69         afb-api.c
  70         afb-api-dbus.c
  71         afb-api-so.c
  72         afb-api-so-v1.c
  73         afb-api-so-v2.c
  74         afb-api-so-v3.c
  75         afb-api-so-vdyn.c
  76         afb-api-v3.c
  77         afb-api-ws.c
  78         afb-apiset.c
  79         afb-args.c
  80         afb-auth.c
  81         afb-autoset.c
  82         afb-calls.c
  83         afb-common.c
  84         afb-context.c
  85         afb-cred.c
  86         afb-debug.c
  87         afb-evt.c
  88         afb-export.c
  89         afb-fdev.c
  90         afb-hook.c
  91         afb-hook-flags.c
  92         afb-hreq.c
  93         afb-hsrv.c
  94         afb-hswitch.c
  95         afb-method.c
  96         afb-monitor.c
  97         afb-msg-json.c
  98         afb-proto-ws.c
  99         afb-session.c
 100         afb-socket.c
 101         afb-stub-ws.c
 102         afb-supervision.c
 103         afb-trace.c
 104         afb-websock.c
 105         afb-ws-client.c
 106         afb-ws-json1.c
 107         afb-ws.c
 108         afb-wsj1.c
 109         afb-xreq.c
 110         evmgr.c
 111         fdev.c
 112         fdev-epoll.c
 113         fdev-systemd.c
 114         globmatch.c
 115         globset.c
 116         jobs.c
 117         locale-root.c
 118         pearson.c
 119         process-name.c
 120         sig-monitor.c
 121         subpath.c
 122         systemd.c
 123         verbose.c
 124         watchdog.c
 125         websock.c
 126         wrap-json.c
 127 )
 128
 129 ADD_LIBRARY(afb-lib STATIC ${AFB_LIB_SOURCES})
 130
 131 ###########################################
 132 # build and install afb-daemon
 133 ###########################################
 134 ADD_EXECUTABLE(afb-daemon main-afb-daemon.c)
 135 TARGET_LINK_LIBRARIES(afb-daemon
 136         afb-lib
 137         ${link_libraries}
 138 )
 139 INSTALL(TARGETS afb-daemon
 140         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 141
 142 ###########################################
 143 # build and install afb-daemon
 144 ###########################################
 145 IF(INCLUDE_SUPERVISOR)
 146         ADD_EXECUTABLE(afs-supervisor main-afs-supervisor.c afs-supervisor.c afs-discover.c afs-args.c)
 147         TARGET_LINK_LIBRARIES(afs-supervisor
 148                 afb-lib
 149                 ${link_libraries}
 150         )
 151         INSTALL(TARGETS afs-supervisor
 152                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 153 ENDIF()
 154
 155 ###########################################
 156 # build and install libafbwsc
 157 ###########################################
 158 ADD_LIBRARY(afbwsc SHARED afb-ws.c afb-ws-client.c afb-wsj1.c websock.c afb-proto-ws.c fdev.c fdev-systemd.c verbose.c)
 159 SET_TARGET_PROPERTIES(afbwsc PROPERTIES
 160         VERSION ${LIBAFBWSC_VERSION}
 161         SOVERSION ${LIBAFBWSC_SOVERSION})
 162 TARGET_LINK_LIBRARIES(afbwsc
 163         ${libsystemd_LDFLAGS}
 164         ${json-c_LDFLAGS}
 165         -lpthread
 166         -Wl,--version-script=${CMAKE_CURRENT_SOURCE_DIR}/export-afbwsc.map
 167         -Wl,--as-needed
 168         -Wl,--gc-sections
 169 )
 170 INSTALL(TARGETS afbwsc LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
 171 INSTALL(FILES afb-wsj1.h afb-ws-client.h afb-proto-ws.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/afb)
 172
 173 ###########################################
 174 # build and install afb-client-demo
 175 ###########################################
 176 ADD_EXECUTABLE(afb-client-demo main-afb-client-demo.c)
 177 TARGET_LINK_LIBRARIES(afb-client-demo
 178         afbwsc
 179         ${link_libraries}
 180         ${libsystemd_LDFLAGS}
 181 )
 182 INSTALL(TARGETS afb-client-demo
 183         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 184