recipes-platform/packagegroups/packagegroup-agl-demo-platform.bb

   1 SUMMARY = "The software for DEMO platform of AGL IVI profile"
   2 DESCRIPTION = "A set of packages belong to AGL Demo Platform"
   3
   4 LICENSE = "MIT"
   5
   6 inherit packagegroup
   7
   8 PACKAGES = "\
   9     packagegroup-agl-demo-platform \
  10     "
  11
  12 ALLOW_EMPTY_${PN} = "1"
  13
  14 RDEPENDS_${PN} += "\
  15     packagegroup-agl-image-ivi \
  16     "
  17
  18 RDEPENDS_${PN} += "\
  19     packagegroup-agl-profile-graphical-qt5 \
  20     packagegroup-agl-demo \
  21     "
  22
  23 MOST_DRIVERS = " \
  24     most \
  25     "
  26 MOST_DRIVERS_append_m3ulcb = " sllin"
  27
  28 # HVAC dependencies depend on drivers above
  29 MOST_HVAC = " "
  30 MOST_HVAC_append = " \
  31     ${MOST_DRIVERS} \
  32     unicens-config \
  33     agl-service-unicens \
  34     agl-service-unicens-controller \
  35     "
  36
  37 # @Chris: This needs to be checked!
  38 MOST_HVAC_dra7xx-evm = ""
  39 MOST_HVAC_dragonboard-410c = ""
  40
  41 AGL_APPS = " \
  42     dashboard \
  43     hvac \
  44     mediaplayer \
  45     virtual/navigation \
  46     phone \
  47     poiapp \
  48     radio \
  49     settings \
  50     ${@bb.utils.contains('DISTRO_FEATURES', 'agl-devel', 'taskmanager' , '', d)} \
  51     high-level-viwi-service \
  52     agl-service-signal-composer \
  53     low-can-demo \
  54     virtual/mixer \
  55     "
  56
  57 AGL_APIS = " \
  58     libnaviapi-agl \
  59     "
  60
  61 QTAGLEXTRAS = "${@bb.utils.contains("DISTRO_FEATURES", "agl-hmi-framework", " qtaglextras", "",d)}"
  62
  63 # Cluster demo support.
  64 # ATM mapviewer is required for navigation map viewing when doing cluster
  65 # demos with the older navigation application.
  66 MAPVIEWER = "${@bb.utils.contains("PREFERRED_PROVIDER_virtual/navigation", "navigation", "mapviewer", "",d)}"
  67 CLUSTER_SUPPORT = "${@bb.utils.contains("DISTRO_FEATURES", "agl-cluster-demo-support", "${MAPVIEWER} cluster-demo-network-config", "",d)}"
  68
  69 # Preload poi API key for demo if requested, and potentially maps for older
  70 # navigation application if it is configured.
  71 DEMO_MAPS_LOCALE ?= "uk"
  72 DEMO_PRELOAD_MAPS = "${@bb.utils.contains("PREFERRED_PROVIDER_virtual/navigation", "navigation", " navigation-maps-${DEMO_MAPS_LOCALE}", "",d)}"
  73 DEMO_PRELOAD = "${@bb.utils.contains("DISTRO_FEATURES", "agl-demo-preload", " ${DEMO_PRELOAD_MAPS} poiapp-api-key", "",d)}"
  74
  75 # Hook for demo platform configuration
  76 # ATM, only used to disable btwilink module on M3ULCB + Kingfisher by default,
  77 # setting DEMO_ENABLE_BTWILINK to "true" in local.conf / site.conf re-enables.
  78 DEMO_ENABLE_BTWILINK ?= ""
  79 DEMO_PLATFORM_CONF = ""
  80 DEMO_PLATFORM_CONF_append_m3ulcb = "${@bb.utils.contains("DEMO_ENABLE_BTWILINK", "true", "", " btwilink-disable-conf", d)}"
  81
  82 RDEPENDS_${PN}_append = " \
  83     qtquickcontrols2-agl \
  84     qtquickcontrols2-agl-style \
  85     linux-firmware-ralink \
  86     ${MOST_HVAC} \
  87     ${AGL_APPS} \
  88     ${AGL_APIS} \
  89     ${QTAGLEXTRAS} \
  90     ${CLUSTER_SUPPORT} \
  91     ${DEMO_PRELOAD} \
  92     ${DEMO_PLATFORM_CONF} \
  93     "