recipes-platform/images/agl-kvm-demo-platform.bb

   1 DESCRIPTION = "AGL KVM+QEMU Demo Platform image."
   2
   3 LICENSE = "MIT"
   4
   5 require recipes-platform/images/agl-image-compositor.bb
   6 require agl-demo-features.inc
   7
   8 IMAGE_FEATURES += "splash package-management ssh-server-openssh"
   9
  10 # If building with "agl-kvm-host-kuksa", the databroker and likely
  11 # some clients run on the host
  12 IMAGE_FEATURES += " \
  13     ${@bb.utils.contains("AGL_FEATURES", "agl-kvm-host-kuksa", "kuksa-val-databroker kuksa-val-databroker-client", "", d)} \
  14     ${@bb.utils.contains("DISTRO_FEATURES", "agl-devel", "can-test-tools" , "", d)} \
  15 "
  16
  17 # Add packages for KVM+QEMU demo platform here
  18 IMAGE_INSTALL += " \
  19     packagegroup-agl-core-connectivity \
  20     kernel-image \
  21     agl-compositor \
  22     weston-ini-conf-kvm \
  23     output-udev-conf \
  24     native-shell-client \
  25     qemu \
  26     ${QEMU_GUEST_CONFIGS} \
  27     util-linux-taskset \
  28     screen \
  29     simple-can-simulator \
  30     alsa-utils \
  31 "
  32
  33 # Potential size reduction options
  34 #IMAGE_LINGUAS = " "
  35 #NO_RECOMMENDATIONS = "1"
  36
  37 GUEST_MACHINE ?= "virtio-${TUNE_ARCH}"
  38
  39 GUEST_VM1_IMAGE ?= "agl-ivi-demo-platform-flutter"
  40 GUEST_VM2_IMAGE ?= "agl-cluster-demo-platform-flutter"
  41
  42 GUEST_IMAGES ?= "agl-kvm-guest:${GUEST_VM1_IMAGE} agl-kvm-guest:${GUEST_VM2_IMAGE}"
  43
  44 QEMU_GUEST_CONFIGS ?= ""
  45
  46 python __anonymous() {
  47     for c in (d.getVar('GUEST_IMAGES') or "").split():
  48         (mc, image) = c.split(':')
  49         dependency = 'mc::' + mc + ':' + image + ':do_image_complete'
  50         d.appendVarFlag('do_rootfs', 'mcdepends', ' ' + dependency)
  51
  52         # Assume there is a qemu-config-X package for guest image X
  53         d.appendVar('QEMU_GUEST_CONFIGS', ' ' + 'qemu-config-' + image)
  54 }
  55
  56 install_guest_images() {
  57     for c in ${GUEST_IMAGES}; do
  58         config=${c%:*}
  59         image=${c#*:}
  60         name=${image}
  61         rm -rf  ${IMAGE_ROOTFS}/var/lib/machines/${name}
  62         install -m 0755 -d ${IMAGE_ROOTFS}/var/lib/machines/${name}
  63         src="${TOPDIR}/tmp-${config}/deploy/images/${GUEST_MACHINE}/${image}-${GUEST_MACHINE}.ext4"
  64         bbnote "Installing ${src}"
  65         install -m 0600 ${src} ${IMAGE_ROOTFS}/var/lib/machines/${name}/
  66         # Placeholder until booting from kernel in VM image is worked out
  67         install -m 0600 ${TOPDIR}/tmp-${config}/deploy/images/${GUEST_MACHINE}/Image-${GUEST_MACHINE}.bin ${IMAGE_ROOTFS}/var/lib/machines/${name}/
  68     done
  69 }
  70
  71 ROOTFS_POSTPROCESS_COMMAND += "install_guest_images; "
  72
  73 IMAGE_ROOTFS_EXTRA_SPACE:append = "${@bb.utils.contains("DISTRO_FEATURES", "systemd", " + 4096", "" ,d)}"