recipes-platform/images/agl-cluster-demo-platform-flutter.bb

   1 SUMMARY = "Baseline Flutter Image for Release"
   2
   3 LICENSE = "MIT"
   4
   5 require recipes-platform/images/agl-image-compositor.bb
   6
   7 IMAGE_FEATURES += "splash package-management ssh-server-openssh"
   8
   9 # Break out KUKSA.val packages, as demo unit configuration
  10 # points at KUKSA.val server on the IVI board instead of
  11 # running the full stack locally.
  12 IMAGE_KUKSA_PACKAGES = " \
  13     kuksa-val \
  14     kuksa-databroker \
  15     kuksa-val-agl \
  16     kuksa-databroker-agl \
  17     kuksa-certificates-agl \
  18     kuksa-dbc-feeder \
  19     kuksa-vss-init \
  20     ${@bb.utils.contains('DISTRO_FEATURES', 'agl-devel', 'kuksa-databroker-cli' , '', d)} \
  21 "
  22
  23 # generic
  24 IMAGE_INSTALL += "\
  25     ${@bb.utils.contains("AGL_FEATURES", "agl-demo-preload", "weston-ini-conf-landscape-inverted", "weston-ini-conf-landscape", d)} \
  26     \
  27     packagegroup-agl-networking \
  28     cluster-receiver \
  29     \
  30     ${@bb.utils.contains("AGL_FEATURES", "agl-demo-preload", "", "${IMAGE_KUKSA_PACKAGES}", d)} \
  31     simple-can-simulator \
  32     "
  33
  34 # Flutter
  35 IMAGE_INSTALL += "\
  36     flutter-cluster-dashboard \
  37     ${@bb.utils.contains("AGL_FEATURES", "agl-demo-preload", "flutter-cluster-dashboard-conf-demo", "flutter-cluster-dashboard-conf", d)} \
  38     cluster-demo-config-flutter \
  39     flutter-auto \
  40     "
  41
  42 CLANGSDK = "1"