recipes-wam/chromium/chromium.inc

   1 # Copyright (c) 2018 LG Electronics, Inc.
   2
   3 SUMMARY = "Chromium webruntime for webOS"
   4 AUTHOR = "Lokesh Kumar Goel <lokeshkumar.goel@lge.com>"
   5 SECTION = "webos/apps"
   6 LICENSE = "Apache-2.0 & BSD-3-Clause & LGPL-2.0 & LGPL-2.1"
   7 LIC_FILES_CHKSUM = "\
   8     file://src/LICENSE;md5=0fca02217a5d49a14dfe2d11837bb34d \
   9     file://src/third_party/blink/renderer/core/LICENSE-LGPL-2;md5=36357ffde2b64ae177b2494445b79d21 \
  10     file://src/third_party/blink/renderer/core/LICENSE-LGPL-2.1;md5=a778a33ef338abbaf8b8a7c36b6eec80 \
  11 "
  12
  13 require gn-utils.inc
  14
  15 inherit gettext qemu pythonnative
  16
  17 DEPENDS = "virtual/gettext wayland wayland-native pixman freetype glib-2.0 fontconfig openssl pango cairo icu libxkbcommon libexif dbus pciutils udev libcap alsa-lib virtual/egl elfutils-native libdrm atk at-spi2-atk gperf-native gconf nss nss-native nspr nspr-native bison-native qemu-native"
  18
  19 PROVIDES = "${BROWSER_APPLICATION}"
  20
  21 SRCREV_v8 = "1e3af71f1ff3735e8a5b639c48dfca63a7b8a647"
  22
  23 # we don't include SRCPV in PV, so we have to manually include SRCREVs in do_fetch vardeps
  24 do_fetch[vardeps] += "SRCREV_v8"
  25 SRCREV_FORMAT = "main_v8"
  26
  27 S = "${WORKDIR}/git"
  28
  29 SRC_DIR = "${S}/src"
  30 OUT_DIR = "${WORKDIR}/build"
  31 BUILD_TYPE = "Release"
  32
  33 B = "${OUT_DIR}/${BUILD_TYPE}"
  34
  35 OUT_IMAGE_DIR = "${B}/image"
  36
  37 WEBRUNTIME_BUILD_TARGET = "webos:weboswebruntime"
  38 BROWSER_APP_BUILD_TARGET = "chrome"
  39 BROWSER_APPLICATION = "chromium84-browser"
  40 BROWSER_APPLICATION_DIR = "/opt/chromium84"
  41
  42 TARGET = "${WEBRUNTIME_BUILD_TARGET}"
  43
  44 # Skip do_install_append of webos_system_bus. It is not compatible with this component.
  45 WEBOS_SYSTEM_BUS_FILES_LOCATION = "${S}/files/sysbus"
  46
  47 PACKAGECONFIG ?= "jumbo use-upstream-wayland"
  48
  49
  50 # Set a default value for jumbo file merge of 8. This should be good for build
  51 # servers and workstations with a big number of cores. In case build is
  52 # happening in a machine with less cores but still enough RAM a good value could
  53 # be 50.
  54 JUMBO_FILE_MERGE_LIMIT="8"
  55 PACKAGECONFIG[jumbo] = "use_jumbo_build=true jumbo_file_merge_limit=${JUMBO_FILE_MERGE_LIMIT}, use_jumbo_build=false"
  56
  57 PACKAGECONFIG[lttng] = "use_lttng=true,use_lttng=false,lttng-ust,lttng-tools lttng-modules babeltrace"
  58
  59 # Chromium can use v4l2 device for hardware accelerated video decoding on such boards as Renesas R-car M3, for example.
  60 # In case of R-car m3, additional patches are required for gstreamer and v4l2apps.
  61 # See https://github.com/igel-oss/meta-browser-hwdecode/tree/igalia-chromium71.
  62 PACKAGECONFIG[use-linux-v4l2] = "use_v4l2_codec=true use_v4lplugin=true use_linux_v4l2_only=true"
  63
  64 PACKAGECONFIG[use-upstream-wayland] = " \
  65     ozone_platform_wayland_external=false ozone_platform_wayland=true, \
  66     ozone_platform_wayland_external=true ozone_platform_wayland=false \
  67 "
  68
  69 GN_ARGS = "\
  70     enable_memorymanager_webapi=false\
  71     ffmpeg_branding=\"Chrome\"\
  72     host_os=\"linux\"\
  73     ozone_auto_platforms=false\
  74     proprietary_codecs=true\
  75     target_os=\"linux\"\
  76     treat_warnings_as_errors=false\
  77     is_agl=true\
  78     use_cbe=true\
  79     is_chrome_cbe=false\
  80     use_cups=false\
  81     use_custom_libcxx=false\
  82     use_kerberos=false\
  83     use_neva_media=false\
  84     use_ozone=true\
  85     use_xkbcommon=true\
  86     use_wayland_gbm=false\
  87     use_pmlog=false\
  88     use_system_debugger_abort=true\
  89     ${PACKAGECONFIG_CONFARGS}\
  90 "
  91
  92 # From Chromium's BUILDCONFIG.gn:
  93 # Set to enable the official build level of optimization. This has nothing
  94 # to do with branding, but enables an additional level of optimization above
  95 # release (!is_debug). This might be better expressed as a tri-state
  96 # (debug, release, official) but for historical reasons there are two
  97 # separate flags.
  98 # See also: https://groups.google.com/a/chromium.org/d/msg/chromium-dev/hkcb6AOX5gE/PPT1ukWoBwAJ
  99 GN_ARGS += "is_debug=false is_official_build=true"
 100
 101 # is_cfi default value is true for x86-64 builds with is_official_build=true.
 102 # As of M63, we explicitly need to set it to false, otherwise we fail the
 103 # following assertion in //build/config/sanitizers/sanitizers.gni:
 104 #   assert(!is_cfi || is_clang,
 105 #          "is_cfi requires setting is_clang = true in 'gn args'")
 106 GN_ARGS += "is_cfi=false"
 107
 108 # By default, passing is_official_build=true to GN causes its symbol_level
 109 # variable to be set to "2". This means the compiler will be passed "-g2" and
 110 # we will end up with a very large chrome binary (around 5Gb as of M58)
 111 # regardless of whether DEBUG_BUILD has been set or not. In addition, binutils,
 112 # file and other utilities are unable to read a 32-bit binary this size, which
 113 # causes it not to be stripped.
 114 # The solution is two-fold:
 115 # 1. Make sure -g is not passed on 32-bit architectures via DEBUG_FLAGS. -g is
 116 #    the same as -g2. -g1 generates an 800MB binary, which is a lot more
 117 #    manageable.
 118 # 2. Explicitly pass symbol_level=0 to GN. This causes -g0 to be passed
 119 #    instead, so that if DEBUG_BUILD is not set GN will not create a huge debug
 120 #    binary anyway. Since our compiler flags are passed after GN's, -g0 does
 121 #    not cause any issues if DEBUG_BUILD is set, as -g1 will be passed later.
 122 DEBUG_FLAGS_remove_arm = "-g"
 123 DEBUG_FLAGS_append_arm = "-g1"
 124 DEBUG_FLAGS_remove_x86 = "-g"
 125 DEBUG_FLAGS_append_x86 = "-g1"
 126 GN_ARGS += "symbol_level=0"
 127
 128 # We do not want to use Chromium's own Debian-based sysroots, it is easier to
 129 # just let Chromium's build system assume we are not using a sysroot at all and
 130 # let Yocto handle everything.
 131 GN_ARGS += "use_sysroot=false"
 132
 133 # ARM builds need special additional flags (see ${S}/build/config/arm.gni).
 134 # If we do not pass |arm_arch| and friends to GN, it will deduce a value that
 135 # will then conflict with TUNE_CCARGS and CC.
 136 # Note that as of M61 in some corner cases parts of the build system disable
 137 # the "compiler_arm_fpu" GN config, whereas -mfpu is always passed via ${CC}.
 138 # We might want to rework that if there are issues in the future.
 139 def get_compiler_flag(params, param_name, d):
 140     """Given a sequence of compiler arguments in |params|, returns the value of
 141     an option |param_name| or an empty string if the option is not present."""
 142     for param in params:
 143       if param.startswith(param_name):
 144         return param.split('=')[1]
 145     return ''
 146
 147 ARM_FLOAT_ABI = "${@bb.utils.contains('TUNE_FEATURES', 'callconvention-hard', 'hard', 'softfp', d)}"
 148 ARM_FPU = "${@get_compiler_flag(d.getVar('TUNE_CCARGS').split(), '-mfpu', d)}"
 149 ARM_TUNE = "${@get_compiler_flag(d.getVar('TUNE_CCARGS').split(), '-mcpu', d)}"
 150 ARM_VERSION_aarch64 = "8"
 151 ARM_VERSION_armv7a = "7"
 152 ARM_VERSION_armv7ve = "7"
 153 ARM_VERSION_armv6 = "6"
 154
 155 # GN computes and defaults to it automatically where needed
 156 # forcing it from cmdline breaks build on places where it ends up
 157 # overriding what GN wants
 158 TUNE_CCARGS_remove = "-mthumb"
 159
 160 GN_ARGS_append_arm = " \
 161         arm_float_abi=\"${ARM_FLOAT_ABI}\" \
 162         arm_fpu=\"${ARM_FPU}\" \
 163         arm_tune=\"${ARM_TUNE}\" \
 164         arm_version=${ARM_VERSION} \
 165 "
 166 # tcmalloc's atomicops-internals-arm-v6plus.h uses the "dmb" instruction that
 167 # is not available on (some?) ARMv6 models, which causes the build to fail.
 168 GN_ARGS_append_armv6 += 'use_allocator="none"'
 169 # The WebRTC code fails to build on ARMv6 when NEON is enabled.
 170 # https://bugs.chromium.org/p/webrtc/issues/detail?id=6574
 171 GN_ARGS_append_armv6 += 'arm_use_neon=false'
 172
 173 # Disable glibc shims on musl
 174 # tcmalloc does not play well with musl as of M62 (and possibly earlier).
 175 # https://github.com/gperftools/gperftools/issues/693
 176 GN_ARGS_append_libc-musl = ' use_allocator_shim=false'
 177
 178 # More options to speed up the build
 179 GN_ARGS += "\
 180     enable_nacl=false\
 181     disable_ftp_support=true\
 182     enable_print_preview=false\
 183     enable_remoting=false\
 184     use_glib=true\
 185     use_gnome_keyring=false\
 186     use_pulseaudio=false\
 187 "
 188
 189 # Doesn't build for armv[45]*
 190 COMPATIBLE_MACHINE = "(-)"
 191 COMPATIBLE_MACHINE_aarch64 = "(.*)"
 192 COMPATIBLE_MACHINE_armv6 = "(.*)"
 193 COMPATIBLE_MACHINE_armv7a = "(.*)"
 194 COMPATIBLE_MACHINE_armv7ve = "(.*)"
 195 COMPATIBLE_MACHINE_x86 = "(.*)"
 196 COMPATIBLE_MACHINE_x86-64 = "(.*)"
 197
 198 #CHROMIUM_PLUGINS_PATH = "${libdir}"
 199 CBE_DATA_PATH = "${libdir}/cbe"
 200 CBE_DATA_LOCALES_PATH = "${CBE_DATA_PATH}/locales"
 201
 202 # The text relocations are intentional -- see comments in [GF-52468]
 203 # TODO: check if we need INSANE_SKIP on ldflags
 204 INSANE_SKIP_${PN} = "textrel ldflags"
 205
 206
 207 do_compile[progress] = "outof:^\[(\d+)/(\d+)\]\s+"
 208 do_compile() {
 209     if [ ! -f ${OUT_DIR}/${BUILD_TYPE}/build.ninja ]; then
 210          do_configure
 211     fi
 212
 213     export PATH="${S}/depot_tools:$PATH"
 214     ${S}/depot_tools/ninja ${PARALLEL_MAKE} -v -C ${OUT_DIR}/${BUILD_TYPE} ${TARGET}
 215 }
 216
 217 do_configure() {
 218     configure_env
 219 }
 220
 221 configure_env() {
 222     export GYP_CHROMIUM_NO_ACTION=1
 223     export PATH="${S}/depot_tools:$PATH"
 224
 225     GN_ARGS="${GN_ARGS}"
 226     echo GN_ARGS is ${GN_ARGS}
 227     echo BUILD_TARGETS are ${TARGET}
 228     cd ${SRC_DIR}
 229     gn gen ${OUT_DIR}/${BUILD_TYPE} --args="${GN_ARGS}"
 230 }
 231
 232 WINDOW_SIZE ?= "1920,1080"
 233
 234 configure_browser_settings() {
 235     USER_AGENT="Mozilla/5.0 (Linux; NetCast; U) AppleWebKit/537.31 (KHTML, like Gecko) Chrome/${CHROMIUM_VERSION} Safari/537.31"
 236     echo "${USER_AGENT}" > ${D_DIR}/user_agent_conf
 237     #We can replace below WINDOW_SIZE values from build configuration if available
 238     #echo "${WINDOW_SIZE}" > ${D_DIR}/window_size_conf
 239 }
 240
 241 install_chromium_browser() {
 242     D_DIR=${D}${BROWSER_APPLICATION_DIR}
 243     install -d ${D_DIR}
 244
 245     # Install browser files
 246      if [ -e "${SRC_DIR}/webos/install" ]; then
 247          cd ${OUT_DIR}/${BUILD_TYPE}
 248          xargs --arg-file=${SRC_DIR}/webos/install/default_browser/binary.list cp -R --no-dereference --preserve=mode,links -v --target-directory=${D_DIR}
 249          cd ${SRC_DIR}
 250          xargs --arg-file=${SRC_DIR}/webos/install/default_browser/runtime.list cp -R --no-dereference --preserve=mode,links -v --target-directory=${D_DIR}
 251      fi
 252
 253     # AGL does not have PMLOG
 254     sed -i.bak s/PmLogCtl.*// ${D_DIR}/run_webbrowser
 255
 256     # To execute chromium in JAILER, Security Part needs permissions change
 257     # run_webbrowser: Script file for launching chromium
 258     chmod -v 755 ${D_DIR}/chrome
 259     chmod -v 755 ${D_DIR}/kill_webbrowser
 260     chmod -v 755 ${D_DIR}/run_webbrowser
 261
 262     configure_browser_settings
 263 }
 264
 265 install_webruntime() {
 266
 267     # # Generate install webos webview files
 268     # ${S}/depot_tools/ninja ${PARALLEL_MAKE} -C ${OUT_DIR}/${BUILD_TYPE} webos/install/weboswebruntime
 269
 270     # # Move installation files to D directory
 271     # mv ${OUT_DIR}/${BUILD_TYPE}/image/* ${D}
 272     # # Rename include and locale directories
 273     # mv ${D}${includedir}/webruntime ${D}${includedir}/${BPN}
 274     # mv ${D}${CBE_DATA_PATH}/neva_locales ${D}${CBE_DATA_LOCALES_PATH}
 275
 276     # # move this to separate mksnapshot-cross recipe once we figure out how to build just cross mksnapshot from chromium repository
 277     # install -d ${D}${bindir_cross}
 278     # gzip -c ${OUT_DIR}/${BUILD_TYPE}/${MKSNAPSHOT_PATH}mksnapshot > ${D}${bindir_cross}/${HOST_SYS}-mksnapshot.gz
 279
 280     install -d ${D}${libdir}
 281     install -d ${D}${libdir}/swiftshader
 282     install -d ${D}${includedir}/${BPN}
 283     install -d ${D}${CBE_DATA_PATH}
 284     install -d ${D}${CBE_DATA_LOCALES_PATH}
 285
 286     # Install webos webview files
 287     ${S}/depot_tools/ninja ${PARALLEL_MAKE} -C ${OUT_DIR}/${BUILD_TYPE} webos/install/weboswebruntime
 288
 289     install -v -m 0644 ${OUT_DIR}/${BUILD_TYPE}/swiftshader/*.so ${D}${libdir}/swiftshader
 290
 291     cp -R --no-dereference --preserve=mode,links -v ${OUT_IMAGE_DIR}/${includedir}/${BPN}/* ${D}${includedir}/${BPN}/
 292     install -v -m 0644 ${OUT_IMAGE_DIR}/${libdir}/*.so ${D}${libdir}
 293
 294     install -v -m 0644 ${OUT_IMAGE_DIR}/${CBE_DATA_PATH}/icudtl.dat ${D}${CBE_DATA_PATH}
 295     install -v -m 0644 ${OUT_IMAGE_DIR}/${CBE_DATA_PATH}/snapshot_blob.bin ${D}${CBE_DATA_PATH}
 296     # app_runtime_content.pak, webos_content.pak, extensions_shell_and_test.pak
 297     install -v -m 0644 ${OUT_IMAGE_DIR}/${CBE_DATA_PATH}/*.pak ${D}${CBE_DATA_PATH}
 298
 299     cp -R --no-dereference --preserve=mode,links -v ${OUT_IMAGE_DIR}/${CBE_DATA_LOCALES_PATH}/*.pak ${D}${CBE_DATA_LOCALES_PATH}
 300
 301     chown root:root -R ${D}${libdir}
 302     chown root:root -R ${D}${includedir}
 303     chown root:root -R ${D}${CBE_DATA_LOCALES_PATH}
 304
 305     # move this to separate mksnapshot-cross recipe once we figure out how to build just cross mksnapshot from chromium repository
 306     install -d ${D}${base_bindir}
 307     gzip -c ${OUT_DIR}/${BUILD_TYPE}/${MKSNAPSHOT_PATH}mksnapshot > ${D}${base_bindir}/${HOST_SYS}-mksnapshot.gz
 308
 309 }
 310
 311 do_install() {
 312     install_webruntime
 313 }
 314
 315 WEBOS_SYSTEM_BUS_DIRS_LEGACY_BROWSER_APPLICATION = " \
 316     ${webos_sysbus_prvservicesdir}/${BROWSER_APPLICATION}.service \
 317     ${webos_sysbus_pubservicesdir}/${BROWSER_APPLICATION}.service \
 318     ${webos_sysbus_prvrolesdir}/${BROWSER_APPLICATION}.json \
 319     ${webos_sysbus_pubrolesdir}/${BROWSER_APPLICATION}.json \
 320 "
 321
 322 SYSROOT_DIRS_append = " ${bindir_cross}"
 323
 324 PACKAGES_prepend = " \
 325     ${PN}-cross-mksnapshot \
 326     ${BROWSER_APPLICATION} \
 327 "
 328
 329 FILES_${BROWSER_APPLICATION} += " \
 330     ${BROWSER_APPLICATION_DIR} \
 331     ${WEBOS_SYSTEM_BUS_DIRS_LEGACY_BROWSER_APPLICATION} \
 332 "
 333
 334 RDEPENDS_${BROWSER_APPLICATION} += "${PN}"
 335
 336 VIRTUAL-RUNTIME_gpu-libs ?= ""
 337 RDEPENDS_${PN} += "${VIRTUAL-RUNTIME_gpu-libs}"
 338
 339 # The text relocations are intentional -- see comments in [GF-52468]
 340 # TODO: check if we need INSANE_SKIP on ldflags
 341 INSANE_SKIP_${BROWSER_APPLICATION} += "libdir ldflags textrel"
 342
 343 FILES_${PN} = " \
 344     ${libdir}/*.so \
 345     ${libdir}/swiftshader/*.so \
 346     ${CBE_DATA_PATH}/* \
 347     ${libdir}/${BPN}/*.so \
 348     ${WEBOS_SYSTEM_BUS_DIRS} \
 349 "
 350
 351 FILES_${PN}-dev = " \
 352     ${includedir} \
 353 "
 354
 355 FILES_${PN}-cross-mksnapshot = "${bindir_cross}/${HOST_SYS}-mksnapshot.gz"