recipes-platform/packagegroups/packagegroup-agl-demo.bb

   1 SUMMARY = "The software for AGL IVI DEMO profile"
   2 DESCRIPTION = "A set of packages belong to AGL Demo"
   3
   4 LICENSE = "MIT"
   5
   6 inherit packagegroup
   7
   8 PACKAGES = "\
   9     packagegroup-agl-demo \
  10     "
  11
  12 ALLOW_EMPTY_${PN} = "1"
  13
  14 # MOST out-of-tree kernel drivers
  15 #################################
  16 MOST_DRIVERS ??= " \
  17     most \
  18     "
  19 # These boards use different kernels - needs to be checked
  20 MOST_DRIVERS_dragonboard-410c ?= ""
  21 MOST_DRIVERS_cyclone5 ?= ""
  22
  23
  24 # HVAC dependencies
  25 ###################
  26 LIN_DRIVERS ??= " sllin sllin-virtual"
  27 # These boards use different kernels - needs to be checked
  28 LIN_DRIVERS_dra7xx-evm ?= "sllin-virtual"
  29 LIN_DRIVERS_dragonboard-410c ?= "sllin-virtual"
  30
  31 # UNICENS service
  32 UNICENS ?= " \
  33     unicens-config \
  34     agl-service-unicens \
  35     agl-service-unicens-controller \
  36     "
  37
  38 # Hook for demo platform configuration
  39 # ATM, only used to disable btwilink module on [MH]3ULCB + Kingfisher by default,
  40 # setting DEMO_ENABLE_BTWILINK to "true" in local.conf / site.conf re-enables.
  41 DEMO_ENABLE_BTWILINK ?= ""
  42 DEMO_PLATFORM_CONF = ""
  43 DEMO_PLATFORM_CONF_append_ulcb = "${@bb.utils.contains("DEMO_ENABLE_BTWILINK", "true", "", " btwilink-disable-conf", d)}"
  44
  45 SMARTDEVICELINK = "${@bb.utils.contains('DISTRO_FEATURES', 'agl-sdl', \
  46     'packagegroup-agl-smartdevicelink', '', d)}"
  47
  48 RDEPENDS_${PN} += "\
  49     udisks2 \
  50     ${SMARTDEVICELINK} \
  51     "
  52
  53 # fonts
  54 TTF_FONTS = " \
  55     ttf-bitstream-vera \
  56     ttf-dejavu-sans \
  57     ttf-dejavu-sans-mono \
  58     ttf-dejavu-serif \
  59     ttf-noto-emoji-color \
  60     source-han-sans-cn-fonts \
  61     source-han-sans-jp-fonts \
  62     source-han-sans-tw-fonts \
  63     "
  64
  65
  66 RDEPENDS_${PN} += " \
  67     linux-firmware-ath9k \
  68     linux-firmware-ralink \
  69     can-utils \
  70     iproute2 \
  71     dhcp-client \
  72     ${UNICENS} \
  73     ${MOST_DRIVERS} \
  74     ${LIN_DRIVERS} \
  75     ${DEMO_PLATFORM_CONF} \
  76     ${TTF_FONTS} \
  77     ${@bb.utils.contains('DISTRO_FEATURES', 'webruntime', 'virtual/webruntime', '', d)} \
  78     "