meta-agl/recipes-multimedia/lightmediascanner/lightmediascanner_0.5.1.bb

   1 SUMMARY = "Lightweight media scanner"
   2 DESCRIPTION = "Lightweight media scanner meant to be used in not-so-powerful devices, like embedded systems or old machines."
   3 SECTION = "libs/multimedia"
   4
   5 LICENSE = "LGPLv2.1+"
   6 LIC_FILES_CHKSUM = "file://COPYING;md5=a6f89e2100d9b6cdffcea4f398e37343 \
   7                     file://src/lib/lightmediascanner.c;endline=21;md5=6d8889bccb4c6c27e8b786342a3eb267"
   8
   9 DEPENDS = "file gawk glib-2.0 sqlite3"
  10
  11 PV = "0.5.1+git${SRCPV}"
  12 SRCREV = "adfddb3486276a5ed2f5008c9e43a811e1271cc9"
  13 SRC_URI = "git://github.com/profusion/lightmediascanner.git \
  14            file://id3-plugin-support-out-of-tree-build.patch \
  15           "
  16
  17 S = "${WORKDIR}/git"
  18
  19 inherit autotools pkgconfig
  20
  21 EXTRA_OECONF = "--enable-static --disable-mp4"
  22
  23 PACKAGECONFIG ??= "ogg flac wave id3 m3u pls asf rm jpeg png"
  24 PACKAGECONFIG[generic] = "--enable-generic,--disable-generic,libav"
  25 PACKAGECONFIG[ogg] = "--enable-ogg,--disable-ogg,libogg libvorbis libtheora"
  26 PACKAGECONFIG[flac] = "--enable-flac,--disable-flac,flac"
  27 PACKAGECONFIG[wave] = "--enable-wave,--disable-wave"
  28 PACKAGECONFIG[id3] = "--enable-id3,--disable-id3"
  29 PACKAGECONFIG[m3u] = "--enable-m3u,--disable-m3u"
  30 PACKAGECONFIG[pls] = "--enable-pls,--disable-pls"
  31 PACKAGECONFIG[asf] = "--enable-asf,--disable-asf"
  32 PACKAGECONFIG[rm] = "--enable-rm,--disable-rm"
  33 PACKAGECONFIG[jpeg] = "--enable-jpeg,--disable-jpeg"
  34 PACKAGECONFIG[png] = "--enable-png,--disable-png"
  35
  36 do_install_append() {
  37        # Install "test" binary for corresponding package
  38        install -d ${D}/${bindir}
  39        install -m 755 ${B}/src/bin/.libs/test ${D}/${bindir}/test-lms
  40        # Remove .la files for loadable modules
  41        rm -f ${D}/${libdir}/${PN}/plugins/*.la
  42 }
  43
  44 FILES_${PN} += "${datadir}/dbus-1"
  45 FILES_${PN}-dbg += "${libdir}/${PN}/plugins/.debug"
  46
  47 PACKAGES_prepend = "${PN}-test "
  48 FILES_${PN}-test_prepend = "${bindir}/test-lms "
  49
  50 PACKAGES += "${PN}-meta"
  51 ALLOW_EMPTY_${PN}-meta = "1"
  52
  53 PACKAGES_DYNAMIC = "${PN}-plugin-*"
  54
  55 python populate_packages_prepend () {
  56     lms_libdir = d.expand('${libdir}/${PN}')
  57     pkgs = []
  58
  59     pkgs += do_split_packages(d, oe.path.join(lms_libdir, "plugins"), '^(.*)\.so$', d.expand('${PN}-plugin-%s'), 'LightMediaScanner plugin for %s', prepend=True, extra_depends=d.expand('${PN}'))
  60     metapkg = d.getVar('PN', True) + '-meta'
  61     d.setVar('RDEPENDS_' + metapkg, ' '.join(pkgs))
  62 }