homescreen/meson.build

   1 cpp = meson.get_compiler('cpp')
   2 qt5_dep = dependency('qt5', modules: ['Qml', 'Quick', 'Gui'])
   3 dep_wayland_client = dependency('wayland-client', version: '>= 1.20.0')
   4 dep_qtappfw = [
   5     dependency('qtappfw-weather'),
   6     dependency('qtappfw-network'),
   7     dependency('qtappfw-bt'),
   8     dependency('qtappfw-vehicle-signals'),
   9     dependency('qtappfw-applauncher')
  10 ]
  11
  12 grpcpp_reflection_dep = cpp.find_library('grpc++_reflection')
  13 protoc = find_program('protoc')
  14 grpc_cpp = find_program('grpc_cpp_plugin')
  15
  16 qt_defines = []
  17 qpa_header_path = join_paths(qt5_dep.version(), 'QtGui')
  18 qpa_header = join_paths(qpa_header_path, 'qpa/qplatformnativeinterface.h')
  19 # we pass this QT_QPA_HEADER straight in the code as there's no easy
  20 # way to pass the correct header
  21 if cpp.has_header(qpa_header, dependencies : qt5_dep)
  22   qt_defines += [ '-DQT_QPA_HEADER=<@0@>'.format(qpa_header) ]
  23   message('Found QtGui QPA header in ' + qpa_header_path)
  24 endif
  25
  26 dep_scanner = dependency('wayland-scanner')
  27 prog_scanner = find_program('wayland-scanner')
  28 agl_compositor_dep = dependency('agl-compositor-0.0.21-protocols')
  29 dir_agl_compositor_base = agl_compositor_dep.get_variable(pkgconfig: 'pkgdatadir')
  30
  31 protoc_gen = generator(protoc, \
  32                        output : ['@BASENAME@.pb.cc', '@BASENAME@.pb.h'],
  33                        arguments : ['--proto_path=@CURRENT_SOURCE_DIR@/proto',
  34                          '--cpp_out=@BUILD_DIR@',
  35                          '@INPUT@'])
  36
  37 generated_protoc_sources = protoc_gen.process('proto/agl_shell.proto')
  38
  39 grpc_gen = generator(protoc, \
  40                      output : ['@BASENAME@.grpc.pb.cc', '@BASENAME@.grpc.pb.h'],
  41                      arguments : ['--proto_path=@CURRENT_SOURCE_DIR@/proto',
  42                        '--grpc_out=@BUILD_DIR@',
  43                        '--plugin=protoc-gen-grpc=' + grpc_cpp.path(),
  44                        '@INPUT@'])
  45 generated_grpc_sources = grpc_gen.process('proto/agl_shell.proto')
  46
  47 grpc_deps = [
  48     dependency('protobuf'),
  49     dependency('grpc'),
  50     dependency('grpc++'),
  51     grpcpp_reflection_dep,
  52 ]
  53
  54
  55 homescreen_dep = [
  56     qt5_dep,
  57     dep_wayland_client,
  58     dep_qtappfw,
  59     grpc_deps
  60 ]
  61
  62 homescreen_resources = [
  63   'qml/images/MediaPlayer/mediaplayer.qrc',
  64   'qml/images/MediaMusic/mediamusic.qrc',
  65   'qml/images/Weather/weather.qrc',
  66   'qml/images/Shortcut/shortcut.qrc',
  67   'qml/images/Status/status.qrc',
  68   'qml/images/images.qrc',
  69   'qml/qml.qrc'
  70 ]
  71
  72 resource_files = qt5.compile_resources(sources: homescreen_resources)
  73
  74 protocols = [
  75         [ 'agl-shell', 'agl-compositor' ],
  76 ]
  77
  78 foreach proto: protocols
  79         proto_name = proto[0]
  80         if proto[1] == 'agl-compositor'
  81                 base_file = proto_name
  82                 xml_path = join_paths(dir_agl_compositor_base, '@0@.xml'.format(base_file))
  83         endif
  84
  85         foreach output_type: [ 'client-header', 'server-header', 'private-code' ]
  86                 if output_type == 'client-header'
  87                         output_file = '@0@-client-protocol.h'.format(base_file)
  88                 elif output_type == 'server-header'
  89                         output_file = '@0@-server-protocol.h'.format(base_file)
  90                 else
  91                         output_file = '@0@-protocol.c'.format(base_file)
  92                         if dep_scanner.version().version_compare('< 1.14.91')
  93                                 output_type = 'code'
  94                         endif
  95                 endif
  96
  97                 var_name = output_file.underscorify()
  98                 target = custom_target(
  99                         '@0@ @1@'.format(base_file, output_type),
 100                         command: [ prog_scanner, output_type, '@INPUT@', '@OUTPUT@' ],
 101                         input: xml_path,
 102                         output: output_file,
 103                 )
 104                 message('protocol name is ' + var_name)
 105                 set_variable(var_name, target)
 106         endforeach
 107 endforeach
 108
 109 homescreen_src_headers = [
 110   'src/applicationlauncher.h',
 111   'src/mastervolume.h',
 112   'src/statusbarmodel.h',
 113   'src/statusbarserver.h',
 114   'src/homescreenhandler.h',
 115   'src/AglShellGrpcClient.h',
 116 ]
 117
 118 moc_files = qt5.compile_moc(headers: homescreen_src_headers,
 119                             dependencies: qt5_dep)
 120
 121 homescreen_src = [
 122   'src/statusbarserver.cpp',
 123   'src/statusbarmodel.cpp',
 124   'src/applicationlauncher.cpp',
 125   'src/mastervolume.cpp',
 126   'src/homescreenhandler.cpp',
 127   'src/AglShellGrpcClient.cpp',
 128   'src/main.cpp',
 129   agl_shell_client_protocol_h,
 130   agl_shell_protocol_c,
 131   generated_protoc_sources,
 132   generated_grpc_sources
 133 ]
 134
 135 executable('homescreen', homescreen_src, resource_files, moc_files,
 136             cpp_args: qt_defines,
 137             dependencies : homescreen_dep,
 138             install: true)