CMakeLists.txt

   1 ###########################################################################
   2 # Copyright (C) 2015-2018 "IoT.bzh"
   3 #
   4 # author: José Bollo <jose.bollo@iot.bzh>
   5 #
   6 # Licensed under the Apache License, Version 2.0 (the "License");
   7 # you may not use this file except in compliance with the License.
   8 # You may obtain a copy of the License at
   9 #
  10 #     http://www.apache.org/licenses/LICENSE-2.0
  11 #
  12 # Unless required by applicable law or agreed to in writing, software
  13 # distributed under the License is distributed on an "AS IS" BASIS,
  14 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15 # See the License for the specific language governing permissions and
  16 # limitations under the License.
  17 ###########################################################################
  18
  19 CMAKE_MINIMUM_REQUIRED(VERSION 3.0)
  20
  21 PROJECT(afb-daemon C CXX)
  22
  23 SET(PROJECT_NAME "AFB Daemon")
  24 SET(PROJECT_PRETTY_NAME "Application Framework Binder Daemon")
  25 SET(PROJECT_DESCRIPTION "Secured binder of API for clients of the Application framework")
  26 SET(PROJECT_VERSION "5.99-FFRC0")
  27 set(PROJECT_URL "https://gerrit.automotivelinux.org/gerrit/gitweb?p=src/app-framework-binder.git;a=summary")
  28
  29 SET(LIBAFBWSC_VERSION "1.1")
  30 SET(LIBAFBWSC_SOVERSION "1")
  31
  32 INCLUDE(FindPkgConfig)
  33 INCLUDE(CheckIncludeFiles)
  34 INCLUDE(CheckLibraryExists)
  35 INCLUDE(GNUInstallDirs)
  36 INCLUDE(CTest)
  37
  38 ###########################################################################
  39 # possible settings
  40 set(AGL_DEVEL OFF CACHE BOOL "Activates developping features")
  41 set(INCLUDE_MONITORING OFF CACHE BOOL "Activates installation of monitoring")
  42 set(INCLUDE_SUPERVISOR OFF CACHE BOOL "Activates installation of supervisor")
  43 set(AFS_SURPERVISION_SOCKET "@urn:AGL:afs:supervision:socket" CACHE STRING "Internal socket for supervision")
  44 set(AFS_SUPERVISOR_PORT 1619 CACHE STRING "Port of service for the supervisor")
  45 set(AFS_SUPERVISOR_TOKEN HELLO CACHE STRING "Secret token for the supervisor")
  46 set(UNITDIR_SYSTEM ${CMAKE_INSTALL_LIBDIR}/systemd/system CACHE STRING "Path to systemd system unit files")
  47
  48 ###########################################################################
  49
  50 link_libraries(-Wl,--as-needed -Wl,--gc-sections -Wl,--no-undefined)
  51
  52 add_compile_options(-Wall -Wextra -Wconversion)
  53 add_compile_options(-Wno-unused-parameter) # frankly not using a parameter does it care?
  54 add_compile_options(-Wno-sign-compare -Wno-sign-conversion)
  55 add_compile_options(-Werror=maybe-uninitialized)
  56 add_compile_options(-Werror=implicit-function-declaration)
  57 add_compile_options(-ffunction-sections -fdata-sections)
  58 add_compile_options(-fPIC)
  59 add_compile_options(-g)
  60 set (CMAKE_CXX_STANDARD 14)
  61
  62 set(CMAKE_C_FLAGS_PROFILING    "-g -O2 -pg -Wp,-U_FORTIFY_SOURCE")
  63 set(CMAKE_C_FLAGS_DEBUG        "-g -ggdb -Wp,-U_FORTIFY_SOURCE")
  64 set(CMAKE_C_FLAGS_RELEASE      "-g -O2")
  65 set(CMAKE_C_FLAGS_CCOV         "-g -O2 --coverage")
  66
  67 ###########################################################################
  68
  69 INCLUDE(FindThreads)
  70 FIND_PACKAGE(Threads)
  71
  72 PKG_CHECK_MODULES(json-c REQUIRED json-c)
  73
  74 CHECK_INCLUDE_FILES(magic.h HAVE_MAGIC_H)
  75 CHECK_LIBRARY_EXISTS(magic magic_load "" HAVE_LIBMAGIC_SO)
  76 IF(HAVE_MAGIC_H)
  77   IF(HAVE_LIBMAGIC_SO)
  78     SET(HAVE_LIBMAGIC "1")
  79     SET(LIBMAGIC_LDFLAGS -lmagic)
  80   ENDIF(HAVE_LIBMAGIC_SO)
  81 ENDIF(HAVE_MAGIC_H)
  82
  83 PKG_CHECK_MODULES(libsystemd libsystemd>=222)
  84 PKG_CHECK_MODULES(libmicrohttpd libmicrohttpd>=0.9.55)
  85 PKG_CHECK_MODULES(openssl openssl)
  86 PKG_CHECK_MODULES(uuid uuid)
  87 PKG_CHECK_MODULES(cynara cynara-client)
  88
  89 ADD_DEFINITIONS("-DAFS_SURPERVISION_SOCKET=\"${AFS_SURPERVISION_SOCKET}\"")
  90
  91 IF(AGL_DEVEL)
  92         ADD_DEFINITIONS(-DAGL_DEVEL)
  93 endif()
  94
  95 IF(cynara_FOUND)
  96         ADD_DEFINITIONS(-DBACKEND_PERMISSION_IS_CYNARA)
  97 ENDIF(cynara_FOUND)
  98
  99 IF(HAVE_LIBMAGIC AND libsystemd_FOUND AND libmicrohttpd_FOUND AND openssl_FOUND AND uuid_FOUND)
 100   ADD_DEFINITIONS(-DUSE_MAGIC_MIME_TYPE)
 101 ELSE()
 102   IF(NOT HAVE_LIBMAGIC)
 103     MESSAGE(WARNING "\"magic.h\" or \"libmagic.so\" missing.
 104     Please install the \"file-devel\" or \"libmagic-dev\" package !")
 105   ENDIF(NOT HAVE_LIBMAGIC)
 106   IF(NOT libsystemd_FOUND)
 107     MESSAGE(WARNING "Dependency to 'libsystemd' is missing")
 108   ENDIF()
 109   IF(NOT libmicrohttpd_FOUND)
 110     MESSAGE(WARNING "Dependency to 'libmicrohttpd' is missing")
 111   ENDIF()
 112   IF(NOT openssl_FOUND)
 113     MESSAGE(WARNING "Dependency to 'openssl' is missing")
 114   ENDIF()
 115   IF(NOT uuid_FOUND)
 116     MESSAGE(WARNING "Dependency to 'uuid' is missing")
 117   ENDIF()
 118   IF(NOT ONLY_DEVTOOLS)
 119     MESSAGE(FATAL_ERROR "Can't compile the binder, either define ONLY_DEVTOOLS or install dependencies")
 120   ENDIF()
 121 ENDIF()
 122
 123 ADD_DEFINITIONS(-DAFB_VERSION="${PROJECT_VERSION}")
 124
 125 INCLUDE_DIRECTORIES(
 126         ${INCLUDE_DIRS}
 127         ${CMAKE_SOURCE_DIR}/include
 128         ${json-c_INCLUDE_DIRS}
 129         ${libsystemd_INCLUDE_DIRS}
 130         ${libmicrohttpd_INCLUDE_DIRS}
 131         ${uuid_INCLUDE_DIRS}
 132         ${openssl_INCLUDE_DIRS}
 133         ${cynara_INCLUDE_DIRS}
 134 )
 135
 136 SET(link_libraries
 137         ${CMAKE_THREAD_LIBS_INIT}
 138         ${json-c_LDFLAGS}
 139         ${libsystemd_LDFLAGS}
 140         ${libmicrohttpd_LDFLAGS}
 141         ${uuid_LDFLAGS}
 142         ${openssl_LDFLAGS}
 143         ${cynara_LDFLAGS}
 144         ${LIBMAGIC_LDFLAGS}
 145         -ldl
 146         -lrt
 147         )
 148
 149 ADD_SUBDIRECTORY(src/devtools)
 150
 151 IF(ONLY_DEVTOOLS)
 152         MESSAGE(WARNING "Only DEVTOOLS are compiled, not the binder!")
 153 ELSE()
 154         SET(binding_install_dir ${CMAKE_INSTALL_FULL_LIBDIR}/afb)
 155
 156         ###########################################################################
 157         # activates the monitoring by default
 158         if(INCLUDE_MONITORING AND NOT ONLY_DEVTOOLS)
 159                 add_definitions(-DWITH_MONITORING_OPTION)
 160                 INSTALL(DIRECTORY
 161                         ${CMAKE_CURRENT_SOURCE_DIR}/test/monitoring
 162                         DESTINATION
 163                         ${binding_install_dir}
 164                 )
 165         endif()
 166
 167         ###########################################################################
 168
 169         ADD_SUBDIRECTORY(src)
 170         ADD_SUBDIRECTORY(src/tests)
 171         ADD_SUBDIRECTORY(include)
 172         ADD_SUBDIRECTORY(bindings)
 173
 174         ############################################################
 175         # installs the pkgconfig files
 176         CONFIGURE_FILE(afb-daemon.pc.in afb-daemon.pc @ONLY)
 177         CONFIGURE_FILE(libafbwsc.pc.in libafbwsc.pc @ONLY)
 178
 179         INSTALL(FILES
 180             ${CMAKE_CURRENT_BINARY_DIR}/afb-daemon.pc
 181             ${CMAKE_CURRENT_BINARY_DIR}/libafbwsc.pc
 182             DESTINATION
 183             ${CMAKE_INSTALL_LIBDIR}/pkgconfig
 184         )
 185
 186 ENDIF()
 187
 188 IF(INCLUDE_SUPERVISOR)
 189         CONFIGURE_FILE(afs-supervisor.service.in afs-supervisor.service @ONLY)
 190         INSTALL(FILES
 191             ${CMAKE_CURRENT_BINARY_DIR}/afs-supervisor.service
 192             DESTINATION
 193             ${UNITDIR_SYSTEM}
 194         )
 195 ENDIF()
 196