recipes-platform/images/agl-cluster-demo-platform-flutter.bb

   1 SUMMARY = "Baseline Flutter Image for Release"
   2
   3 LICENSE = "MIT"
   4
   5 require recipes-platform/images/agl-image-compositor.bb
   6
   7 IMAGE_FEATURES += "splash package-management ssh-server-openssh"
   8
   9 # Break out KUKSA.val packages, as demo unit configuration
  10 # points at KUKSA.val server on the IVI board in full demo
  11 # builds with the "agl-demo-preload" feature enabled.
  12 KUKSA_DATABROKER_PACKAGES = " \
  13     packagegroup-agl-kuksa-val-databroker \
  14     ${@bb.utils.contains('DISTRO_FEATURES', 'agl-devel', 'packagegroup-agl-kuksa-val-databroker-devel' , '', d)} \
  15 "
  16
  17
  18 # generic
  19 IMAGE_INSTALL += "\
  20     ${@bb.utils.contains("AGL_FEATURES", "agl-demo-preload", "psplash-inverted-config", "", d)} \
  21     ${@bb.utils.contains("AGL_FEATURES", "agl-demo-preload", "weston-ini-conf-landscape-inverted", "weston-ini-conf-landscape", d)} \
  22     \
  23     packagegroup-agl-networking \
  24     cluster-receiver \
  25     \
  26     kuksa-certificates-agl-ca \
  27     ${@bb.utils.contains("AGL_FEATURES", "agl-demo-preload", "", "${KUKSA_DATABROKER_PACKAGES}", d)} \
  28     simple-can-simulator \
  29     "
  30
  31 # Flutter
  32 IMAGE_INSTALL += "\
  33     flutter-cluster-dashboard \
  34     ${@bb.utils.contains("AGL_FEATURES", "agl-demo-preload", "flutter-cluster-dashboard-conf-demo", "flutter-cluster-dashboard-conf", d)} \
  35     cluster-demo-config-flutter \
  36     flutter-auto \
  37     "
  38
  39 CLANGSDK = "1"