Add tbtnavi cluster navigation application

Add recipe for tbtnavi turn by turn navigation application for use on
cluster remote display, and update packagegroup-agl-demo-platform to
pull it in when PREFERRED_RPROVIDER_virtual/navigation is ondemandnavi
(the default) and the agl-cluster-demo-support feature is enabled.

Bug-AGL: SPEC-2913

Change-Id: I0280fe3a2fbd3ff58a028232560b421e83baa887
Signed-off-by: Scott Murray <scott.murray@konsulko.com>

diff --git a/recipes-demo-hmi/navigation/tbtnavi_git.bb b/recipes-demo-hmi/navigation/tbtnavi_git.bb
new file mode 100644 (file)
index 0000000..88680ed
--- /dev/null
+++ b/recipes-demo-hmi/navigation/tbtnavi_git.bb
@@ -0,0 +1,33 @@
+SUMMARY     = "AGL Reference Navigation Cluster Streaming application"
+DESCRIPTION = "Demo AGL turn by turn cluster navigation application based on QtLocation widget."
+HOMEPAGE    = "https://gerrit.automotivelinux.org/gerrit/admin/repos/apps/tbtnavi"
+SECTION     = "apps"
+
+LICENSE     = "Apache-2.0 & ISC & BSD-3-Clause & BSL-1.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984 \
+                    file://LICENSE.mapbox-cheap-ruler-cpp;md5=761263ee6bdc98e8697d9fbc897021ba \
+                    file://LICENSE.mapbox-geometry.hpp;md5=6e44f5d6aeec54f40fc84eebe3c6fc6c \
+                    file://LICENSE.mapbox-variant;md5=79558839a9db3e807e4ae6f8cd100c1c \
+                    file://include/mapbox/recursive_wrapper.hpp;beginline=4;endline=13;md5=cd3341aae76c0cf8345935abd20f0051 \
+"
+
+DEPENDS += "qtbase \
+            qtquickcontrols2 \
+            qlibhomescreen \
+            qlibwindowmanager \
+            qtlocation \
+"
+
+PV = "1.0+git${SRCPV}"
+
+SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/tbtnavi;protocol=https;branch=${AGL_BRANCH}"
+#SRCREV  = "4a8b7a6301e4b093c99329d0a16fbee6c535f312"
+SRCREV = "${AGL_APP_REVISION}"
+
+S = "${WORKDIR}/git"
+
+inherit qmake5 aglwgt pkgconfig
+
+RDEPENDS_${PN} += "qtlocation \
+                   ondemandnavi-config \
+"

diff --git a/recipes-platform/packagegroups/packagegroup-agl-demo-platform.bb b/recipes-platform/packagegroups/packagegroup-agl-demo-platform.bb
index d0de2bf..7e57b63 100644 (file)
--- a/recipes-platform/packagegroups/packagegroup-agl-demo-platform.bb
+++ b/recipes-platform/packagegroups/packagegroup-agl-demo-platform.bb
@@ -69,15 +69,14 @@ AGL_APIS = " \
 QTAGLEXTRAS = "${@bb.utils.contains("DISTRO_FEATURES", "agl-hmi-framework", " qtaglextras", "",d)}"
 
 # Cluster demo support.
-# ATM mapviewer is required for navigation map viewing when doing cluster
-# demos with the older navigation application.
-MAPVIEWER = "${@bb.utils.contains("PREFERRED_PROVIDER_virtual/navigation", "navigation", "mapviewer", "",d)}"
+# ATM no cluster map viewer is supported with the older navigation application.
+MAPVIEWER = "${@bb.utils.contains("PREFERRED_RPROVIDER_virtual/navigation", "ondemandnavi", "tbtnavi", "",d)}"
 CLUSTER_SUPPORT = "${@bb.utils.contains("DISTRO_FEATURES", "agl-cluster-demo-support", "${MAPVIEWER} cluster-demo-network-config", "",d)}"
 
 # Preload poi API key for demo if requested, and potentially maps for older
 # navigation application if it is configured.
 DEMO_MAPS_LOCALE ?= "uk"
-DEMO_PRELOAD_MAPS = "${@bb.utils.contains("PREFERRED_PROVIDER_virtual/navigation", "navigation", " navigation-maps-${DEMO_MAPS_LOCALE}", "",d)}"
+DEMO_PRELOAD_MAPS = "${@bb.utils.contains("PREFERRED_RPROVIDER_virtual/navigation", "navigation", " navigation-maps-${DEMO_MAPS_LOCALE}", "",d)}"
 DEMO_PRELOAD = "${@bb.utils.contains("DISTRO_FEATURES", "agl-demo-preload", " ${DEMO_PRELOAD_MAPS} poiapp-api-key", "",d)}"
 
 # Hook for demo platform configuration