recipes-wam/chromium/chromium.inc

   1 # Copyright (c) 2018 LG Electronics, Inc.
   2
   3 SUMMARY = "Chromium webruntime for webOS"
   4 AUTHOR = "Lokesh Kumar Goel <lokeshkumar.goel@lge.com>"
   5 SECTION = "webos/apps"
   6 LICENSE = "Apache-2.0 & BSD-3-Clause & LGPL-2.0-only & LGPL-2.1-only"
   7 LIC_FILES_CHKSUM = "\
   8     file://src/LICENSE;md5=0fca02217a5d49a14dfe2d11837bb34d \
   9     file://src/third_party/blink/renderer/core/LICENSE-LGPL-2;md5=36357ffde2b64ae177b2494445b79d21 \
  10     file://src/third_party/blink/renderer/core/LICENSE-LGPL-2.1;md5=a778a33ef338abbaf8b8a7c36b6eec80 \
  11 "
  12
  13 require gn-utils.inc
  14
  15 inherit gettext qemu pythonnative pkgconfig
  16
  17 DEPENDS = "virtual/gettext wayland wayland-native pixman freetype glib-2.0 fontconfig openssl pango cairo icu libxkbcommon libexif dbus pciutils udev libcap alsa-lib virtual/egl elfutils-native libdrm atk at-spi2-atk gperf-native gconf nss nss-native nspr nspr-native bison-native qemu-native curl"
  18
  19 SRCREV_v8 = "1e3af71f1ff3735e8a5b639c48dfca63a7b8a647"
  20
  21 # we don't include SRCPV in PV, so we have to manually include SRCREVs in do_fetch vardeps
  22 do_fetch[vardeps] += "SRCREV_v8"
  23 SRCREV_FORMAT = "main_v8"
  24
  25 S = "${WORKDIR}/git"
  26
  27 SRC_DIR = "${S}/src"
  28 BUILD_TYPE = "Release"
  29
  30 B = "${WORKDIR}/build"
  31 OUT_DIR = "${B}/${BUILD_TYPE}"
  32
  33 WEBRUNTIME_BUILD_TARGET = "webos:weboswebruntime"
  34
  35 TARGET = "${WEBRUNTIME_BUILD_TARGET}"
  36
  37 # Skip do_install:append of webos_system_bus. It is not compatible with this component.
  38 WEBOS_SYSTEM_BUS_FILES_LOCATION = "${S}/files/sysbus"
  39
  40 PACKAGECONFIG[lttng] = "use_lttng=true,use_lttng=false,lttng-ust,lttng-tools lttng-modules babeltrace"
  41
  42 # Chromium can use v4l2 device for hardware accelerated video decoding on such boards as Renesas R-car M3, for example.
  43 # In case of R-car m3, additional patches are required for gstreamer and v4l2apps.
  44 # See https://github.com/igel-oss/meta-browser-hwdecode/tree/igalia-chromium71.
  45 PACKAGECONFIG[use-linux-v4l2] = "use_v4l2_codec=true use_v4lplugin=true use_linux_v4l2_only=true"
  46
  47 # Options to enable debug build. Add this PACKAGECONFIG to local.conf
  48 # to enable debug build. By default debug is completely disabled to
  49 # speed up build
  50 PACKAGECONFIG[debug] = "symbol_level=2 use_debug_fission=true,symbol_level=1"
  51 PACKAGECONFIG[debug-blink] = "blink_symbol_level=2 use_debug_fission=true,blink_symbol_level=1"
  52
  53 GN_ARGS = "\
  54     enable_memorymanager_webapi=false\
  55     ffmpeg_branding=\"Chrome\"\
  56     host_os=\"linux\"\
  57     ozone_auto_platforms=false\
  58     proprietary_codecs=true\
  59     target_os=\"linux\"\
  60     treat_warnings_as_errors=false\
  61     use_x11=false\
  62     is_agl=true\
  63     use_cbe=true\
  64     is_chrome_cbe=false\
  65     is_component_build=false\
  66     use_cups=false\
  67     use_custom_libcxx=false\
  68     use_kerberos=false\
  69     use_neva_media=false\
  70     use_ozone=true\
  71     use_xkbcommon=true\
  72     use_wayland_gbm=false\
  73     use_pmlog=false\
  74     use_system_debugger_abort=true\
  75     ${PACKAGECONFIG_CONFARGS}\
  76 "
  77
  78 # From Chromium's BUILDCONFIG.gn:
  79 # Set to enable the official build level of optimization. This has nothing
  80 # to do with branding, but enables an additional level of optimization above
  81 # release (!is_debug). This might be better expressed as a tri-state
  82 # (debug, release, official) but for historical reasons there are two
  83 # separate flags.
  84 # See also: https://groups.google.com/a/chromium.org/d/msg/chromium-dev/hkcb6AOX5gE/PPT1ukWoBwAJ
  85 GN_ARGS += "is_debug=false is_official_build=true"
  86
  87 # is_cfi default value is true for x86-64 builds with is_official_build=true.
  88 # As of M63, we explicitly need to set it to false, otherwise we fail the
  89 # following assertion in //build/config/sanitizers/sanitizers.gni:
  90 #   assert(!is_cfi || is_clang,
  91 #          "is_cfi requires setting is_clang = true in 'gn args'")
  92 GN_ARGS += "is_cfi=false"
  93
  94 # use_thin_lto should be also disabled for GCC
  95 GN_ARGS += "use_thin_lto=false"
  96
  97 # We do not want to use Chromium's own Debian-based sysroots, it is easier to
  98 # just let Chromium's build system assume we are not using a sysroot at all and
  99 # let Yocto handle everything.
 100 GN_ARGS += "use_sysroot=false"
 101
 102 # Reduce the size of the build by removing swiftshader and dawn.
 103 # This will effectively block support for WebGPU.
 104 # TODO(jdapena): reenable WebGPU support
 105 GN_ARGS += "use_swiftshader=false enable_swiftshader_vulkan=false use_dawn=false"
 106
 107 # ARM builds need special additional flags (see ${S}/build/config/arm.gni).
 108 # If we do not pass |arm_arch| and friends to GN, it will deduce a value that
 109 # will then conflict with TUNE_CCARGS and CC.
 110 # Note that as of M61 in some corner cases parts of the build system disable
 111 # the "compiler_arm_fpu" GN config, whereas -mfpu is always passed via ${CC}.
 112 # We might want to rework that if there are issues in the future.
 113 def get_compiler_flag(params, param_name, d):
 114     """Given a sequence of compiler arguments in |params|, returns the value of
 115     an option |param_name| or an empty string if the option is not present."""
 116     for param in params:
 117       if param.startswith(param_name):
 118         return param.split('=')[1]
 119     return ''
 120
 121 ARM_FLOAT_ABI = "${@bb.utils.contains('TUNE_FEATURES', 'callconvention-hard', 'hard', 'softfp', d)}"
 122 ARM_FPU = "${@get_compiler_flag(d.getVar('TUNE_CCARGS').split(), '-mfpu', d)}"
 123 ARM_TUNE = "${@get_compiler_flag(d.getVar('TUNE_CCARGS').split(), '-mcpu', d)}"
 124 ARM_VERSION:aarch64 = "8"
 125 ARM_VERSION:armv7a = "7"
 126 ARM_VERSION:armv7ve = "7"
 127 ARM_VERSION:armv6 = "6"
 128
 129 # GN computes and defaults to it automatically where needed
 130 # forcing it from cmdline breaks build on places where it ends up
 131 # overriding what GN wants
 132 TUNE_CCARGS:remove = "-mthumb"
 133
 134 GN_ARGS:append:arm = " \
 135         arm_float_abi=\"${ARM_FLOAT_ABI}\" \
 136         arm_fpu=\"${ARM_FPU}\" \
 137         arm_tune=\"${ARM_TUNE}\" \
 138         arm_version=${ARM_VERSION} \
 139 "
 140 # tcmalloc's atomicops-internals-arm-v6plus.h uses the "dmb" instruction that
 141 # is not available on (some?) ARMv6 models, which causes the build to fail.
 142 GN_ARGS:append:armv6 = ' use_allocator="none"'
 143 # The WebRTC code fails to build on ARMv6 when NEON is enabled.
 144 # https://bugs.chromium.org/p/webrtc/issues/detail?id=6574
 145 GN_ARGS:append:armv6 = ' arm_use_neon=false'
 146
 147 # Disable glibc shims on musl
 148 # tcmalloc does not play well with musl as of M62 (and possibly earlier).
 149 # https://github.com/gperftools/gperftools/issues/693
 150 GN_ARGS:append:libc-musl = ' use_allocator_shim=false'
 151
 152 # Chromium 91 build of highway with NEON is broken. Do not build.
 153 GN_ARGS:append:aarch64 = ' enable_jxl_decoder=false'
 154
 155 # More options to speed up the build
 156 GN_ARGS += "\
 157     enable_nacl=false\
 158     disable_ftp_support=true\
 159     enable_print_preview=false\
 160     enable_basic_printing=false\
 161     enable_remoting=false\
 162     use_glib=true\
 163     use_gnome_keyring=false\
 164     use_pulseaudio=false\
 165 "
 166
 167 # Doesn't build for armv[45]*
 168 COMPATIBLE_MACHINE = "(-)"
 169 COMPATIBLE_MACHINE:aarch64 = "(.*)"
 170 COMPATIBLE_MACHINE:armv6 = "(.*)"
 171 COMPATIBLE_MACHINE:armv7a = "(.*)"
 172 COMPATIBLE_MACHINE:armv7ve = "(.*)"
 173 COMPATIBLE_MACHINE:x86 = "(.*)"
 174 COMPATIBLE_MACHINE:x86-64 = "(.*)"
 175
 176 #CHROMIUM_PLUGINS_PATH = "${libdir}"
 177 CBE_DATA_PATH = "${libdir}/cbe"
 178 CBE_DATA_LOCALES_PATH = "${CBE_DATA_PATH}/locales"
 179
 180 # The text relocations are intentional -- see comments in [GF-52468]
 181 # TODO: check if we need INSANE_SKIP on ldflags
 182 INSANE_SKIP:${PN} = "textrel ldflags"
 183
 184
 185 do_compile[progress] = "outof:^\[(\d+)/(\d+)\]\s+"
 186 do_compile() {
 187     if [ ! -f ${OUT_DIR}/build.ninja ]; then
 188          do_configure
 189     fi
 190
 191     export PATH="${S}/depot_tools:$PATH"
 192     ${S}/depot_tools/ninja ${PARALLEL_MAKE} -C ${OUT_DIR} ${TARGET}
 193 }
 194
 195 do_configure() {
 196     configure_env
 197 }
 198
 199 configure_env() {
 200     export GYP_CHROMIUM_NO_ACTION=1
 201     export PATH="${S}/depot_tools:$PATH"
 202
 203     GN_ARGS="${GN_ARGS}"
 204     echo GN_ARGS is ${GN_ARGS}
 205     echo BUILD_TARGETS are ${TARGET}
 206     cd ${SRC_DIR}
 207     gn gen ${OUT_DIR} --args="${GN_ARGS}"
 208 }
 209
 210 WINDOW_SIZE ?= "1920,1080"
 211
 212 install_webruntime() {
 213
 214     # # Generate install webos webview files
 215     # ${S}/depot_tools/ninja ${PARALLEL_MAKE} -C ${OUT_DIR} webos/install/weboswebruntime
 216
 217     # # Move installation files to D directory
 218     # mv ${OUT_DIR}/image/* ${D}
 219     # # Rename include and locale directories
 220     # mv ${D}${includedir}/webruntime ${D}${includedir}/${BPN}
 221     # mv ${D}${CBE_DATA_PATH}/neva_locales ${D}${CBE_DATA_LOCALES_PATH}
 222
 223     install -d ${D}${libdir}
 224     # install -d ${D}${libdir}/swiftshader
 225     install -d ${D}${includedir}/${BPN}
 226     install -d ${D}${CBE_DATA_PATH}
 227     install -d ${D}${CBE_DATA_LOCALES_PATH}
 228
 229     # Install webos webview files
 230     ${S}/depot_tools/ninja ${PARALLEL_MAKE} -C ${OUT_DIR} webos/install/weboswebruntime
 231
 232     # install -v -m 0644 ${OUT_DIR}/swiftshader/*.so ${D}${libdir}/swiftshader
 233
 234     cp -R --no-dereference --preserve=mode,links -v ${OUT_DIR}/image/${includedir}/${BPN}/* ${D}${includedir}/${BPN}/
 235     install -v -m 0644 ${OUT_DIR}/image/${libdir}/*.so ${D}${libdir}
 236
 237     install -v -m 0644 ${OUT_DIR}/image/${CBE_DATA_PATH}/icudtl.dat ${D}${CBE_DATA_PATH}
 238     install -v -m 0644 ${OUT_DIR}/image/${CBE_DATA_PATH}/snapshot_blob.bin ${D}${CBE_DATA_PATH}
 239     # app_runtime_content.pak, webos_content.pak, extensions_shell_and_test.pak
 240     install -v -m 0644 ${OUT_DIR}/image/${CBE_DATA_PATH}/*.pak ${D}${CBE_DATA_PATH}
 241
 242     cp -R --no-dereference --preserve=mode,links -v ${OUT_DIR}/image/${CBE_DATA_LOCALES_PATH}/*.pak ${D}${CBE_DATA_LOCALES_PATH}
 243
 244     chown root:root -R ${D}${libdir}
 245     chown root:root -R ${D}${includedir}
 246     chown root:root -R ${D}${CBE_DATA_LOCALES_PATH}
 247 }
 248
 249 do_install() {
 250     install_webruntime
 251 }
 252
 253 SYSROOT_DIRS:append = " ${bindir_cross}"
 254
 255 VIRTUAL-RUNTIME_gpu-libs ?= ""
 256 RDEPENDS:${PN} += "${VIRTUAL-RUNTIME_gpu-libs}"
 257
 258 FILES:${PN} = " \
 259     ${libdir}/*.so \
 260     ${CBE_DATA_PATH}/* \
 261     ${libdir}/${BPN}/*.so \
 262 "
 263
 264 FILES:${PN}-dev = " \
 265     ${includedir} \
 266 "