recipes-support/vboxguestdrivers/vboxguestdrivers_6.1.2.bb

   1 SUMMARY = "VirtualBox Linux Guest Drivers"
   2 SECTION = "core"
   3 LICENSE = "GPL-2.0"
   4 LIC_FILES_CHKSUM = "file://${WORKDIR}/${VBOX_NAME}/COPYING;md5=e197d5641bb35b29d46ca8c4bf7f2660"
   5
   6 DEPENDS = "virtual/kernel"
   7
   8 inherit module kernel-module-split
   9
  10 COMPATIBLE_MACHINE = "(qemux86|qemux86-64)"
  11
  12 VBOX_NAME = "VirtualBox-${PV}"
  13
  14 SRC_URI = "http://download.virtualbox.org/virtualbox/${PV}/${VBOX_NAME}.tar.bz2 \
  15     file://Makefile.utils \
  16 "
  17 SRC_URI[md5sum] = "f4f42fd09857556b04b803fb99cc6905"
  18 SRC_URI[sha256sum] = "4326576e8428ea3626194fc82646347576e94c61f11d412a669fc8a10c2a1e67"
  19
  20 S = "${WORKDIR}/vbox_module"
  21
  22 export BUILD_TARGET_ARCH="${ARCH}"
  23 export BUILD_TARGET_ARCH_x86-64="amd64"
  24
  25 EXTRA_OEMAKE += "KERN_DIR='${WORKDIR}/${KERNEL_VERSION}/build' KBUILD_VERBOSE=1"
  26
  27 # otherwise 5.2.22 builds just vboxguest
  28 MAKE_TARGETS = "all"
  29
  30 addtask export_sources after do_patch before do_configure
  31
  32 do_export_sources() {
  33     mkdir -p "${S}"
  34     ${WORKDIR}/${VBOX_NAME}/src/VBox/Additions/linux/export_modules.sh ${T}/vbox_modules.tar.gz
  35     tar -C "${S}" -xzf ${T}/vbox_modules.tar.gz
  36
  37     # add a mount utility to use shared folder from VBox Addition Source Code
  38     mkdir -p "${S}/utils"
  39     install ${WORKDIR}/${VBOX_NAME}/src/VBox/Additions/linux/sharedfolders/mount.vboxsf.c ${S}/utils
  40     install ${WORKDIR}/${VBOX_NAME}/src/VBox/Additions/linux/sharedfolders/vbsfmount.c ${S}/utils
  41     install ${S}/../Makefile.utils ${S}/utils/Makefile
  42
  43 }
  44
  45 do_configure_prepend() {
  46     # vboxguestdrivers/5.2.6-r0/vbox_module/vboxguest/Makefile.include.header:99: *** The variable KERN_DIR must be a kernel build folder and end with /build without a trailing slash, or KERN_VER must be set.  Stop.
  47     # vboxguestdrivers/5.2.6-r0/vbox_module/vboxguest/Makefile.include.header:108: *** The kernel build folder path must end in <version>/build, or the variable KERN_VER must be set.  Stop.
  48     mkdir -p ${WORKDIR}/${KERNEL_VERSION}
  49     ln -snf ${STAGING_KERNEL_DIR} ${WORKDIR}/${KERNEL_VERSION}/build
  50 }
  51
  52 # compile and install mount utility
  53 do_compile() {
  54     oe_runmake all
  55     oe_runmake 'LD=${CC}' 'LDFLAGS=${LDFLAGS}' -C ${S}/utils
  56     if ! [ -e vboxguest.ko -a -e vboxsf.ko -a -e vboxvideo.ko ] ; then
  57         echo "ERROR: One of vbox*.ko modules wasn't built"
  58         exit 1
  59     fi
  60 }
  61
  62 module_do_install() {
  63     MODULE_DIR=${D}${nonarch_base_libdir}/modules/${KERNEL_VERSION}/kernel/misc
  64     install -d $MODULE_DIR
  65     install -m 644 vboxguest.ko $MODULE_DIR
  66     install -m 644 vboxsf.ko $MODULE_DIR
  67     install -m 644 vboxvideo.ko $MODULE_DIR
  68 }
  69
  70 do_install_append() {
  71     install -d ${D}${base_sbindir}
  72     install -m 755 ${S}/utils/mount.vboxsf ${D}${base_sbindir}
  73 }
  74
  75 PACKAGES += "kernel-module-vboxguest kernel-module-vboxsf kernel-module-vboxvideo"
  76 RRECOMMENDS_${PN} += "kernel-module-vboxguest kernel-module-vboxsf kernel-module-vboxvideo"
  77
  78 FILES_${PN} = "${base_sbindir}"
  79
  80 # autoload if installed
  81 KERNEL_MODULE_AUTOLOAD += "vboxguest vboxsf vboxvideo"