recipes-platform/packagegroups/packagegroup-agl-demo.bb

   1 SUMMARY = "The software for AGL IVI DEMO profile"
   2 DESCRIPTION = "A set of packages belong to AGL Demo"
   3
   4 LICENSE = "MIT"
   5
   6 inherit packagegroup
   7
   8 PACKAGES = "\
   9     packagegroup-agl-demo \
  10     "
  11
  12 # HVAC and steering wheel demo dependency
  13 LIN_DRIVERS ??= " sllin"
  14
  15 # Hook for demo platform configuration
  16 # ATM, only used to disable btwilink module on [MH]3ULCB + Kingfisher by default,
  17 # setting DEMO_ENABLE_BTWILINK to "true" in local.conf / site.conf re-enables.
  18 DEMO_ENABLE_BTWILINK ?= ""
  19 DEMO_PLATFORM_CONF = ""
  20 DEMO_PLATFORM_CONF:append:ulcb = "${@bb.utils.contains("DEMO_ENABLE_BTWILINK", "true", "", " btwilink-disable-conf", d)}"
  21
  22 # fonts
  23 TTF_FONTS = " \
  24     ttf-bitstream-vera \
  25     ttf-dejavu-sans \
  26     ttf-dejavu-sans-mono \
  27     ttf-dejavu-serif \
  28     ttf-noto-emoji-color \
  29     source-han-sans-cn-fonts \
  30     source-han-sans-jp-fonts \
  31     source-han-sans-tw-fonts \
  32     source-han-sans-kr-fonts \
  33     "
  34
  35 RDEPENDS:${PN} += " \
  36     udisks2 \
  37     linux-firmware-ath9k \
  38     linux-firmware-ralink \
  39     can-utils \
  40     cannelloni \
  41     iproute2 \
  42     ${LIN_DRIVERS} \
  43     ${DEMO_PLATFORM_CONF} \
  44     ${TTF_FONTS} \
  45     ${@bb.utils.contains('DISTRO_FEATURES', 'webruntime', 'virtual/webruntime', '', d)} \
  46     "