meta-agl-core/recipes-graphics/wayland/agl-compositor_git.bb

   1 SUMMARY = "Reference Wayland compositor for AGL"
   2 DESCRIPTION = "The AGL compositor is a reference Wayland server for Automotive \
   3 Grade Linux, using libweston as a base to provide a graphical environment for \
   4 the automotive environment."
   5
   6 HOMEPAGE = "https://gerrit.automotivelinux.org/gerrit/q/project:src%252Fagl-compositor"
   7 SECTION = "x11"
   8 LICENSE = "MIT"
   9 LIC_FILES_CHKSUM = "file://COPYING;md5=fac6abe0003c4d142ff8fa1f18316df0"
  10
  11 DEPENDS = "wayland wayland-protocols wayland-native weston"
  12
  13 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/src/agl-compositor.git;protocol=https;branch=${AGL_BRANCH}"
  14 SRCREV = "e3f8379e48433d1ba9236f959c2cb4c78da4c38a"
  15 AGL_BRANCH:aglnext = "next"
  16 SRCREV:aglnext = "${AUTOREV}"
  17
  18 AGL_COMPOSITOR_VERSION = "0.0.22"
  19
  20 PV = "${AGL_COMPOSITOR_VERSION}+git${SRCPV}"
  21 S = "${WORKDIR}/git"
  22
  23 PACKAGECONFIG ?= ""
  24 PACKAGECONFIG[policy-rba] = "-Dpolicy-default=rba,,librba,librba rba-config"
  25 PACKAGECONFIG[policy-deny-all] = "-Dpolicy-default=deny-all,,"
  26 PACKAGECONFIG[grpc-proxy] = "-Dgrpc-proxy=true,-Dgrpc-proxy=false,grpc grpc-native,grpc agl-shell-grpc-server"
  27
  28 inherit meson pkgconfig python3native
  29
  30 # Reuse include file from upstream weston since we have the same requirements
  31 require recipes-graphics/wayland/required-distro-features.inc
  32
  33 PACKAGES =+ "agl-shell-grpc-server"
  34
  35 LDFLAGS:append:riscv64 = " -Wl,--no-as-needed -latomic -Wl,--as-needed"
  36
  37 FILES:${PN} = " \
  38     ${bindir}/agl-compositor \
  39     ${bindir}/agl-screenshooter \
  40     ${libdir}/agl-compositor/libexec_compositor.so.0 \
  41     ${libdir}/agl-compositor/libexec_compositor.so.${AGL_COMPOSITOR_VERSION} \
  42 "
  43
  44 FILES:agl-shell-grpc-server = " \
  45     ${libdir}/agl-compositor/agl-shell-grpc-server \
  46 "
  47
  48 RDEPENDS:${PN} += " \
  49     agl-compositor-init \
  50     xkeyboard-config \
  51 "
  52
  53 FILES:${PN}-dev += " \
  54     ${datadir}/agl-compositor/protocols/agl-shell.xml \
  55     ${datadir}/agl-compositor/protocols/agl-shell-desktop.xml \
  56     ${libdir}/agl-compositor/libexec_compositor.so \
  57 "