meta-ivi-common/recipes-multimedia/audiomanager/audiomanager_7.3.bb

   1 SUMMARY = "Genivi AudioManager"
   2 HOMEPAGE = "https://www.genivi.org/"
   3 SECTION = "multimedia"
   4
   5 LICENSE = "MPLv2"
   6 LIC_FILES_CHKSUM = "file://LICENCE;md5=f164349b56ed530a6642e9b9f244eec5"
   7 PR = "r1"
   8
   9 DEPENDS = "dlt-daemon dbus"
  10
  11 BRANCH = "master"
  12
  13 SRC_URI = " \
  14     git://git.projects.genivi.org/AudioManager.git;branch=${BRANCH};tag=${PV} \
  15     file://0001-Fix-duplicated-command-line-arg-t.patch \
  16     file://AudioManager.service \
  17     "
  18
  19 S = "${WORKDIR}/git"
  20 inherit autotools gettext cmake pkgconfig systemd
  21
  22 EXTRA_OECMAKE += "-DWITH_TESTS=OFF -DUSE_BUILD_LIBS=OFF -DWITH_SYSTEMD_WATCHDOG=ON \
  23     -DWITH_DBUS_WRAPPER=ON"
  24 OECMAKE_CXX_FLAGS +="-ldl"
  25
  26 PACKAGECONFIG ??= ""
  27
  28 # With CommonAPI support
  29 PACKAGECONFIG[capi] = "-DWITH_CAPI_WRAPPER=ON,-DWITH_CAPI_WRAPPER=OFF,common-api-c++-dbus"
  30
  31 FILES_${PN} += " \
  32     ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '${systemd_user_unitdir}/AudioManager.service', '', d)} \
  33     "
  34
  35 do_install_append() {
  36     if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
  37         install -m 644 -p -D ${WORKDIR}/AudioManager.service ${D}${systemd_user_unitdir}/AudioManager.service
  38
  39         mkdir -p ${D}/etc/systemd/user/default.target.wants/
  40         ln -sf ${systemd_user_unitdir}/AudioManager.service ${D}/etc/systemd/user/dbus-org.genivi.AudioManager.service
  41         ln -sf ${systemd_user_unitdir}/AudioManager.service ${D}/etc/systemd/user/default.target.wants/AudioManager.service
  42     fi
  43 }