recipes-platform/packagegroups/packagegroup-agl-demo-platform.bb

   1 SUMMARY = "The software for DEMO platform of AGL IVI profile"
   2 DESCRIPTION = "A set of packages belong to AGL Demo Platform"
   3
   4 LICENSE = "MIT"
   5
   6 inherit packagegroup
   7
   8 PACKAGES = "\
   9     packagegroup-agl-demo-platform \
  10     "
  11
  12 ALLOW_EMPTY_${PN} = "1"
  13
  14 RDEPENDS_${PN} += "\
  15     packagegroup-agl-image-ivi \
  16     "
  17
  18 RDEPENDS_${PN} += "\
  19     packagegroup-agl-profile-graphical-qt5 \
  20     packagegroup-agl-demo \
  21     "
  22
  23
  24 AGL_APPS = " \
  25     dashboard \
  26     hvac \
  27     mediaplayer \
  28     virtual/navigation \
  29     phone \
  30     poiapp \
  31     radio \
  32     settings \
  33     messaging \
  34     ${@bb.utils.contains('DISTRO_FEATURES', 'agl-devel', 'taskmanager' , '', d)} \
  35     ${@bb.utils.contains('DISTRO_FEATURES', 'agl-devel', 'unzip' , '', d)} \
  36     low-can-demo \
  37     virtual/mixer \
  38     ${@bb.utils.contains('IMAGE_FEATURES', 'agl-voiceagent-alexa', 'alexa-viewer' , '', d)} \
  39     "
  40
  41 QTAGLEXTRAS = "${@bb.utils.contains("DISTRO_FEATURES", "agl-hmi-framework", " qtaglextras", "",d)}"
  42 QTAGLEXTRAS_append = " libqtappfw"
  43
  44 # add support for websocket in Qt and QML
  45 QTAGLEXTRAS_append = " qtwebsockets qtwebsockets-qmlplugins"
  46 PREFERRED_PROVIDER_virtual/webruntime = "web-runtime"
  47
  48 #QTAGLEXTRAS_append = " ${@bb.utils.contains('DISTRO_FEATURES', 'agl-devel', 'qtwebengine', '', d)}"
  49 #QTAGLEXTRAS_append = " qtsmarthome cinematicexperience qt5everywheredemo qt5-demo-extrafiles"
  50 #IMAGE_INSTALL_append = " qtwebengine-examples"
  51
  52 # packages from hmi-framework aka homescreen-2017
  53 HOMESCREEN = "packagegroup-hmi-framework"
  54
  55 # Cluster demo support.
  56 # ATM no cluster map viewer is supported with the older navigation application.
  57 MAPVIEWER = "${@bb.utils.contains("PREFERRED_RPROVIDER_virtual/navigation", "ondemandnavi", "tbtnavi", "",d)}"
  58 CLUSTER_SUPPORT_PACKAGES = " \
  59         ${MAPVIEWER} \
  60         cluster-demo-network-config \
  61         cluster-lin-bridging-config \
  62 "
  63 CLUSTER_SUPPORT = "${@bb.utils.contains("DISTRO_FEATURES", "agl-cluster-demo-support", "${CLUSTER_SUPPORT_PACKAGES}", "",d)}"
  64
  65 DEMO_UNIT_CONF ?= ""
  66 # Hook for demo platform configuration
  67 # ATM used for:
  68 # 1) Adding udev configuration and scripts for supporting USB attached
  69 #    I2C devices for RTC and HVAC LED support.
  70 DEMO_UNIT_CONF += " demo-i2c-udev-conf "
  71
  72 # Preload poi API key for demo if requested, and potentially maps for older
  73 # navigation application if it is configured.
  74 DEMO_MAPS_LOCALE ?= "uk"
  75 DEMO_PRELOAD_MAPS = "${@bb.utils.contains("PREFERRED_RPROVIDER_virtual/navigation", "navigation", " navigation-maps-${DEMO_MAPS_LOCALE}", "",d)}"
  76
  77 # Preload only if agl-demo-preload is set
  78 DEMO_PRELOAD = "${@bb.utils.contains("DISTRO_FEATURES", "agl-demo-preload", " ${DEMO_PRELOAD_MAPS} ${DEMO_UNIT_CONF} poiapp-api-key", "",d)}"
  79
  80
  81 RDEPENDS_${PN}_append = " \
  82     qtquickcontrols2-agl \
  83     qtquickcontrols2-agl-style \
  84     ${AGL_APPS} \
  85     ${QTAGLEXTRAS} \
  86     ${CLUSTER_SUPPORT} \
  87     ${DEMO_PRELOAD} \
  88     ${HOMESCREEN} \
  89     "