recipes-platform/images/agl-cluster-demo-platform-flutter.bb

   1 SUMMARY = "Baseline Flutter Image for Release"
   2
   3 LICENSE = "MIT"
   4
   5 require recipes-platform/images/agl-image-weston.inc
   6
   7 IMAGE_FEATURES += "splash package-management ssh-server-openssh"
   8
   9 # Break out KUKSA.val packages, as demo unit configuration
  10 # points at KUKSA.val server on the IVI board instead of
  11 # running the full stack locally.
  12 IMAGE_KUKSA_PACKAGES = " \
  13     kuksa-val \
  14     kuksa-val-agl \
  15     kuksa-dbc-feeder \
  16     kuksa-vss-init \
  17 "
  18
  19 # generic
  20 IMAGE_INSTALL:append = "\
  21     agl-compositor \
  22     agl-compositor-init \
  23     ${@bb.utils.contains("AGL_FEATURES", "agl-demo-preload", "weston-ini-conf-landscape-inverted", "weston-ini-conf-landscape", d)} \
  24     \
  25     packagegroup-agl-profile-graphical \
  26     packagegroup-agl-networking \
  27     cluster-receiver \
  28     \
  29     ${@bb.utils.contains("AGL_FEATURES", "agl-demo-preload", "", "${IMAGE_KUKSA_PACKAGES}", d)} \
  30     simple-can-simulator \
  31     "
  32
  33 # Flutter
  34 IMAGE_INSTALL:append = "\
  35     flutter-cluster-dashboard \
  36     ${@bb.utils.contains("AGL_FEATURES", "agl-demo-preload", "cluster-demo-config-flutter", "", d)} \
  37     ${@bb.utils.contains("AGL_FEATURES", "agl-demo-preload", "flutter-cluster-dashboard-conf-demo", "flutter-cluster-dashboard-conf", d)} \
  38     flutter-auto-runtimerelease \
  39     "
  40
  41 CLANGSDK = "1"