meta-agl-core/conf/distro/poky-agl.conf

   1 require conf/distro/poky.conf
   2
   3 # Insert overrides "agldefaulttune" and "forcedefaulttune" before forcevariable
   4 OVERRIDES = "${TARGET_OS}:${TRANSLATED_TARGET_ARCH}:pn-${PN}:${MACHINEOVERRIDES}:${DISTROOVERRIDES}:${CLASSOVERRIDE}${LIBCOVERRIDE}:agldefaulttune:forcedefaulttune:forcevariable"
   5
   6 # AGL specific derivations
   7 DISTRO = "poky-agl"
   8 DISTRO_NAME = "Automotive Grade Linux"
   9
  10
  11 # Release flags
  12 DISTRO_CODENAME = "quillback"
  13 AGL_BRANCH = "quillback"
  14 AGLVERSION = "17.0.1"
  15
  16 # switch  devel/release
  17 #AGLRELEASETYPE ?= "agldevelopment"
  18 AGLRELEASETYPE := "aglrelease"
  19
  20 OVERRIDES .= ":${AGLRELEASETYPE}"
  21
  22 #for development
  23 DISTRO_VERSION:agldevelopment := "${AGLVERSION}+snapshot-${METADATA_REVISION}"
  24
  25 #for release
  26 DISTRO_VERSION:aglrelease := "${AGLVERSION}"
  27 DISTRO_BRANCH_VERSION_TAG = "${DISTRO_CODENAME}/${@'${DISTRO_VERSION}'.replace('+snapshot-${METADATA_REVISION}','')}"
  28
  29 # reproducible builds:
  30 # Set the desired timestamps
  31 # E.g. update for (major) releases
  32 export SOURCE_DATE_EPOCH = "1712000000"
  33 REPRODUCIBLE_TIMESTAMP_ROOTFS = "1712000000"
  34
  35
  36 # SDK
  37 SDK_VENDOR = "-aglsdk"
  38
  39 # SDKPATHINSTALL is the folder where the SDK is going to be installed
  40 # Due to an issue with the qt5 environment (see SPEC-1667),
  41 # we add DEFAULTTUNE to the SDKPATH to mitigate the issue.
  42 SDKPATHINSTALL = "/opt/agl-sdk/${SDK_VERSION}-${DEFAULTTUNE}"
  43
  44
  45 MAINTAINER = "AGL https://lists.automotivelinux.org/g/agl-dev-community"
  46
  47 TARGET_VENDOR = "-agl"
  48
  49 # Override these in poky based distros
  50 AGL_DEFAULT_DISTRO_FEATURES = "usrmerge largefile opengl wayland pam bluetooth bluez5 3g polkit"
  51 POKY_DEFAULT_DISTRO_FEATURES := "${AGL_DEFAULT_DISTRO_FEATURES}"
  52 OVERRIDES .= ":${DISTRO_CODENAME}"
  53
  54 DISTRO_FEATURES:remove = "x11"
  55 DISTRO_FEATURES_BACKFILL_CONSIDERED = "pulseaudio"
  56
  57 INIT_MANAGER = "systemd"
  58 # Override default of "systemd-compat-units"
  59 VIRTUAL-RUNTIME_initscripts = ""
  60 # Override default of "busybox-syslog"
  61 VIRTUAL-RUNTIME_base-utils-syslog = ""
  62
  63 # network manager to use (possible values: systemd, connman)
  64 VIRTUAL-RUNTIME_net_manager = "connman"
  65
  66
  67 QEMU_TARGETS ?= "arm aarch64 i386 x86_64 riscv64"
  68 # Other QEMU_TARGETS "mips mips64 mips64el ppc sh4"
  69
  70 MIRRORS =+ "\
  71 bzr://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  72 cvs://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  73 git://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  74 gitsm://.*/.*    https://download.automotivelinux.org/AGL/mirror/ \n \
  75 hg://.*/.*       https://download.automotivelinux.org/AGL/mirror/ \n \
  76 osc://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  77 p4://.*/.*       https://download.automotivelinux.org/AGL/mirror/ \n \
  78 svn://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  79 bzr://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  80 cvs://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  81 git://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  82 gitsm://.*/.*    http://download.automotivelinux.org/AGL/mirror/  \n \
  83 hg://.*/.*       http://download.automotivelinux.org/AGL/mirror/  \n \
  84 osc://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  85 p4://.*/.*       http://download.automotivelinux.org/AGL/mirror/  \n \
  86 svn://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  87                  \
  88 ftp://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  89 http://.*/.*     https://download.automotivelinux.org/AGL/mirror/ \n \
  90 https://.*/.*    https://download.automotivelinux.org/AGL/mirror/ \n \
  91 ftp://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  92 http://.*/.*     http://download.automotivelinux.org/AGL/mirror/  \n \
  93 https://.*/.*    http://download.automotivelinux.org/AGL/mirror/  \n \
  94 "
  95
  96 # The CONNECTIVITY_CHECK_URI's are used to test whether we can succesfully
  97 # fetch from the network (and warn you if not). To disable the test set
  98 # the variable to be empty.
  99 # Git example url: git://git.yoctoproject.org/yocto-firewall-test;protocol=git;rev=HEAD
 100 CONNECTIVITY_CHECK_URIS ?= ""
 101
 102 # using multiple BSP layers causes dangling bbappends in meta-agl-bsp
 103 # turn it into a warning
 104 #BB_DANGLINGAPPENDS_WARNONLY = "1"
 105
 106 # Not yet upstreamed; should be submitted.
 107 SECURITY_CFLAGS:pn-qtwebengine = "${SECURITY_NO_PIE_CFLAGS}"
 108
 109 #Redefined USER_CLASSES
 110 #Disable prelink. It is unmaintained and likely will go away.
 111 #default: USER_CLASSES ?= "buildstats image-prelink"
 112 USER_CLASSES = "buildstats"
 113
 114 # AGL uses 4 optimization levels
 115 # 2 for ARM 32bit
 116 #   - a high and a medium setting for the CCARGS
 117 #   - the high setting is default (needs >= cortex-a15)
 118 #   - the medium setting is enabled with: DISTRO_FEATURES:append = " agl-medium-arm-compiler "
 119 # 1 for ARM 64bit / AARCH64
 120 # 1 for x86-64
 121 # 1 for RISC-V 64-bit
 122 require conf/distro/include/${TARGET_ARCH}-tune.inc
 123
 124 # Generic qemu and qemuboot (runqemu) enhancements
 125 # check qemuboot.bbclass
 126 # - use 2G RAM by default
 127 QB_MEM ?= "-m 2048"
 128 # use pulseaudio on the host side - off as qemu-native is built with alsa
 129 #QB_AUDIO_DRV = "pa"
 130 # expose a virtual 'hda' sound card to the guest (arm/aarch64/x86-64)
 131 QB_AUDIO_OPT = "-device intel-hda -device hda-duplex -audiodev alsa,id=agl"
 132
 133 # Board templates can add extra IMAGE_FSTYPES through this.
 134 # It is added (late) through the AGL image recipes.
 135 AGL_EXTRA_IMAGE_FSTYPES ??= ""
 136 AGL_EXTRA_INITRAMFS_FSTYPES ??= ""
 137 #
 138 # Default IMAGE FSTYPES wic.xz
 139 AGL_DEFAULT_IMAGE_FSTYPES ?= "wic.xz wic.bmap wic.xz.sha256sum"
 140 AGL_DEFAULT_IMAGE_FSTYPES:qemuall ?= "${@bb.utils.contains('AGL_FEATURES', 'AGLCI', 'ext4.xz', 'ext4', d)}"
 141 AGL_DEFAULT_IMAGE_FSTYPES:append:netboot = " ${@bb.utils.contains('AGL_FEATURES', 'AGLCI', 'ext4.xz', 'ext4', d)}"
 142 AGL_DEFAULT_INITRAMFS_FSTYPES ?= "ext4.gz"
 143
 144 # DEFAULT IMAGE_FSTYPES for AGL (no - BSPs should not set this)
 145 #
 146 IMAGE_FSTYPES = "${AGL_DEFAULT_IMAGE_FSTYPES} ${AGL_EXTRA_IMAGE_FSTYPES}"
 147 INITRAMFS_FSTYPES = "${AGL_DEFAULT_INITRAMFS_FSTYPES} ${AGL_EXTRA_INITRAMFS_FSTYPES}"
 148 #
 149
 150 # Fix for rpm metadata clash between nativesdk-cmake and nativesdk-qtbase-tools
 151 # (revalidate after 2017-10-15, 2018-06-12: still required)
 152 DIRFILES:pn-nativesdk-cmake = "1"
 153
 154 # For https://jira.automotivelinux.org/browse/SPEC-1629 :
 155 # We exclude the conflicting vars from the sstate task hash.
 156 # This needs to be verified.
 157 do_package_write_rpm[vardepsexclude] += "ARCHIVER_TOPDIR PF"
 158