recipes-wam/chromium/chromium_git.bb

   1 require chromium.inc
   2
   3 SRC_URI = "\
   4     git://github.com/igalia/chromium91;branch=@17.agl;protocol=https;rev=${SRCREV_chromium91};name=chromium91 \
   5     git://github.com/webosose/chromium-v8;branch=@chromium91;destsuffix=git/src/v8;rev=${SRCREV_v8};name=v8;protocol=https \
   6 "
   7
   8 # Needed by catapult
   9 DEPENDS += "python-six-native python-beautifulsoup4-native python-lxml-native python-html5lib-native python-webencodings-native"
  10
  11 SRCREV_chromium91 = "40fa88380696f62a3644efa6ae4fafda402698f7"
  12 SRCREV_v8 = "b958ec542dcb086f422a1216a959be38a4cc0339"
  13
  14 CHROMIUM_VERSION = "91.0.4472.114"
  15 PV_BRANCH_SUFFIX = "ose17.agl"
  16
  17 PV = "${CHROMIUM_VERSION}.${PV_BRANCH_SUFFIX}+git"
  18
  19 GN_ARGS += "use_gtk=false"
  20
  21 # Disable closure compile
  22 # Else we need HOSTTOOLS += "java"
  23 GN_ARGS += " \
  24   enable_mojom_closure_compile=false\
  25   enable_js_type_check=false\
  26 "
  27
  28 # When using meta-clang, one can switch to using the lld linker
  29 # by using the ld-is-lld distro feature otherwise use gold linker
  30 GN_ARGS += "${@bb.utils.contains('DISTRO_FEATURES', 'ld-is-lld', 'use_lld=true use_gold=false', bb.utils.contains('DISTRO_FEATURES', 'ld-is-gold', 'use_lld=false use_gold=true', 'use_lld=false use_gold=false', d), d)}"
  31
  32 # Toolchains we will use for the build. We need to point to the toolchain file
  33 # we've created, set the right target architecture and make sure we are not
  34 # using Chromium's toolchain (bundled clang, bundled binutils etc).
  35 GN_ARGS += "\
  36     host_toolchain=\"//build/toolchain/cros:host\" \
  37     cros_host_is_clang=false \
  38     use_custom_libcxx_for_host=false \
  39     cros_host_ar=\"${BUILD_AR}\" \
  40     cros_host_cc=\"${BUILD_CC} ${BUILD_CFLAGS}\" \
  41     cros_host_cxx=\"${BUILD_CXX} ${BUILD_CXXFLAGS}\" \
  42     cros_host_extra_ldflags=\"${BUILD_LDFLAGS}\" \
  43     custom_toolchain=\"//build/toolchain/cros:target\" \
  44     is_clang=false \
  45     use_custom_libcxx=false \
  46     target_cpu=\"${@gn_arch_name('${TUNE_ARCH}')}\" \
  47     cros_target_ar=\"${AR}\" \
  48     cros_target_cc=\"${CC}\" \
  49     cros_target_cxx=\"${CXX}\" \
  50     cros_target_extra_ldflags=\"${LDFLAGS}\" \
  51     v8_snapshot_toolchain=\"//build/toolchain/cros:v8_snapshot\" \
  52     cros_v8_snapshot_is_clang=false \
  53     cros_v8_snapshot_ar=\"${BUILD_AR}\" \
  54     cros_v8_snapshot_cc=\"${BUILD_CC}\" \
  55     cros_v8_snapshot_cxx=\"${BUILD_CXX}\" \
  56     gold_path=\"\" \
  57     v8_enable_embedded_builtins=false \
  58     use_v8_context_snapshot=false \
  59 "
  60
  61 GN_ARGS:append = " \
  62   ozone_platform_wayland_external=false \
  63   ozone_platform_wayland=true \
  64   use_system_libwayland=true \
  65   use_system_wayland_scanner=false \
  66   use_system_minigbm=false \
  67   use_wayland_gbm=false \
  68 "
  69
  70 GN_ARGS:append = " \
  71   is_webos=false \
  72   is_agl=true \
  73   grpc_use_static_linking=true \
  74 "
  75
  76 # TODO: drop this after we migrate to ubuntu 16.04 or above
  77 GN_ARGS += "\
  78     fatal_linker_warnings=false\
  79 "
  80
  81 # TODO(rzanoni) copied from original recipe to fix qemux86 build.
  82 # check if it can be removed in the future.
  83 PACKAGECONFIG:remove:qemux86 = "gstreamer umediaserver neva-media gav neva-webrtc"
  84 #END TODO