recipes-platform/images/agl-demo-platform-crosssdk.bb

   1 SUMMARY = "Cross SDK of Full AGL Distribution for IVI profile"
   2
   3 DESCRIPTION = "SDK image for full AGL Distribution for IVI profile. \
   4 It includes the full meta-toolchain, plus developement headers and libraries \
   5 to form a standalone cross SDK."
   6
   7 require agl-demo-platform.bb
   8
   9 LICENSE = "MIT"
  10
  11 IMAGE_FEATURES_append = " dev-pkgs"
  12 IMAGE_INSTALL_append = " kernel-dev kernel-devsrc"
  13
  14 inherit populate_sdk populate_sdk_qt5
  15
  16 # Task do_populate_sdk and do_rootfs can't be exec simultaneously.
  17 # Both exec "createrepo" on the same directory, and so one of them
  18 # can failed (randomly).
  19 addtask do_populate_sdk after do_rootfs
  20
  21 # native tools to support Chromium build inside SDK (SPEC-942)
  22 TOOLCHAIN_HOST_TASK += " \
  23     nativesdk-gn \
  24     nativesdk-ninja \
  25     nativesdk-gperf \
  26     nativesdk-zlib \
  27     nativesdk-xz \
  28     nativesdk-nspr-dev \
  29     nativesdk-nss-dev \
  30     nativesdk-lua \
  31     "
  32
  33 # required dependencies for Chromium build inside SDK (SPEC-942)
  34 TOOLCHAIN_TARGET_TASK += " \
  35     pciutils-dev \
  36     ${@bb.utils.contains('DISTRO_FEATURES', 'pulseaudio', 'pulseaudio-dev' , '', d)} \
  37     ${@bb.utils.contains('DISTRO_FEATURES', 'agl-audio-4a-framework', 'libavirt-staticdev' , '', d)} \
  38     cairo-dev \
  39     nss-dev \
  40     cups-dev \
  41     gconf-dev \
  42     libexif-dev \
  43     pango-dev \
  44     libdrm-dev  \
  45     libssp-dev \
  46     lua-dev \
  47     lua-staticdev \
  48     libafb-helpers-staticdev \
  49     libafb-helpers-qt-staticdev \
  50     libappcontroller-staticdev \
  51     ${@bb.utils.contains('LICENSE_FLAGS_WHITELIST', 'commercial', 'ffmpeg-dev', '', d)} \
  52     "
  53
  54 # Add wayland-scanner to SDK (SPEC-945)
  55 # Use TOOLCHAIN_HOST_TASK instead of adding to the packagegroup
  56 # wayland-scanner is in nativesdk-wayland-dev !
  57 # option: add also nativesdk-qtwayland-tools
  58 TOOLCHAIN_HOST_TASK_append = " nativesdk-wayland nativesdk-wayland-dev"
  59
  60 TOOLCHAIN_HOST_TASK_append = " nativesdk-perl-modules "
  61
  62 # Add libvcard to the SDK to support libqtappfw
  63 TOOLCHAIN_TARGET_TASK += " \
  64     libvcard-dev \
  65     libvcard-staticdev \
  66     "