recipes-platform/packagegroups/packagegroup-agl-demo-platform.bb

   1 SUMMARY = "The software for DEMO platform of AGL IVI profile"
   2 DESCRIPTION = "A set of packages belong to AGL Demo Platform"
   3
   4 LICENSE = "MIT"
   5
   6 inherit packagegroup
   7
   8 PACKAGES = "\
   9     packagegroup-agl-demo-platform \
  10     "
  11
  12 ALLOW_EMPTY_${PN} = "1"
  13
  14 RDEPENDS_${PN} += "\
  15     packagegroup-agl-image-ivi \
  16     "
  17
  18 RDEPENDS_${PN} += "\
  19     packagegroup-agl-profile-graphical-qt5 \
  20     packagegroup-agl-demo \
  21     "
  22
  23 MOST_DRIVERS = " \
  24     most \
  25     "
  26 MOST_DRIVERS_append_m3ulcb = " sllin"
  27
  28 # HVAC dependencies depend on drivers above
  29 MOST_HVAC = " "
  30 MOST_HVAC_append = " \
  31     ${MOST_DRIVERS} \
  32     unicens-config \
  33     agl-service-unicens \
  34     agl-service-unicens-controller \
  35     "
  36
  37 # @Chris: This needs to be checked!
  38 MOST_HVAC_dra7xx-evm = ""
  39 MOST_HVAC_dragonboard-410c = ""
  40
  41 AGL_APPS = " \
  42     dashboard \
  43     hvac \
  44     mediaplayer \
  45     virtual/navigation \
  46     phone \
  47     poiapp \
  48     radio \
  49     settings \
  50     messaging \
  51     ${@bb.utils.contains('DISTRO_FEATURES', 'agl-devel', 'taskmanager' , '', d)} \
  52     high-level-viwi-service \
  53     agl-service-signal-composer \
  54     low-can-demo \
  55     virtual/mixer \
  56     "
  57
  58 AGL_APIS = " \
  59     libnaviapi-agl \
  60     "
  61
  62 QTAGLEXTRAS = "${@bb.utils.contains("DISTRO_FEATURES", "agl-hmi-framework", " qtaglextras", "",d)}"
  63
  64 # Cluster demo support.
  65 # ATM mapviewer is required for navigation map viewing when doing cluster
  66 # demos with the older navigation application.
  67 MAPVIEWER = "${@bb.utils.contains("PREFERRED_PROVIDER_virtual/navigation", "navigation", "mapviewer", "",d)}"
  68 CLUSTER_SUPPORT = "${@bb.utils.contains("DISTRO_FEATURES", "agl-cluster-demo-support", "${MAPVIEWER} cluster-demo-network-config", "",d)}"
  69
  70 # Preload poi API key for demo if requested, and potentially maps for older
  71 # navigation application if it is configured.
  72 DEMO_MAPS_LOCALE ?= "uk"
  73 DEMO_PRELOAD_MAPS = "${@bb.utils.contains("PREFERRED_PROVIDER_virtual/navigation", "navigation", " navigation-maps-${DEMO_MAPS_LOCALE}", "",d)}"
  74 DEMO_PRELOAD = "${@bb.utils.contains("DISTRO_FEATURES", "agl-demo-preload", " ${DEMO_PRELOAD_MAPS} poiapp-api-key", "",d)}"
  75
  76 # Hook for demo platform configuration
  77 # ATM, only used to disable btwilink module on M3ULCB + Kingfisher by default,
  78 # setting DEMO_ENABLE_BTWILINK to "true" in local.conf / site.conf re-enables.
  79 DEMO_ENABLE_BTWILINK ?= ""
  80 DEMO_PLATFORM_CONF = ""
  81 DEMO_PLATFORM_CONF_append_m3ulcb = "${@bb.utils.contains("DEMO_ENABLE_BTWILINK", "true", "", " btwilink-disable-conf", d)}"
  82
  83 RDEPENDS_${PN}_append = " \
  84     qtquickcontrols2-agl \
  85     qtquickcontrols2-agl-style \
  86     linux-firmware-ralink \
  87     ${MOST_HVAC} \
  88     ${AGL_APPS} \
  89     ${AGL_APIS} \
  90     ${QTAGLEXTRAS} \
  91     ${CLUSTER_SUPPORT} \
  92     ${DEMO_PRELOAD} \
  93     ${DEMO_PLATFORM_CONF} \
  94     "