recipes-platform/images/agl-kvm-demo-platform.bb

   1 DESCRIPTION = "AGL KVM+QEMU Demo Platform image."
   2
   3 LICENSE = "MIT"
   4
   5 require recipes-platform/images/agl-image-compositor.bb
   6
   7 IMAGE_FEATURES += "splash package-management ssh-server-openssh"
   8
   9 # Add packages for KVM+QEMU demo platform here
  10 IMAGE_INSTALL += " \
  11     packagegroup-agl-core-connectivity \
  12     kernel-image \
  13     agl-compositor \
  14     weston-ini-conf-kvm \
  15     output-udev-conf \
  16     native-shell-client \
  17     qemu \
  18     ${QEMU_GUEST_CONFIGS} \
  19     util-linux-taskset \
  20     screen \
  21     simple-can-simulator \
  22     alsa-utils \
  23 "
  24
  25 # Potential size reduction options
  26 #IMAGE_LINGUAS = " "
  27 #NO_RECOMMENDATIONS = "1"
  28
  29 GUEST_MACHINE ?= "virtio-${TUNE_ARCH}"
  30
  31 GUEST_VM1_IMAGE ?= "agl-ivi-demo-platform-flutter"
  32 GUEST_VM2_IMAGE ?= "agl-cluster-demo-platform-flutter"
  33
  34 GUEST_IMAGES ?= "agl-kvm-guest:${GUEST_VM1_IMAGE} agl-kvm-guest:${GUEST_VM2_IMAGE}"
  35
  36 QEMU_GUEST_CONFIGS ?= ""
  37
  38 python __anonymous() {
  39     for c in (d.getVar('GUEST_IMAGES') or "").split():
  40         (mc, image) = c.split(':')
  41         dependency = 'mc::' + mc + ':' + image + ':do_image_complete'
  42         d.appendVarFlag('do_rootfs', 'mcdepends', ' ' + dependency)
  43
  44         # Assume there is a qemu-config-X package for guest image X
  45         d.appendVar('QEMU_GUEST_CONFIGS', ' ' + 'qemu-config-' + image)
  46 }
  47
  48 install_guest_images() {
  49     for c in ${GUEST_IMAGES}; do
  50         config=${c%:*}
  51         image=${c#*:}
  52         name=${image}
  53         rm -rf  ${IMAGE_ROOTFS}/var/lib/machines/${name}
  54         install -m 0755 -d ${IMAGE_ROOTFS}/var/lib/machines/${name}
  55         src="${TOPDIR}/tmp-${config}/deploy/images/${GUEST_MACHINE}/${image}-${GUEST_MACHINE}.ext4"
  56         bbnote "Installing ${src}"
  57         install -m 0600 ${src} ${IMAGE_ROOTFS}/var/lib/machines/${name}/
  58         # Placeholder until booting from kernel in VM image is worked out
  59         install -m 0600 ${TOPDIR}/tmp-${config}/deploy/images/${GUEST_MACHINE}/Image-${GUEST_MACHINE}.bin ${IMAGE_ROOTFS}/var/lib/machines/${name}/
  60     done
  61 }
  62
  63 ROOTFS_POSTPROCESS_COMMAND += "install_guest_images; "
  64
  65 IMAGE_ROOTFS_EXTRA_SPACE:append = "${@bb.utils.contains("DISTRO_FEATURES", "systemd", " + 4096", "" ,d)}"