recipes-platform/images/agl-kvm-demo-platform.bb

   1 DESCRIPTION = "AGL KVM+QEMU Demo Platform image."
   2
   3 LICENSE = "MIT"
   4
   5 require recipes-platform/images/agl-image-compositor.bb
   6 require agl-demo-features.inc
   7
   8 IMAGE_FEATURES += "splash package-management ssh-server-openssh"
   9
  10 # If building with "agl-kvm-host-kuksa", the databroker and likely
  11 # some clients run on the host
  12 IMAGE_FEATURES += " \
  13     ${@bb.utils.contains("AGL_FEATURES", "agl-kvm-host-kuksa", "kuksa-val-databroker kuksa-val-databroker-client", "", d)} \
  14     ${@bb.utils.contains("DISTRO_FEATURES", "agl-devel", "can-test-tools" , "", d)} \
  15 "
  16
  17 # Add packages for KVM+QEMU demo platform here
  18 IMAGE_INSTALL += " \
  19     packagegroup-agl-core-connectivity \
  20     kernel-image \
  21     agl-compositor \
  22     weston-ini-conf-kvm \
  23     output-udev-conf \
  24     native-shell-client \
  25     qemu \
  26     ${QEMU_GUEST_CONFIGS} \
  27     util-linux-taskset \
  28     screen \
  29     simple-can-simulator \
  30     alsa-utils \
  31 "
  32
  33 # Until virtio sound is workable with QEMU, run the audio using
  34 # services on the host for a better demo experience.  At the
  35 # moment, this also includes the HVAC service since it does not
  36 # make sense to try to make things more fine-grained with respect
  37 # to configuration for where things expect to find the databroker.
  38 # It will need to be revisited when virtio-snd, virtio-gpio, etc.
  39 # become feasible to use.
  40 HOST_AUDIO_INSTALL = " \
  41     packagegroup-agl-ivi-services-platform \
  42     agl-service-radio-conf-kvm-demo \
  43     packagegroup-pipewire \
  44     wireplumber-config-agl \
  45     wireplumber-policy-config-agl \
  46     mpd \
  47     udisks2 \
  48     ${@bb.utils.contains("DISTRO_FEATURES", "agl-devel", "packagegroup-pipewire-tools mpc" , "", d)} \
  49 "
  50
  51 IMAGE_INSTALL += "\
  52     ${@bb.utils.contains("AGL_FEATURES", "agl-kvm-host-kuksa", "kuksa-databroker-agl-demo-cluster", "", d)} \
  53     ${@bb.utils.contains("AGL_FEATURES", "agl-kvm-host-audio", "${HOST_AUDIO_INSTALL}", "", d)} \
  54 "
  55
  56 # Potential size reduction options
  57 #IMAGE_LINGUAS = " "
  58 #NO_RECOMMENDATIONS = "1"
  59
  60 GUEST_MACHINE ?= "virtio-${TUNE_ARCH}"
  61
  62 GUEST_VM1_IMAGE ?= "agl-ivi-demo-platform-flutter"
  63 GUEST_VM2_IMAGE ?= "agl-cluster-demo-platform-flutter"
  64
  65 GUEST_IMAGES ?= "agl-kvm-guest:${GUEST_VM1_IMAGE} agl-kvm-guest:${GUEST_VM2_IMAGE}"
  66
  67 QEMU_GUEST_CONFIGS ?= ""
  68
  69 python __anonymous() {
  70     for c in (d.getVar('GUEST_IMAGES') or "").split():
  71         (mc, image) = c.split(':')
  72         dependency = 'mc::' + mc + ':' + image + ':do_image_complete'
  73         d.appendVarFlag('do_rootfs', 'mcdepends', ' ' + dependency)
  74
  75         # Assume there is a qemu-config-X package for guest image X
  76         d.appendVar('QEMU_GUEST_CONFIGS', ' ' + 'qemu-config-' + image)
  77 }
  78
  79 install_guest_images() {
  80     for c in ${GUEST_IMAGES}; do
  81         config=${c%:*}
  82         image=${c#*:}
  83         name=${image}
  84         rm -rf  ${IMAGE_ROOTFS}/var/lib/machines/${name}
  85         install -m 0755 -d ${IMAGE_ROOTFS}/var/lib/machines/${name}
  86         src="${TOPDIR}/tmp-${config}/deploy/images/${GUEST_MACHINE}/${image}-${GUEST_MACHINE}.ext4"
  87         bbnote "Installing ${src}"
  88         install -m 0600 ${src} ${IMAGE_ROOTFS}/var/lib/machines/${name}/
  89         # Placeholder until booting from kernel in VM image is worked out
  90         install -m 0600 ${TOPDIR}/tmp-${config}/deploy/images/${GUEST_MACHINE}/Image-${GUEST_MACHINE}.bin ${IMAGE_ROOTFS}/var/lib/machines/${name}/
  91     done
  92 }
  93
  94 ROOTFS_POSTPROCESS_COMMAND += "install_guest_images; "
  95
  96 IMAGE_ROOTFS_EXTRA_SPACE:append = "${@bb.utils.contains("DISTRO_FEATURES", "systemd", " + 4096", "" ,d)}"