recipes-platform/images/agl-kvm-demo-platform.bb

   1 DESCRIPTION = "AGL KVM+QEMU Demo Platform image."
   2
   3 LICENSE = "MIT"
   4
   5 require recipes-platform/images/agl-image-compositor.bb
   6 require agl-demo-features.inc
   7
   8 IMAGE_FEATURES += "splash package-management ssh-server-openssh"
   9
  10 # If building with "agl-kvm-host-kuksa", the databroker and likely
  11 # some clients run on the host
  12 IMAGE_FEATURES += " \
  13     ${@bb.utils.contains("AGL_FEATURES", "agl-kvm-host-kuksa", "kuksa-val-databroker kuksa-val-databroker-client", "", d)} \
  14 "
  15
  16 # Add packages for KVM+QEMU demo platform here
  17 IMAGE_INSTALL += " \
  18     packagegroup-agl-core-connectivity \
  19     kernel-image \
  20     agl-compositor \
  21     weston-ini-conf-kvm \
  22     output-udev-conf \
  23     native-shell-client \
  24     qemu \
  25     ${QEMU_GUEST_CONFIGS} \
  26     util-linux-taskset \
  27     screen \
  28     simple-can-simulator \
  29     alsa-utils \
  30 "
  31
  32 # Potential size reduction options
  33 #IMAGE_LINGUAS = " "
  34 #NO_RECOMMENDATIONS = "1"
  35
  36 GUEST_MACHINE ?= "virtio-${TUNE_ARCH}"
  37
  38 GUEST_VM1_IMAGE ?= "agl-ivi-demo-platform-flutter"
  39 GUEST_VM2_IMAGE ?= "agl-cluster-demo-platform-flutter"
  40
  41 GUEST_IMAGES ?= "agl-kvm-guest:${GUEST_VM1_IMAGE} agl-kvm-guest:${GUEST_VM2_IMAGE}"
  42
  43 QEMU_GUEST_CONFIGS ?= ""
  44
  45 python __anonymous() {
  46     for c in (d.getVar('GUEST_IMAGES') or "").split():
  47         (mc, image) = c.split(':')
  48         dependency = 'mc::' + mc + ':' + image + ':do_image_complete'
  49         d.appendVarFlag('do_rootfs', 'mcdepends', ' ' + dependency)
  50
  51         # Assume there is a qemu-config-X package for guest image X
  52         d.appendVar('QEMU_GUEST_CONFIGS', ' ' + 'qemu-config-' + image)
  53 }
  54
  55 install_guest_images() {
  56     for c in ${GUEST_IMAGES}; do
  57         config=${c%:*}
  58         image=${c#*:}
  59         name=${image}
  60         rm -rf  ${IMAGE_ROOTFS}/var/lib/machines/${name}
  61         install -m 0755 -d ${IMAGE_ROOTFS}/var/lib/machines/${name}
  62         src="${TOPDIR}/tmp-${config}/deploy/images/${GUEST_MACHINE}/${image}-${GUEST_MACHINE}.ext4"
  63         bbnote "Installing ${src}"
  64         install -m 0600 ${src} ${IMAGE_ROOTFS}/var/lib/machines/${name}/
  65         # Placeholder until booting from kernel in VM image is worked out
  66         install -m 0600 ${TOPDIR}/tmp-${config}/deploy/images/${GUEST_MACHINE}/Image-${GUEST_MACHINE}.bin ${IMAGE_ROOTFS}/var/lib/machines/${name}/
  67     done
  68 }
  69
  70 ROOTFS_POSTPROCESS_COMMAND += "install_guest_images; "
  71
  72 IMAGE_ROOTFS_EXTRA_SPACE:append = "${@bb.utils.contains("DISTRO_FEATURES", "systemd", " + 4096", "" ,d)}"