recipes-wam/wam/wam_git.bb

   1 SUMMARY = "WAM"
   2 AUTHOR = "Jani Hautakangas <jani.hautakangas@lge.com>"
   3 LICENSE = "Apache-2.0"
   4 LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/Apache-2.0;md5=89aea4e17d99a7cacdbeed46a0096b10"
   5
   6 inherit cmake
   7
   8 DEPENDS = "glib-2.0 jsoncpp boost chromium84 libhomescreen protobuf protobuf-native"
   9
  10 EXTRA_OECMAKE = "\
  11     -DCMAKE_BUILD_TYPE=Release \
  12     -DCMAKE_INSTALL_PREFIX=${prefix} \
  13     -DPLATFORM_NAME=${@'${DISTRO}'.upper().replace('-', '_')} \
  14     -DCHROMIUM_SRC_DIR=${STAGING_INCDIR}/chromium84"
  15
  16 PR="r0"
  17
  18 PROVIDES += "virtual/webruntime"
  19 RPROVIDES:${PN} += "virtual/webruntime"
  20
  21 # Disable some of securit_flags
  22 # Disable D_FORTIFY_SOURCE=2 and -fstack-protector-strong
  23 # Refer conf/distro/include/security_flags.inc in meta-webos/conf/distro/include/webos.inc
  24 lcl_maybe_fortify = ""
  25 SECURITY_STACK_PROTECTOR = ""
  26
  27 SRC_URI = "\
  28     git://github.com/igalia/${BPN}.git;branch=koi;protocol=https \
  29     file://WebAppMgr@.service \
  30     file://WebAppMgr.env \
  31     file://wam-user-setup.sh \
  32     file://wam-user-setup@.service \
  33     file://trunc-webapp-roles.patch \
  34 "
  35 S = "${WORKDIR}/git"
  36 SRCREV = "2a246d2ea79bd335b86942a5579d6de0c9ddce40"
  37
  38 do_install:append() {
  39     install -d ${D}${sysconfdir}/wam
  40     install -v -m 644 ${S}/files/launch/security_policy.conf ${D}${sysconfdir}/wam/security_policy.conf
  41     install -d ${D}${systemd_system_unitdir}
  42     install -v -m 644 ${WORKDIR}/WebAppMgr@.service ${D}${systemd_system_unitdir}/WebAppMgr@.service
  43     install -d ${D}${sysconfdir}/default/
  44     install -v -m 644 ${WORKDIR}/WebAppMgr.env ${D}${sysconfdir}/default/WebAppMgr.env
  45     ln -snf WebAppMgr ${D}${bindir}/web-runtime
  46     install -d ${D}${systemd_system_unitdir}/afm-user-session@.target.wants
  47     ln -sf ../WebAppMgr@.service ${D}${systemd_system_unitdir}/afm-user-session@.target.wants/
  48     install -d ${D}${libexecdir}/wam/
  49     install -v -m 755 ${WORKDIR}/wam-user-setup.sh ${D}${libexecdir}/wam/wam-user-setup.sh
  50     install -v -m 644 ${WORKDIR}/wam-user-setup@.service ${D}${systemd_system_unitdir}/wam-user-setup@.service
  51     install -d ${D}${systemd_system_unitdir}/user-runtime-dir@.service.wants/
  52     ln -sf ../wam-user-setup@.service ${D}${systemd_system_unitdir}/user-runtime-dir@.service.wants/
  53 }
  54
  55 FILES:${PN} += "${sysconfdir}/init ${sysconfdir}/wam ${libdir}/webappmanager/plugins/*.so ${systemd_system_unitdir}"
  56
  57 CXXFLAGS:append:agl-devel = " -DAGL_DEVEL"
  58
  59 do_install:append:agl-devel() {
  60     # Enable remote inspector and dev mode
  61     install -d ${D}${localstatedir}/agl-devel/preferences
  62     touch ${D}${localstatedir}/agl-devel/preferences/debug_system_apps
  63     touch ${D}${localstatedir}/agl-devel/preferences/devmode_enabled
  64 }