recipes-qt/qt-cluster/qtcompositor-conf_1.0.bb

   1 SUMMARY = "Configuration files for running wayland with a non-weston compositor"
   2 LICENSE = "MIT"
   3 LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
   4
   5 inherit allarch agl-graphical
   6
   7 do_configure[noexec] = "1"
   8 do_compile[noexec] = "1"
   9
  10 do_install() {
  11     # Add a rule to ensure the 'display' user has permissions to
  12     # open the graphics device
  13     install -d ${D}${sysconfdir}/udev/rules.d
  14     cat >${D}${sysconfdir}/udev/rules.d/zz-dri.rules <<'EOF'
  15 SUBSYSTEM=="drm", MODE="0660", GROUP="${WESTONGROUP}", SECLABEL{smack}="*"
  16 EOF
  17
  18     # user 'display' must also be able to access /dev/input/*
  19     cat >${D}${sysconfdir}/udev/rules.d/zz-input.rules <<'EOF'
  20 SUBSYSTEM=="input", MODE="0660", GROUP="input", SECLABEL{smack}="^"
  21 EOF
  22
  23     # user 'display' must also be able to access /dev/media*, etc.
  24     cat >${D}${sysconfdir}/udev/rules.d/zz-remote-display.rules <<'EOF'
  25 SUBSYSTEM=="media", MODE="0660", GROUP="display", SECLABEL{smack}="*"
  26 SUBSYSTEM=="video4linux", MODE="0660", GROUP="display", SECLABEL{smack}="*"
  27 KERNEL=="uvcs", SUBSYSTEM=="misc", MODE="0660", GROUP="display", SECLABEL{smack}="*"
  28 KERNEL=="rgnmm", SUBSYSTEM=="misc", MODE="0660", GROUP="display", SECLABEL{smack}="*"
  29 EOF
  30 }
  31
  32 do_install:append:imx() {
  33     install -d ${D}${sysconfdir}/udev/rules.d
  34     cat >>${D}${sysconfdir}/udev/rules.d/zz-dri.rules <<'EOF'
  35 SUBSYSTEM=="gpu_class", MODE="0660", GROUP="${WESTONGROUP}", SECLABEL{smack}="*"
  36 EOF
  37
  38 }
  39
  40 RCONFLICTS:${PN} = "weston-init"