meta-agl/recipes-connectivity/rygel/rygel_0.26.1.bb

   1 SUMMARY = "A UPnP AV media server and renderer"
   2 DESCRIPTION = "Rygel is a home media solution (UPnP AV MediaServer) that \
   3 allow you to easily share audio, video and pictures to other devices. \
   4 Additionally, media player software may use Rygel to become a MediaRenderer \
   5 that may be controlled remotely by a UPnP or DLNA Controller."
   6 HOMEPAGE = "http://live.gnome.org/Rygel"
   7
   8 LICENSE = "LGPLv2+"
   9 LIC_FILES_CHKSUM = "file://COPYING;md5=5f30f0716dfdd0d91eb439ebec522ec2 \
  10                     file://src/rygel/rygel-main.vala;endline=25;md5=a4cce4d389da1c1638fe68d07ae9d811"
  11
  12 DEPENDS = "libxml2 glib-2.0 gssdp gupnp gupnp-av gupnp-dlna gstreamer1.0 gstreamer1.0-plugins-base ossp-uuid libgee-0.8 libsoup-2.4 libmediaart-2.0"
  13 RDEPENDS_${PN} = "gstreamer1.0-plugins-base-playback shared-mime-info"
  14
  15 GNOME_COMPRESS_TYPE = "xz"
  16 SRC_URI[archive.md5sum] = "f182d54913a528bb5b4fb2f291aca0fc"
  17 SRC_URI[archive.sha256sum] = "390740609e34399b886ddb9a8f7eca25055ad72048dfdd869edf02999b1e1d8f"
  18
  19 inherit gnomebase vala
  20
  21 EXTRA_OECONF = "--disable-introspection --disable-tracker-plugin --with-media-engine=gstreamer"
  22
  23 PACKAGECONFIG ?= "external mpris mediathek ruih media-export gst-launch gtk+3"
  24 PACKAGECONFIG[external] = "--enable-external-plugin,--disable-external-plugin"
  25 PACKAGECONFIG[mpris] = "--enable-mpris-plugin,--disable-mpris-plugin"
  26 PACKAGECONFIG[mediathek] = "--enable-mediathek-plugin,--disable-mediathek-plugin"
  27 PACKAGECONFIG[ruih] = "--enable-ruih-plugin,--disable-ruih-plugin"
  28 PACKAGECONFIG[media-export] = "--enable-media-export-plugin,--disable-media-export-plugin,sqlite3"
  29 PACKAGECONFIG[gst-launch] = "--enable-gst-launch-plugin,--disable-gst-launch-plugin"
  30 PACKAGECONFIG[gtk+3] = ",--without-ui,gtk+3"
  31
  32 LIBV = "2.6"
  33
  34 do_install_append() {
  35        # Remove .la files for loadable modules
  36        rm -f ${D}/${libdir}/rygel-${LIBV}/engines/*.la
  37        rm -f ${D}/${libdir}/rygel-${LIBV}/plugins/*.la
  38 }
  39
  40 FILES_${PN} += "${libdir}/rygel-${LIBV}/engines ${datadir}/dbus-1 ${datadir}/icons"
  41 FILES_${PN}-dbg += "${libdir}/rygel-${LIBV}/engines/.debug ${libdir}/rygel-${LIBV}/plugins/.debug"
  42
  43 PACKAGES += "${PN}-meta"
  44 ALLOW_EMPTY_${PN}-meta = "1"
  45
  46 PACKAGES_DYNAMIC = "${PN}-plugin-*"
  47
  48 python populate_packages_prepend () {
  49     rygel_libdir = d.expand('${libdir}/rygel-${LIBV}')
  50     postinst = d.getVar('plugin_postinst', True)
  51     pkgs = []
  52
  53     pkgs += do_split_packages(d, oe.path.join(rygel_libdir, "plugins"), 'librygel-(.*)\.so$', d.expand('${PN}-plugin-%s'), 'Rygel plugin for %s', postinst=postinst, extra_depends=d.expand('${PN}'))
  54     pkgs += do_split_packages(d, oe.path.join(rygel_libdir, "plugins"), '(.*)\.plugin$', d.expand('${PN}-plugin-%s'), 'Rygel plugin for %s', postinst=postinst, extra_depends=d.expand('${PN}'))
  55
  56     metapkg = d.getVar('PN', True) + '-meta'
  57     d.setVar('RDEPENDS_' + metapkg, ' '.join(pkgs))
  58 }