docs/migration-to-binding-v3.sed

   1 #######################################################################################
   2 # Script sed for migrating from AFB_BINDING_VERSION 2 to AFB_BINDING_VERSION 3
   3 # See http://docs.automotivelinux.org/docs/apis_services/en/dev/reference/af-binder/afb-migration-to-ibinding-v3.html
   4 #######################################################################################
   5 # update the version
   6 # ------------------
   7 s:\(\<AFB_BINDING_VERSION[[:blank:]]\{1,\}\)2\>:\13:
   8
   9 # update common types
  10 # -------------------
  11 s:\<\(struct[[:blank:]]\{1,\}\)\{0,1\}afb_req\>:afb_req_t:g
  12 s:\<\(struct[[:blank:]]\{1,\}\)\{0,1\}afb_event\>:afb_event_t:g
  13 s:\<\(struct[[:blank:]]\{1,\}\)\{0,1\}afb_verb_v2\>:afb_verb_t:g
  14 s:\<\(struct[[:blank:]]\{1,\}\)\{0,1\}afb_binding_v2\>:afb_binding_t:g
  15
  16 # update common names
  17 # -------------------
  18 s:\<afbBindingV2\>:afbBindingExport:g
  19
  20 # very special
  21 # ------------
  22 s:( *afb_req_t *) *{ *NULL *, *NULL *}:NULL:g
  23
  24 # special dynapi
  25 # --------------
  26 s:\(\<AFB_BINDING_VERSION[[:blank:]]\{1,\}\)0\>:\13:
  27 /^[[:blank:]]*# *define *\<AFB_BINDING_WANT_DYNAPI\>/d
  28 s:\<\(struct[[:blank:]]\{1,\}\)\{0,1\}afb_dynapi\>\([[:blank:]]*\)\*:afb_api_t\2:g
  29 s:\<\(struct[[:blank:]]\{1,\}\)\{0,1\}afb_request\>\([[:blank:]]*\)\*:afb_req_t\2:g
  30 s:\<\(struct[[:blank:]]\{1,\}\)\{0,1\}afb_eventid\>\([[:blank:]]*\)\*:afb_event_t\2:g
  31 s:\<afb_request_:afb_req_:g
  32 s:\<afb_dynapi_:afb_api_:g
  33 s:\<afb_eventid_:afb_event_:g
  34 s:\<AFB_DYNAPI_:AFB_API_:g
  35 s:\<AFB_REQUEST_:AFB_REQ_:g
  36 s:\<afbBindingVdyn\>:afbBindingV3entry:g
  37 s:\<dynapi\>:api:g
  38 s:\<eventid\>:event:g
  39 s:\<afb_api_make_eventid\>:afb_api_make_event:g
  40 s:\<afb_api_new_api\>:-!&:g
  41 s:\<afb_api_sub_verb\>:afb_api_del_verb:g
  42
  43 # update legacy calls
  44 # ------------------
  45 s:\<afb_req_subcall\(_req\)\>:afb_req_subcall_legacy:g
  46 s:\<afb_req_subcall_sync\>:afb_req_subcall_sync_legacy:g
  47 s:\<afb_api_call\>:afb_api_call_legacy:g
  48 s:\<afb_api_call_sync\>:afb_api_call_sync_legacy:g
  49 s:\<afb_req_store\>:afb_req_addref:g
  50 s:\<afb_req_unstore\> *( *\(.*\) *):\1:g
  51
  52 # optional but activated by default
  53 # ---------------------------------
  54 s:\<afb_daemon_get_\(event_loop\|user_bus\|system_bus\)[ \t]*(:afb_api_get_\1(afbBindingV3root:g
  55 s:\<afb_daemon_\([a-z_0-9]* *(\):afb_api_\1afbBindingV3root, :g
  56 s:\<afb_service_call_\([a-z_0-9]*\)\( *(\):afb_api_\1_legacy\2afbBindingV3root, :g
  57 s:\<afb_service_\([a-z_0-9]* *(\):afb_api_\1afbBindingV3root, :g
  58 s:\<AFB_\(\(ERROR\|WARNING\|NOTICE\|INFO\|DEBUG\)\> *(\):AFB_API_\1afbBindingV3root, :g
  59
  60 # special app-controller
  61 # ----------------------
  62 s:\<_\(AFB_SYSLOG_LEVEL_[A-Z]*\)_\>:\1:g
  63
  64 # UNSAFES (uncomment it if optimistic)
  65 # --------------
  66 #s:\<afb_req_fail\(_[fv]\)\{0,1\}\>\( *([^,]*\):afb_req_reply\1\2, NULL:g
  67 #s:\<afb_req_success\(_[fv]\)\{0,1\}\>\( *([^,]*,[^,]*\):afb_req_reply\1\2, NULL:g
  68 #
  69 #s:\<afb_api_add_verb\>[^)]*:&, 0:g      ;# dynapi
  70 #s:\<afb_api_del_verb\>[^)]*:&, NULL:g   ;# dynapi
  71 #######################################################################################